Access - Exportar formato

   
Vista:

Exportar formato

Publicado por Pequenogigante (7 intervenciones) el 18/04/2009 15:45:26
Hola:

mi versión de access es 2003, tengo un informe que paso por correo y tiene formato condicional en algunos campos pero al exportarlo a rich text format no exporta el formato condicional ni otro.

como puedo hacerlo

gracias, sl2
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:Exportar formato

Publicado por Pequenogigante (7 intervenciones) el 18/04/2009 17:42:21
hola: yo mismo me respondo pues lo descubrí en otras respuestas del foro

se puede exportar en snapshot format y te lo exporta todo

espero les sea de utilidad

sl2
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Exportar formato

Publicado por Jefferson (381 intervenciones) el 18/04/2009 18:19:55
Si Usas Access 2007, tambien lo puedes exportar como PDF
pincha en la direccion URL y te descargas el complemento

y para extaerlo tan facil como
DoCmd.OutputTo acReport, "Nombre de tu Informe", acFormatPDF, CurrentProject.Path & "Nombre de Salida.pdf"

Espero y te sirva
Desde Venezuela
Jefferson
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

como puedo exportar snapshot con vba2003

Publicado por pequeno gigante (7 intervenciones) el 19/04/2009 18:42:45
si gracias pero quisiera saber como puedo enviar un informe por correo en formato snapshot de forma automatica

probé docmd.sendobject acsendreport, "nombre del informe", [outputformat]

en outputformat probé acformatXLS y si lo reconoce pero cual puedo usar para snapshot

gracias again access 2003 es lo que uso

sl2
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:como puedo exportar snapshot con vba2003

Publicado por mi menda (1111 intervenciones) el 19/04/2009 21:50:45
Hola:
Te va a ser más fácil crear una macro EnviarObjeto, hay configuras todo de una manera sencilla, luego sí quieres utilizar código en vez de la macro, la conviertes a visual basic y copias y pegas el código donde te interese.

Un saludo.
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:como puedo exportar snapshot con vba2003

Publicado por Jefferson (381 intervenciones) el 20/04/2009 05:50:57
Como te indica mi menda es una opcion y por supuestos la mas sencilla

Perooooo.......
Particularmente no me gusta el Outlook, es por eso que adapte una funcion de envio de correo libre escrita originalmente para VB6 a VBA

1) Para ello deberias copiar este codigo en un modulo clase
'Envio de correo electronico a través de CDO (Microsoft)
'Escrito originalmente para ser usado en VB6 y modificado por
'Jefferson Jimenez Tarre JJJT
'Abril de 2009
'Cabimas, Venezuela
Option Compare Database
Option Explicit
' para la conexión a internet
Private Declare Function InternetGetConnectedState _
Lib "wininet.dll" ( _
ByRef lpdwFlags As Long, _
ByVal dwReserved As Long) As Long
Private Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8
Private Const INTERNET_RAS_INSTALLED As Long = &H10
Private Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Private Const INTERNET_CONNECTION_CONFIGURED As Long = &H40
' variables locales
Private mServidor As String
Private mPara As String
Private mDe As String
Private mAsunto As String
Private mMensaje As String
Private mAdjunto As String
Private mPuerto As Variant
Private mUsuario As String
Private mPassword As String
Private mUseAuntentificacion As Boolean
Private mSSL As Boolean
Public Event Error(Descripcion As String, Numero As Variant)
Public Event EnvioCompleto()
Function Enviar_Correo() As Boolean
' Variable de objeto Cdo.Message
Dim oCDO As Object
' chequeamos si hay conexión a internet
If InternetGetConnectedState(0&, 0&) = False Then
RaiseEvent Error("No se puede enviar el correo. " & _
"Verificar la conexión a internet si está disponible", 0)
Exit Function
End If
' chequea que el puerto sea un número, o que no esté vacío
If Not IsNumeric(puerto) Then
RaiseEvent Error("No se ha indicado el puerto del servidor", 0)
Exit Function
End If
' Crea un Nuevo objeto CDO.Message _
o lo que es lo mismo agregamos la libreria _
Activex Microsoft CDO "Microsoft CDO for windows 2000 library"
Set oCDO = CreateObject("CDO.Message")
' Indica el servidor Smtp para poder enviar el Mail ( puede ser el nombre _
del servidor o su dirección IP )
oCDO.Configuration.Fields( _
"http://schemas.microsoft.com/cdo/configuration/smtpserver") = mServidor
oCDO.Configuration.Fields( _
"http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
' Puerto. Por defecto se usa el puerto 25, _
en el caso de Gmail se usa el puerto 465
oCDO.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = mPuerto
' Indica el tipo de autentificación con el servidor de correo _
El valor 0 no requiere autentificarse, el valor 1 es con autentificación
oCDO.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/" & _
"configuration/smtpauthenticate") = Abs(mUseAuntentificacion)
' Tiempo máximo de espera en segundos para la conexión
oCDO.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
' Configura las opciones para el login en el SMTP
If mUseAuntentificacion Then
' Id de usuario del servidor Smtp ( en el caso de gmail, _
debe ser la dirección de correro mas el @gmail.com )
oCDO.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = mUsuario
' Password de la cuenta
oCDO.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = mPassword
' Indica si se usa SSL para el envío. En el caso de Gmail requiere que esté en True
oCDO.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = mSSL
End If
' Estructura del mail
'''''''''''''''''''''''''''''''''''''''''''''''
' Dirección del Destinatario
oCDO.To = mPara
' Dirección del remitente
oCDO.From = mDe
' Asunto del mensaje
oCDO.Subject = mAsunto
' Cuerpo del mensaje
oCDO.TextBody = mMensaje
'Ruta del archivo adjunto
If mAdjunto <> "" Then
If Len(Dir(mAdjunto)) = 0 Then
' ..error
RaiseEvent Error("No se ha encontrado el archivo en la siguiente ruta: ", 0)
Exit Function
Else
' ..lo agrega
oCDO.AddAttachment (mAdjunto)
End If
End If
' Actualiza los datos antes de enviar
oCDO.Configuration.Fields.Update
On Error Resume Next
DoCmd.Hourglass True
' Envía el email
oCDO.Send
Screen.MousePointer = 0
' .. si no hubo error
If Err.Number = 0 Then
Enviar_Correo = True
RaiseEvent EnvioCompleto
ElseIf Err.Number = -2147220973 Then
RaiseEvent Error("Posible error : nombre del Servidor " & _
"incorrecto o número de puerto incorrecto", Err.Number)
ElseIf Err.Number = -2147220975 Then
RaiseEvent Error("Posible error : error en la el nombre de usuario, " & _
"o en el password ", Err.Number)
Else
RaiseEvent Error(Err.Description, Err.Number)
End If
' Descarga la referencia
If Not oCDO Is Nothing Then
Set oCDO = Nothing
End If
Err.Clear
Screen.MousePointer = vbNormal
End Function
' propiedades
'''''''''''''''''''''
Property Get servidor() As String
servidor = mServidor
End Property
Property Let servidor(value As String)
mServidor = value
End Property
Property Get para() As String
para = mPara
End Property
Property Let para(value As String)
mPara = value
End Property
Property Get de() As String
de = mDe
End Property
Property Let de(value As String)
mDe = value
End Property
Property Get Asunto() As String
Asunto = mAsunto
End Property
Property Let Asunto(value As String)
mAsunto = value
End Property
Property Get Mensaje() As String
Mensaje = mMensaje
End Property
Property Let Mensaje(value As String)
mMensaje = value
End Property
Property Get Adjunto() As String
Adjunto = mAdjunto
End Property
Property Let Adjunto(value As String)
mAdjunto = value
End Property
Property Get puerto() As Variant
puerto = mPuerto
End Property
Property Let puerto(value As Variant)
mPuerto = value
End Property
Property Get Usuario() As String
Usuario = mUsuario
End Property
Property Let Usuario(value As String)
mUsuario = value
End Property
Property Get PassWord() As String
PassWord = mPassword
End Property
Property Let PassWord(value As String)
mPassword = value
End Property
Property Get UseAuntentificacion() As Boolean
UseAuntentificacion = mUseAuntentificacion
End Property
Property Let UseAuntentificacion(value As Boolean)
mUseAuntentificacion = value
End Property
Property Get ssl() As Boolean
ssl = mSSL
End Property
Property Let ssl(value As Boolean)
mSSL = value
End Property
' ******************************Hasta aqui***************************************

2) Ahora en el formulario desde donde vas a enviar el correo crea un boton de comando y le llamas Comando1 y en el modulo vba pegas esto
'Envio de correo electronico a través de CDO (Microsoft)
'Escrito originalmente para ser usado en VB6 y modificado por
'Jefferson Jimenez Tarre JJJT
'Abril de 2009
'Cabimas, Venezuela
Option Compare Database
Option Explicit
Private WithEvents oMail As clsCDOmail
Private Sub Comando1_Click()
'Primero extraemos el informe como SnapShot
DoCmd.OutputTo acReport, "Productos por categoría", acFormatSNP, CurrentProject.Path & "Productos por categoría.snp"
'Empezamos la rutina de envio
Set oMail = New clsCDOmail
With oMail
.servidor = "smtp.gmail.com" 'No lo tocamos puesto que vamos a utilizar _
el servidor Gmail como SMTP
.puerto = 465 'De no servir este puerto lo cambiamos a 587
.UseAuntentificacion = True
.ssl = True
.Usuario = "correojjjtcdo@gmail.com" 'Aqui colocas el nombre de tu correo gmail
.PassWord = "correojjjt1973cdo" 'Aqui tu clave del correo gmail
.Asunto = "Mensaje de Prueba"
.Adjunto = CurrentProject.Path & "Productos por categoría.snp" 'El Archivo Adjunto _
que deberia estar en la misma carpeta del la BD
.de = "Jefferson Jimenez" 'Aqui te identificas
'********************************************************************************
'********************************************************************************
.para = "jefferson-jimenez@hotmail.com" 'El Destinatario o ha quien se lo envias
'********************************************************************************
'********************************************************************************
.Mensaje = "Este es un Mensaje de Prueba, por favor Eliminelo" 'Los comentarios
.Enviar_Correo ' Hasta que al fin lo enviamos
End With
Set oMail = Nothing
End Sub
'Al enviar exitosamente
Private Sub oMail_EnvioCompleto()
With oMail
MsgBox "Enviado a : " & .para & vbCrLf & _
"Asunto : " & .Asunto & vbCrLf & _
"Con el Archivo Adjunto : " & .Adjunto & vbCrLf & _
"", vbInformation, "Correo Enviado"
End With
End Sub
' al ocurrir un error
Private Sub oMail_Error(Descripcion As String, Numero As Variant)
MsgBox Descripcion, vbCritical, Numero
End Sub
' ******************************Hasta aqui***************************************

COMO ES COSTUMBRE TE DEJO EL EJEMPLO EN LA DIRECCION URL

Espero haberte ayudado
Desde Venezuela
Jefferson
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:como puedo exportar snapshot con vba2003

Publicado por pequeno gigante (7 intervenciones) el 23/04/2009 13:19:06
gracias a mi menda me funciona de maravilla, lo siento jefferson pero no soy todo un experto y en realidad no entiendo lo que me pusiste, gracias, de todas maneras guardé lo que me enviaste porque seguro que en futuro lo necesitaré...

hasta la próxima
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar