Access - Contador en Access

Buenos días.

Tengo una base de datos en Access, la cuál esta compuesta a su vez por distintas tablas, en las cuáles hay un sinfin de registros.

Mi pregunta es saber si hay alguna función o manera de saber el número de registros que hay en cada tabla, y a su vez el total de toda la base de datos, si hay algún metodo para tenerlo resumido de alguna forma.

Actualmente, me meto en cada tabla y abajo pone el total de registros, lo que hago es ir tabla por tabla y sumando todos los registros.

No se si me explico bien, lo pondre con un ejemplo:

Tengo una base X que esta compuesta por las siguientes tablas:

- A con 100 registros
- B con 223 registros
- C con 4500 registros
- D con 15 registros.

Estas tablas se van actualizando añadiendo y quitando registros, con lo que el número va variando constantemente.

Me gustaría saber si hay alguna función para poder pinchar en ella (genero un botón) y que me de un resumen:

A = 100
B = 223
C = 4500
D = 15

TOTAL: 4.838

Muchas gracias y disculpar las molestias.

Francisco Javier.

Hay una opsion que te permite obtener el total de los registros de un campo, coloca agregar totales en vista diseño

Hola!

Haz lo siguiente:

- Créate una tabla y guárdala como TResumen. Esta tabla no tendrá ninguna clave principal.
- En esa tabla créate dos campos (importante que respetes el orden que te indico):
*** Un primer campo, llamado [NomTabla], de tipo texto
*** Un segundo campo, llamado [Registros], de tipo entero largo

Ahora, en un botón de comando, en su evento "Al hacer clic", le generas este código:

...
Private Sub...
'Declaramos las variables
Dim recuento As Long, acumulado As Long
Dim tbl As Object
Dim rst As DAO.Recordset
'Borramos los datos de TResumen
DoCmd.SetWarnings False
DoCmd.RunSQL ("DELETE FROM TResumen")
DoCmd.SetWarnings True
'Creamos el recordset sobre TResumen
Set rst = CurrentDb.OpenRecordset("TResumen", dbOpenTable)
'Iniciamos el recorrido por las tablas
For Each tbl In CurrentData.AllTables
If tbl.Name <> "TResumen" Then
If Left(tbl.Name, 4) <> "MSys" Then
recuento = DCount("*", tbl.Name)
'Escribimos la información en la tabla TResumen
With rst
.AddNew
.Fields(0).Value = tbl.Name
.Fields(1).Value = recuento
.Update
End With
'Acumulamos el valor
acumulado = acumulado + recuento
End If
End If
Next tbl
'Abrimos la tabla para ver los resultados
DoCmd.OpenTable "TResumen", , acReadOnly
'Mostramos un mensaje con el total de registros
MsgBox "Número total de registros: " & acumulado, vbInformation, "TOTALES"
'Cerramos conexiones y liberamos memoria
rst.Close
Set rst = Nothing
End Sub
...

Ya me dirás qué tal.

Un saludo,


http://neckkito.siliconproject.com.ar