Access - Access 2007. Error de no coinciden los tipos

   
Vista:

Access 2007. Error de no coinciden los tipos

Publicado por Jose Miguel (7 intervenciones) el 05/02/2009 11:25:57
Buenas

Estoy usando Access 2007, he creado un formulario para introducir datos en una tabla.

Mi problema es el siguiente, en el boton que al hacer click graba el registro en la tabla, me da error de que no coinciden los tipos, os pongo el codigo

Private Sub Comando27_Click()
Dim tablanombre As String
tablanombre = "SALONES"
Dim base As Database
Dim tabla As Recordset
Set base = CurrentDb()
Set tabla = base.OpenRecordset(tablanombre)
With tabla
.AddNew
![CODIGO SALON] = Me.SALON_SOLICITADO
![CODIGO RAMA] = Me.RAMA
![FECHA PETICION] = Me.FECHA_DE_PETICION
![HORA DE INICIO] = Me.HORA_DE_INICIO
![HORA FINALIZACION] = Me.HORA_DE_FINALIZACION
![RESPONSABLE DE PETICION] = Me.PERSONA_QUE_REALIZA_LA_PETICION
![FECHADEREUNION] = Me.FECHA_DE_REUNION
![MOTIVO] = Me.MOTIVO_DE_PETICION
![COMENTARIOS] = Me.COMENTARIOS_PETICION
.Update
End With
tabla.Close
Set base = Nothing
DoCmd.Close acDefault
End Sub

Bien cuando llega a la linea "Set tabla = base.OpenRecordset(tablanombre)", me salta un error diciendome que no coinciden los tipos. He probado a poner el nombre de la tabla directamente en lugar de usar la variable para poner el nombre de la tabla, y tampoco.

Se os ocurre algo?

Gracias de antemano.
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:Access 2007. Error de no coinciden los tipos

Publicado por Chea (1015 intervenciones) el 05/02/2009 20:09:31
OpenRecordset es un método de DAO, pero un Recordset puede ser de DAO o de ADO, por lo que cabe la posibilidad de que tengas una referencia a ADO por delante a la de DAO.

Prueba a dimensionar los objetos con el prefijo DAO:

Dim base As DAO.Database
Dim tabla As DAO.Recordset

Saludos
José Bengoechea Ibaceta
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Access 2007. Error de no coinciden los tipos

Publicado por Carlos Andrés (1 intervención) el 20/04/2010 07:33:33
A mí me pasó lo mismo. Lo más probable es que hayas convertido un archivo en access de una versión anterior a access 2007, en mi caso 2003. Al hacer eso, se pierden el orden de las referencias en Visual Basic.
Para solucionarlo, abre la ventana del editor de Visual Basic y entra a Herramientas-Referencias. Sube la prioridad a Microsoft Office 12.0 Access database engine Object Library, de tal forma que quede por encima de Microsoft ActiveX Data Objects 2.1 Library. Y solucionado. (Tomado de Microsoft Support Article ID: 927678).
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Access 2007. Error de no coinciden los tipos

Publicado por Victor (1 intervención) el 15/10/2012 18:11:14
Gracias, a mi me pasaba lo mismo al convertir el archivo. Solucionado!!!
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar