FoxPro/Visual FoxPro - cambiar nombre de un archivo pdf desde un form de vfp9

   
Vista:

cambiar nombre de un archivo pdf desde un form de vfp9

Publicado por celso omar yo_28_2@yahoo.com.ar (31 intervenciones) el 24/03/2014 19:15:06
hola buenos dias:
estoy necesitando de su valiosa ayuda ya que estoy desarrollando una pequeña aplicación que me permita cambiar el nombre de un archivo desde un textbox. este archivo esta alojado en un directorio del disco C ej
Carchivo de programas\archivos recibidos.
mi idea es lo siguiente tengo 3 textbox
text1: ruta en la que se encuentra el archivo.
text2: nombre del archivo
text3: que me permita cambiar el nombre del archivo que figura en el text2.

es en estos puntos donde estoy trabado les agradecería muchísimo su valioso aporte.
desde ya muchas gracias
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

cambiar nombre de un archivo pdf desde un form de vfp9

Publicado por Fidel José (558 intervenciones) el 25/03/2014 13:30:17
Supongamos que tenemos en un form, 3 textbox y dos commandbutton (cmdGetfile y cmdRename)
Las funciones que se necesitan: JustPath(), JustFname() y File()
Los comandos que se necesitan: RENAME
Las referencias utilizadas son This.Parent en lugar de Thisform, para permitir que el código funcione sin cambios dentro de un Container o Page de un pageframe.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
*<Funciones y Comandos>
* JustPath(), JustFName(), File() , RENAME
*</Funciones y Comandos>
 
*<cmdGetFile.Click>
* Lee un archivo del disco y rellena los cuadros de texto
* Puede reemplazarse por un parámetro si se convierte en un método o procedure
*----------------------------------------------------------------------------------------------------------------
LOCAL lcFile
lcFile=GETFILE()
IF EMPTY(lcFile)
	RETURN
ENDIF
WITH this.Parent
	.text1.value=JUSTPATH(lcfile)
	.text2.Value=JUSTFNAME(lcFile)
	.text3.value=JUSTFNAME(lcFile)
ENDWITH
*</cmdGetFile.Click>
 
*<cmdRename.Click>
* Renombrar el archivo
LOCAL lcOriginal,lcRename,lcAchieve
IF EMPTY(this.Parent.text1.Value) OR EMPTY(this.Parent.text3.Value)
	RETURN
ENDIF
lcOriginal=ADDBS(ALLTRIM(this.Parent.text1.Value))+ALLTRIM(this.Parent.text2.Value)
lcRename=ADDBS(ALLTRIM(this.Parent.text1.Value))+ALLTRIM(this.Parent.text3.Value)
 
* Si la ruta o el nombre de archivo tienen espacios
* debemos encomillar, de lo contrario dará error.
IF AT(CHR(32),lcOriginal)>0
	lcOriginal=["]+lcoriginal+["]
ENDIF
IF AT(CHR(32),lcRename)>0
	lcREname=["]+lcRename+["]
ENDIF
* Renombrando
RENAME &lcOriginal TO &lcRename
 
* Resultado obtenido
lcAchieve=IIF(FILE(lcRename),"Exito","falla")
MESSAGEBOX("Resultado="+lcAchieve)
*</cmdRename.Click>
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
1
Comentar

cambiar nombre de un archivo pdf desde un form de vfp9

Publicado por celso melo yo_28_2@yahoo.com.ar (31 intervenciones) el 26/03/2014 22:17:06
"UN MILLÓN DE GRACIAS" . ES JUNTO LO QUE NECESITABA. GRACIAS POR TU PRONTA RESPUESTA A MI PREGUNTA,
Y SI NO ES MUCHO PEDIR QUISIERA SABER SI HAY ALGUNA FORMA DE IMPRIMIR ESE MISMO ARCHIVO ".PDF" UNA VEZ MODIFICADO SU NOMBRE PERO SIN TENER QUE ABIRLO DESDE LA CARPETA DE ORIGEN.
DESDE YA TE ESTOY MUY AGRADECIDO POR TU RESPUESTA
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

crear subcarpetas

Publicado por celso melo (31 intervenciones) el 06/04/2014 22:54:43
Hola buenos dias estimado amogo del foro continuando con la solucion que valiosamente me proporcionaste, si no es mucha molestia tengo una inquietud mas.
necesito crear una subcarpeta la cual estara ubicada segun la ruta que indique en un textbox. ej:
Text1:C:\TFCO MM(s) SITM2\RX\PUBLICO\04 ABRIL 2014\03 dende 03 es la carpeta a crear. y correponde al dia 03
necesito crear esta carpeta todos los dias manualmente pata q la aplicaion me guarde los archivo en este subdirectorio y si no lo cree no me guara el archivo ya que no encuantra la carpeta correspondiente al dia 03.

tengo una tabla en la cual guardo las rutas y dia a dias las actualiso desde su formulario, mi idea es q al actualizar esta basede datos me cree automaticamente una carpeta corresondiente al dia asi no tengo que ir hasta el subdirectorio y creala manualmente.
estuveintentando crearla con mkdir, pero se me complica al momento de intentar que me tome los valores del text1 con el dia actualizado y me cree la carpeta.
nuevamente gracias por el valioso aporte que me brindaste, Saludos.-
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar