FoxPro/Visual FoxPro - como copiar imágenes desde una lista de txt

LOCAL lcRoot,;

	lcFilePict,;

	lcString,;

	i,;

	lnCount,;

	lcTargetFolder,;

	lnFilesCopy,;

	loFso as Object

LOCAL ARRAY lafiles(1)

* Estos valores seguramente serán parámetros

* o valores alojados en alguna parte.

lcRoot = "c:\theodore\graphics"

lcfilePict = ADDBS(lcRoot)+"MyFilePict.txt"

lcTargetFolder = "c:\theodore\graphics\jpg"

lnCount = 0

*<Genera_escenario_de_prueba>

	* El archivo txt ya estará generado en producción.

	lcString = ""

	lnFiles = ADIR(laFiles,ADDBS(lcRoot)+"*.jpg","",1)

	FOR i= 1 TO lnFiles

		lcSTring = m.lcSTring ;

			+ laFiles[i,1] + CHR(13)+CHR(10)

	NEXT

	STRTOFILE(m.lcSTring, m.lcFilePict)

*</Genera_escenario_de_prueba>

*<Funcionamiento>

	* Crea objeto FileSystem

	loFso = NEWOBJECT("Scripting.FileSystemObject")

	* Comprueba Existencia de Carpeta

	IF !loFso.FolderExists(m.lcTargetFolder)

		loFso.CreateFolder(m.lcTargetFolder)

	ENDIF

	* Crea un array (laFiles) con el contenido del archivo de texto m.lcFilePict

	lnFilesCopy = ALINES(laFiles,FILETOSTR(m.lcFilePict),1+4,CHR(9),CHR(10),CHR(13))

	* Copia lo que se necesario

	FOR i = 1 TO m.lnfilesCopy

		lcSourceFile = ADDBS(lcRoot)+lafiles[i]

		lcTargetFile = ADDBS(lcTargetFolder) + laFiles[i]

		* Comprueba que exista el archivo Source

		* Comprueba que no exista ya en destino

		* Esto se puede mejorar comparando la antigüedad para

		* el caso en que exista en ambas carpetas.

		* Pero para ello conviene hacer una función o método separado.

		IF loFso.FileExists(m.lcSourceFile) AND ;

			!loFso.FileExists(m.lcTargetFile)

			loFso.CopyFile(m.lcSourceFile , ADDBS(m.lcTargetFolder))

			lnCount = m.lnCount + 1

		ENDIF

	NEXT

	loFso = null

*</Funcionamiento>

*<Opcional>

	MESSAGEBOX(TRANSFORM(lnCount)+" Files Copyied")

*</Opcional>