Access - Que hago mal?

   
Vista:

Que hago mal?

Publicado por Sandra Veronica (203 intervenciones) el 08/10/2007 17:29:51
Hola a todos. Serían tan amables de mirar este código. Es una MSGBox que al presionar "Aceptar" deberia hacer una exportacion, pero el tema es que no entra al IF. Alguien me ayuda y me dice que estoy haciendo mal?
Saludos
Sandra!
*****************************************************
Private Sub Comando50_Click()

Dim RCliName As String
Dim CliName As String
Dim ValBtn As Integer


RCliName = Replace(Me.nombre, ".", "")
CliName = RCliName & " MC= " & Format(Left(Me.FechaCreac, 10), "dd-mm-yyyy") & " S= " & Format(Left(Me.FechaCreac1, 10), "dd-mm-yyyy")
ValBtn = vbInformation + vbOKCancel

MsgBox "Se Creará un Archivo con el nombre: " & Chr(13) & _
CliName & Chr(13) & _
"en la carpeta 'Mis Documentos'", ValBtn, "Exportar"

If ValBtn = VbOk Then
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, "SAP_Detalle_Final", CliName
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, "Consu Detalle_Mic_Calipso", CliName
MsgBox "Exportación Finalizada", vbInformation + vbOKOnly, "Exportar"
End If
End Sub
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:Que hago mal?

Publicado por xavi (92 intervenciones) el 08/10/2007 17:43:17
Hola,

Porque no evaluas la respuesta del MsgBox.

Si escibes:
MsgBox mensaje, iconos+botones, titulo
el sistema obvia la respuesta

en cambio, si escribes;:

respuesta = MsgBox(mensaje, iconos+botones, titulo)
el sistema evaluara la respuesta.
Tambien puedes meter el MsgBox en la condicion (que es lo que yo he hecho)

Prueba asi (lo he acortado un poco):

Private Sub Comando50_Click()

Dim CliName As String

CliName = Replace(Me!nombre, ".", "") & " MC= " & Format(Left(Me.FechaCreac, 10), "dd-mm-yyyy") & " S= " & Format(Left(Me.FechaCreac1, 10), "dd-mm-yyyy")

If MsgBox ("Se Creará un Archivo con el nombre: " & vbCrLf & _
CliName & vbCrLf & _
"en la carpeta 'Mis Documentos'", vbInformation + vbOKCancel, "Exportar" ) = vbOK Then
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, _
"SAP_Detalle_Final", CliName
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, _
"Consu Detalle_Mic_Calipso", CliName
MsgBox "Exportación Finalizada", vbInformation, "Exportar"
Else
MsgBox "Exportación cancelada", vbInformation, "Exportar"
End If
End Sub

Un saludo

Xavi
http://www.llodax.com
http://www.mvp-access.com/foro
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Que hago mal?

Publicado por Sandra Veronica (203 intervenciones) el 08/10/2007 18:32:26
Xavi, Muchisimassssssssssssssssssss Gracias!!!!!!!!!!! por tu valiosa ayuda. Ha funcionado a la perfección.
He estado toda la mañana tratando de descifrar esto.
Saludos
Sandra
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Que hago mal? CERRADO

Publicado por xavi (92 intervenciones) el 09/10/2007 09:29:07
De nada

:o)
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar