Access - Generar fichero mdb con vbasic

Hola a todo el mundo, bueno vamos a ver, mi duda es probable que sea muy sencilla de responder pero estuve buscando en varios sitios y no consegui resultados satisfactorios.
El caso, necesito crear una macro con la que pueda generar un fichero mdb en blanco y despues exportar unas tablas del fichero con el que estoy trabajando a esa base de datos nueva y vacia, alguien puede echarme una mano con esto? gracias por anticipado

Si te parece, mejor que una Macro, un Procedimiento de Evento por ejemplo "Al hacer click" de un botón de comando que haga las dos cosas, una detrás de otra. Primero Crea la nueva mdb y luego le Exporta las Tablas que quieras:

Antes que nada debes abrir la Ventana Referencias y marcar la librería:
Microsoft ADO Ext. 2.8 for DDL and Security

'ARRIBA EN LA SECCION DE DECLARACIONES DEL FORMULARIO:
Option Compare Database
Dim BD As ADOX.Catalog

'EVENTO "AL HACER CLICK" DE UN BOTON:
Private Sub Crear_Click()
On Error GoTo Cancela
'Creamos la Nueva Base de Datos "BaseDatosNueva.mdb"
Set BD = New ADOX.Catalog
BD.Create "Provider = Microsoft.Jet.OLEDB.4.0;" & _
"Data Source = C:/TuCarpeta/BaseDatosNueva.mdb"

'Transferimos 2 Tablas desde esta Mdb a la Nueva Mdb
DoCmd.TransferDatabase acExport, "Microsoft Access", _
"C:/TuCarpeta/BaseDatosNueva.mdb", acTable, "Tabla1", "Tabla1", False

DoCmd.TransferDatabase acExport, "Microsoft Access", _
"C:/TuCarpeta/BaseDatosNueva.mdb", acTable, "Tabla2", "Tabla2", False
Exit Sub

Cancela:
MsgBox "La Base de datos ya existe.", vbCritical, "Creación cancelada"
End Sub

Realmente, como bien dices, tu duda es fácil de solucionar, todo depende de si sabes interpretar todo este código y aplicarlo correctamente.

Nota: Las Barras de las Ruta de la nueva MDB las pones inclinadas a la izquierda, como es debido. Yo las he puesto a la derecha porque las otras no se muestran en este Foro.

Saludos
Enrique