FoxPro/Visual FoxPro - CONTABILIZAR DIAS

*

*

*  WEEKDAYS.PRG

*  Return the number of days that are MONDAY - FRIDAY

*  in the passed date range.

*  ERROR 11 when called with incorrect parameters.

*

*  Author:

*  Mike Yearwood,

*      with input from various

*      UniversalThread members.

*  Martina Jindrova for the DATETIME modifications.

*

*  USAGE:

*    ?WEEKDAYS({^2004-05-01},{^2004-05-31})

*

*  OR:

*    m.ldFrom = {^2004-05-01}

*    m.ldTo = {^2004-05-31}

*    m.lnWeekdays = WEEKDAYS(m.ldFrom, m.ldTo)

*    ?"The number of weekdays is: " + ALLTRIM(STR(m.luWeekdays)) + "."

*

*  RETURNS:

*    A numeric value for the number of weekdays.

*

*  lParameters

*     tdFrom (R)     Start of the date range.

*     tdTo   (R)     End of the date range.

*

LPARAMETERS m.tdFrom, m.tdTo

IF INLIST(VARTYPE(m.tdFrom),"D","T") AND INLIST(VARTYPE(m.tdTo),"D","T")

ELSE

  ERROR 11

ENDIF

LOCAL ;

  m.lnDays, ;

  m.lnDOW

*Determine the total possible number of days.

m.lnDays = ABS(IIF(VARTYPE(m.tdFrom)="D",m.tdFrom,TTOD(m.tdFrom)) -;

               IIF(VARTYPE(m.tdTo)="D",m.tdTo,TTOD(m.tdTo))) + 1

*Determine the number of the day of the week.

m.lnDOW = DOW(MIN(m.tdFrom,m.tdTo),2)

*Subtract the weekend (Sat/Sun) days (2 of every 7).

*Also remove the difference between the

*"start" date and the closest Monday.

RETURN m.lnDays - INT(m.lnDays / 7) * 2 ;

	- IIF( m.lnDOW = 7, ;

	     SIGN(m.lnDays % 7), ;

	     SIGN(m.lnDOW - 7 + (m.lnDays % 7)) + 1)