Clarion - Enter x Tab

   
Vista:

Enter x Tab

Publicado por Marco (114 intervenciones) el 17/06/2014 14:27:19
Donde puedo conseguir los template Reemplazar enter x tab y pasar números a letras para Clarion 8?
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder
información
Otras secciones de LWP con contenido de Clarion
- Código fuente de Clarion
- Cursos de Clarion
información
Códigos de Clarion
- Llamar al form para insertar desde el menu

Enter x Tab

Publicado por Francisco J. Valencia (85 intervenciones) el 18/06/2014 05:03:49
1. Para reemplazar enter x tab, marcas la opción "Use ENTER key instead of TAB".
Esta opción la encuentras en tu aplicación en la pestaña "Global Properties" --> "App Settings"

2.- Para pasar números a letras te copio el código para que lo pegues a un archivo con extensión tpl

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
#TEMPLATE(RH3,'Template para conversión números a letras'),Family('ABC')
#EXTENSION(Global_Num_Let,'Extensión global para incluir Números a Letras'),APPLICATION
#SHEET
   #TAB('NUMALET')
     #display('')
     #Display('Agregar la función NumeroaLetra en esta aplicación')
     #Display('')
     #Display('Uso:')
     #Display('Donde se requiera la conversión,')
     #Display('Utilizar la función')
     #Display('VarString=NumeroaLetra(Valor)')
     #Display('')
     #Display('Adaptado a template y modificado por: ')
     #Display('Ing. Ramón Hernández D.')
     #Display('Email:ramonh@vel.com.mx')
     #Display('Modificado para manejar pesos')
   #ENDTAB
#ENDSHEET
 
#ATSTART
  #DECLARE(%ModuloNumalet)
  #set(%ModuloNumalet,CLip(Left(%Program,LEN(Clip(%Program))-5)))
  #SET(%ModuloNumalet,CLIP(LEFT(%ModuloNumalet,4))&'_NAL')
#ENDAT
 
#AT(%CustomGlobalDeclarations)
  #PROJECT(%ModuloNumalet&'.CLW')
#ENDAT
 
#AT(%GlobalMap)
  #INSERT(%GeneradorModuloNumalet)
  #INSERT(%GeneradorIncludeNumalet)
#ENDAT
#!--------------------------------------------------------------------
#GROUP(%GeneradorModuloNumalet)
#MESSAGE('Generando Módulo:    '& %ModuloNumalet&'.CLW',1)
#MESSAGE('Generando módulo Numalet',2)
#MESSAGE('',3)
#CREATE(%ModuloNumalet&'.$$$')
   MEMBER('%Program')
#INSERT(%ImplementacionNumalet) 
#CLOSE(%ModuloNumalet&'.$$$')
#REPLACE(%ModuloNumalet&'.CLW',%ModuloNumalet&'.$$$')
#REMOVE(%ModuloNumalet&'.$$$')
#!-----------------------------------------------------------------------
#GROUP(%GeneradorIncludeNumalet)
  MODULE('%'ModuloNumalet.CLW')
   #Insert(%ProtoNumalet)
  END
#!-----------------------------------------------------------------------
#GROUP(%ProtoNumalet)
NumeroaLetra(REAL),STRING
#!----------------------------------------------------------------------
#GROUP(%ImplementacionNumalet)
NumeroaLetra PROCEDURE (Numero)

ModuloMillones       LONG
Centimos             REAL
Unidadess            REAL
Decenas              REAL
Centenas             REAL
Valor                REAL
SinCientos           REAL
Respuesta            STRING(255)
Modulo               STRING(34)
Parcial              STRING(34)
D_Unidades_G         STRING(210)
D_Unidades           STRING(10),DIM(21),OVER(D_Unidades_G)
D_Decenas_G          STRING(72)
D_Decenas            STRING(9),DIM(8),OVER(D_Decenas_G)
D_Centenas_G         STRING(117)
D_Centenas           STRING(13),DIM(9),OVER(D_Centenas_G)
  CODE
  D_Unidades_G = 'CERO      ' |        !Carga de Unidades
               & 'UN        ' |
               & 'DOS       ' |
               & 'TRES      ' |
               & 'CUATRO    ' |
               & 'CINCO     ' |
               & 'SEIS      ' |
               & 'SIETE     ' |
               & 'OCHO      ' |
               & 'NUEVE     ' |
               & 'DIEZ      ' |
               & 'ONCE      ' |        ! Y de primera decena
               & 'DOCE      ' |
               & 'TRECE     ' |
               & 'CATORCE   ' |
               & 'QUINCE    ' |
               & 'DIECISEIS ' |
               & 'DIECISIETE' |
               & 'DIECIOCHO ' |
               & 'DIECINUEVE' |
               & 'VEINTE    '
  D_Decenas_G =  'VEINTI   ' |         !Carga de Decenas
               & 'TREINTA  ' |
               & 'CUARENTA ' |
               & 'CINCUENTA' |
               & 'SESENTA  ' |
               & 'SETENTA  ' |
               & 'OCHENTA  ' |
               & 'NOVENTA  '
  D_Centenas_G = 'CIENTO       ' |     !Carga de Centenas
               & 'DOSCIENTOS   ' |
               & 'TRESCIENTOS  ' |
               & 'CUATROCIENTOS' |
               & 'QUINIENTOS   ' |
               & 'SEISCIENTOS  ' |
               & 'SETECIENTOS  ' |
               & 'OCHOCIENTOS  ' |
               & 'NOVECIENTOS  '
!--------------------------------------------------------------------------
  Clear(Respuesta)
  Valor = INT(Numero)
  Centimos = (Numero - Valor) * 100                        !Centavos
  Valor = INT(Centimos+  0.01)
  IF INT(NUMERO)=1 THEN
     Respuesta = ' PESO '  & FORMAT(Valor,@N02) & '/100 M.N.'
  ELSE 
     Respuesta = ' PESOS ' & FORMAT(Valor,@N02) & '/100 M.N.'
  END
 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

  Valor = INT (Numero - (INT(Numero / 1000) *1000))        !Unidades

  If Valor = 1 AND CENTIMOS<>0 Then
    Respuesta = 'UN '   & Clip (Respuesta)
  ELSIF Valor = 0 Then
    Respuesta = 'CERO ' & Clip (Respuesta)
  ELSIF Valor <> 0 Then
    Do Calc_Modulo
    Respuesta = Clip (Modulo) &' '&Clip (Respuesta)
  END

  Valor = INT (Numero / 1000) - (INT(Numero / 1000000) * 1000)  !Miles

  If Valor = 1 Then
    Respuesta = 'MIL '&Clip (Respuesta)
  ElsIf Valor <> 0 Then
    Do Calc_Modulo
    Respuesta = Clip (Modulo) &' MIL '&Clip (Respuesta)
  end
  ModuloMillones=Numero % 1000000  !RHD*** si es cero son millones redondos
  Valor = INT (Numero / 1000000)   !Millones
  If Valor = 1 Then
    if MOduloMIllones >0
     Respuesta = 'UN MILLON '&Clip (Respuesta)
    else
     Respuesta = 'UN MILLON DE '&Clip (Respuesta)
    end
  ElsIf Valor <> 0 Then
    Do Calc_Modulo
    if ModuloMillones >0
     Respuesta = Clip (Modulo) &' MILLONES '&Clip (Respuesta)
    else
     Respuesta = Clip (Modulo) &' MILLONES DE '&Clip (Respuesta)
    end
  end
  Return(Respuesta)

!---------------------------------------------------------------------------
Calc_Modulo        ROUTINE
  If valor = 100 Then
    Modulo = 'CIEN'
  Else
    Do Calc_Parcial
    IF Valor > 100 Then
      Valor = int(Valor / 100)
      If SinCientos = 0 Then
        Modulo = Clip(D_Centenas[Valor])
      Else
        Modulo = Clip(D_Centenas[Valor]) &' '& Clip(Parcial)
      end
    Else
      Modulo = Clip(Parcial)
  end
  end

!---------------------------------------------------------------------------
Calc_Parcial       ROUTINE

  Centenas = Int(Valor/100)
  Decenas  = INT(Valor/10) - Centenas*10
  Unidadess = Valor - (Decenas*10) - (Centenas*100) +1
  SinCientos = (Decenas*10)+ Unidadess - 1

  Case SinCientos

     Of 0 to 20
       Parcial = Clip(D_Unidades[SinCientos+1])

     Of 21 to 99
       If Unidadess = 1 Then
         Parcial = Clip(D_Decenas[Decenas-1])
       ElsIF Decenas > 2 Then
         Parcial = Clip(D_Decenas[Decenas-1]) & ' Y '& Clip(D_Unidades[Unidadess])
       Else
         Parcial = Clip(D_Decenas[Decenas-1]) & Clip(D_Unidades[Unidadess])
       end

  end

 #!--------------------------------------------------------------------------------------------
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar