FoxPro/Visual FoxPro - CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Jaime Javier Ortiz (63 intervenciones) el 17/01/2011 22:18:29

HOLA A TOD@S:

GRACIAS PROGRAMADORES POR SU COLABORACION Y POR ESTE FORO DONDE SIEMPRES E DISCUTEN TEMAS IMPORTANTES Y SE APRENDEN NUEVAS COSAS.

ME GUSTARIA QUE ME AYUDARAN CON UNA DIFICULTAD QUE TENGO PARA CREAR UN ARCHIVO PLANO CON UNA LINEA DE TITULOS AL PRINCIPIO DEL ARCHIVO DESPUES DE LA LINEA DE NOMBRES DE LA TABLA, DE LA SIGUIENTE MANERA:

NOMBRE APELLIDO TELEFONO --------->Nombre de los campos de la tabla
nombres apellidos telefono -------------->Nombres crados en el plano
pedro roa 12545
ana paz 98776
luis castro 54584

El archivo anterior lo creo como CSV, separado por comas y me lo crea de la siguiente manera:

"NOMBRE","APELLIDO","TELEFONO"
"nombres","apellidos","telefono"
"pedro"," roa","12545"
"ana ","paz","98776"
"luis","castro","54584"

Me lo crea corectamente, pero lo necesito separado por comas y sin comillas dobles asi:

NOMBRE,APELLIDO,TELEFONO
nombres,apellidos,telefono
pedro,roa,12545
ana,paz,98776
luis,castro,5458

ESPERO SU GRANDIOSA COLABORACION Y GRACIAS POR SU AYUDA.

SALUDOS

JAIME O.

Valora esta pregunta

Me gusta: Está pregunta es útil y esta clara

No me gusta: Está pregunta no esta clara o no es útil

Responder

Pos: 30

Val: 29

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Javier (271 intervenciones) el 19/01/2011 14:12:00

Hola, prueba este comando, a lo mejor te sirve:

COPY TO archivo.txt DELIMITED WITH ","

El problema es que no incluye el nombre de los campos como primera línea.
-------------------------------------------------------------------------------------------------------------

Por otro lado podes hacer algo asi tambien (si es necesario que los nombres de los campos estén en la primera fila ) ( Con ayuda de : http://support.microsoft.com/kb/113278/es )

Este código crea una tabla temporal con un campo memo, almacena el contendio del archivo de texto CSV en ese campo, luego reemplaza las comillas por cadena nula (con strtran) y lo guarda en cTempo y por último, con COPY MEMO genera un nuevo archivo.txt con el mismo nombre que el original (el nombre puede ser otro, obvio)

USE TUTABLA

COPY TO texto1.txt TYPE CSV

CREATE TABLE AUXILIAR ( CAMPOMEMO m(10) )

APPEND BLANK

APPEND MEMO CAMPOMEMO FROM texto1.txt OVERWRITE

cTempo = STRTRAN( CAMPOMEMO , '"', '' )

REPLACE CAMPOMEMO WITH cTempo

COPY MEMO CAMPOMEMO TO texto2.txt

Puede que tenga limitiaciones con respecto al tamaño de texto1.txt.

Probalo y si podes comentanos como te fue.

Javier (Jujuy, Argentina)
Saludos.

Valora esta respuesta

Me gusta: Está respuesta es útil y esta clara

No me gusta: Está respuesta no esta clara o no es útil

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Jaime Javier Ortiz (63 intervenciones) el 19/01/2011 20:52:34

HOLA MI AMIGO JAVIER, GRACIAS POR TU APOYO Y BUENA VOLUNTAD PARA AYUDARME CON ESTA SITUACION.

NO ENTIENDO ESTA PARTE DONDE TU ESCRIBES:
APPEND MEMO CAMPOMEMO FROM texto1.txt OVERWRITE

PORQUE ESCRIBES ANTES DE FROM, LAS PALABRAS MEMO Y CAMPOMEMO?

POR FAVOR TE AGRADEZCO LA AYUDA PARA TERMINAR DE ENTERDER Y SOLUCIONAR ESTA SITUACION.

SALUDOS.

JAIME O.

Valora esta respuesta

Comentar

Pos: 30

Val: 29

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Javier (271 intervenciones) el 20/01/2011 15:59:59

Hola:

APPEND MEMO CAMPOMEMO FROM texto1.txt OVERWRITE

APPEND MEMO es el comando que toma el contenido de un archivo de texto (texto1.txt)
y la "almacena" en un campo de tipo memo (yo le puse de nombre CAMPOMEMO, fijate más arriba en donde se crea, con CREATE TABLE , la tabla dbf de nombre AUXILIAR).

OVERWRITE es necesario para que lo que agregue de texto1.txt , "sobreescriba" el contenido anterior, si hubiere.

Te comento línea x línea el código que te pasé:

USE TUTABLA
*Abre la tabla cuyos datos quieres generar a txt

COPY TO texto1.txt TYPE CSV
*Copia el contenido de tutabla en formato txt (con los nombres de los campos como primera línea).

CREATE TABLE AUXILIAR ( CAMPOMEMO m(10) )
*Crea una tabla de nombre auxiliar con un único campo llamado CAMPOMEMO de tipo MEMO). Este comando deja abierta la tabla auxiliar.dbf

APPEND BLANK
*Agrega un registro en blanco en la tabla auxiliar.dbf

APPEND MEMO CAMPOMEMO FROM texto1.txt OVERWRITE
*Guarda en el campo de tipo memo llamado CAMPOMEMO, el contenido del archivo de texto de nombre texto1.txt, credo con COPY TO texto1.txt TYPE CSV

cTempo = STRTRAN( CAMPOMEMO , '"', '' )
* El campo COMPOMEMO ya tiene el contenido de texto1.txt . La función strtran toma el valor del CAMPOMEMO , "elimina" las comillas de ese valor contenido y los guarda ya "convertido" en la variabla cTempo. Es decir strtran "devuelve", en cTempo, el contenido del campo memo sin las comillas.

REPLACE CAMPOMEMO WITH cTempo
* Se reemplaza el valor de CAMPOMEMO con el valor de cTempo

COPY MEMO CAMPOMEMO TO texto2.txt
* Copia el valor de CAMPOMEMO en un archivo de texto (texto2.txt)

Espero que esté un poco más claro.

Suerte.

Valora esta respuesta

Comentar

Pos: 30

Val: 29

OTRA FORMA (tomando idea de santiago)

Publicado por Javier (271 intervenciones) el 20/01/2011 16:35:43

Jaime, fijate en esta forma, quizas tambien te sirve. La idea es usar el comando SET ALTERNATE para grabar en un archivo lo que habitualmente verías en pantalla usando el comando ? o ??.
SET CONSOLE OFF desactiva la visualización en pantalla de los ?, ??
Te recomiendo que consultas la ayuda de VFP, ahí te vas a despejar más rápido las dudas que tengas de algunos comandos como SET ALTERNATE y funciones como fcount() , field(), el operador &, etc.

Saludos.(Le puse unos puntos al principio de las líneas para que veas mejor el código, ya que los espacios se eliminan al publicar la nota.)

SET ALTERNATE TO texto1.txt
SET ALTERNATE on

SET CONSOLE OFF

CLOSE DATABASES

USE TuTabla

* Este ciclo manda al archivo los nombres de los campos de la tabla
FOR nI = 1 TO FCOUNT()
...?? FIELD( nI )
...IF nI < FCOUNT()
......?? ","
... ENDIF
NEXT

DO WHILE ! EOF()
...?
...FOR nI = 1 TO FCOUNT()
......cCampo = FIELD( nI)
......?? &cCampo
.......IF nI < FCOUNT()
..........?? ","
.......ENDIF
...NEXT

...SKIP

ENDDO

SET CONSOLE ON

SET ALTERNATE off
SET ALTERNATE TO

CLOSE DATABASES

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por jesus (2 intervenciones) el 08/05/2012 08:03:13

Esta es la solución que me funcionó. Estuve pasando trabajo con este problema y gracias a lo planteado por Javier me funcionó excelente.

Mil gracias

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Fernando (3 intervenciones) el 22/02/2013 23:19:52

Esta excelente" Gracias expertos, prácticamente me salvaron el pellejo haha,

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por CELSO OMAR (31 intervenciones) el 07/06/2014 03:03:53

hola como estas:
estuve leyendo tus respuestas y necesito algo parecido a lo que publicaste: necesito copiar varios archivos .txt en uno solo pero como me van llegando de a uno necesito que no se me sobrescriban y si es posible que cada archivo que se vayan agregando al txt estén separados por "****" o "________" así e los pueda separar.
desde ya muchas gracias por cualquier aporte que me puedas facilitar

Valora esta respuesta

Comentar

Pos: 2

Val: 1.011

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por Fidel José (558 intervenciones) el 07/06/2014 17:34:17

Básicamente, puede ser algo así:

*joinTExt

LOCAL tcNewFile

tcNewFile="JoinTExt.txt"

LOCAL lcdir,lnFiles,lnSource,lnTarget,i,lcTarget,lcSource

* Buscar carpeta

lcdir=GETDIR(FULLPATH(""),"Carpeta de txt","Juntando Archivos",48)

IF EMPTY(lcDir)

	RETURN

ENDIF

LOCAL ARRAY lafiles(1)

*Obtiene todos los archivos de la carpeta con extensión "txt"

lnFiles=ADIR(laFiles,ADDBS(lcdir)+"*.txt")

IF lnFiles=0

	MESSAGEBOX("No hay archivos txt en "+lcdir)

	RETURN

ENDIF

* Apertura o creación del archivo de destino en bajo nivel

lcTarget=ADDBS(lcDir)+FORCEEXT(tcNewFile,"txt")

IF !FILE(lcTarget)

	lnTarget=FCREATE(lcTarget)

ELSE

	lnTArget=FOPEN(lcTarget,12)

ENDIF

IF lnTarget = -1

	MESSAGEBOX("No se pudo abrir o crear el archivo de destino")

	RETURN

ENDIF

* Proceso de agreagado.

FOR i=1 TO lnFiles

	lcSource=ADDBS(lcDir)+laFiles[i,1]

	IF UPPER(lcSource)==UPPER(lcTarget)

		LOOP

	ENDIF

	lnSource=FOPEN(lcsource)

	IF lnSource= -1

		MESSAGEBOX("No se pudo abrir "+lcSource)

		RETURN

	ENDIF

	FSEEK(lnTarget,0,2)

	=FPUTS(lnTarget,"<"+JUSTSTEM(lcSource)+">")

	DO WHILE !FEOF(lnSource)

		=FPUTS(lnTarget,FGETS(lnsource))

	ENDDO

	=FCLOSE(lnSource)

	=FPUTS(lnTarget,"</"+JUSTSTEM(lcSource)+">")

ENDFOR

=FCLOSE(lnTarget)

* Renombrar los archivos con *.bak

FOR i=1 TO lnLines

	lcSource=ADDBS(lcDir)+laFiles[i,1]

	IF UPPER(lcSource)==UPPER(lcTarget)

		LOOP

	ENDIF

	lcRename=FORCEEXT(ADDBS(lcDir)+lcSource,".bak")

	RENAME &lcSource TO &lcRename

ENDFOR

* Mostrar el resultado con NotePad.exe

o = CREATEOBJECT("Shell.Application")

o.ShellExecute("notepad.exe", LcTarget, "", "open", 1)

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por celso omar (31 intervenciones) el 11/06/2014 15:24:14

hola como estas:
ante todo quiero agradecerte por la pronta respuesta y pedir disculpas por mi demora, probé la rutina que me mandaste funciona bien pero a partit de esta linea: Renombrar los archivos con *.bak me salta un cartel que dice que la expresión no es numérica.
una vez mas quiero agradecerte por tu pronta respuesta y predisposición.-

Valora esta respuesta

Comentar

Pos: 2

Val: 1.011

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por Fidel José (558 intervenciones) el 11/06/2014 23:18:45

Omar
Fijate en esta línea
lcSource=ADDBS(lcDir)+laFiles[i,1] && +laFiles[ i , el número uno ]

Digo esto porque mirando el código ese número uno puede parecer una letra "L" minúscula.
Se refiere a la primer columna del array laFiles. La columna uno tiene los nombres de los archivos.

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por celso omar (31 intervenciones) el 12/06/2014 00:04:53

hola, nuevamente te agradezco mucho tu pronta respuesta y el aporte q brindas a este foro ni bien lo pruebo y te aviso como me fue.
gracias por tu aporte, un abraso.-

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por celso omar (31 intervenciones) el 16/06/2014 12:38:37

hola como estas: disculpa nuevamente la tardanza, estuve probando la corrección que me recomendaste y funciono a la perfección, te agradezco de todo corazón tu aporte a este foro y tu activa colaboración, DIOS BENDIGA tu sabiduría.-

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por celso omar (31 intervenciones) el 20/06/2014 00:31:57

Hola como estas:
tengo una pequeña consulta mas para hacer.
tengo un text1 al que le doy valor numérico desde el formulario a este text no escribo nada sino que tomo un valor que tengo en un archivo .txt al que llamo numerador, y funciona lo mas bien el tema es que una vez que cargo el numero al text1 desde un botón comando este campo pasa automáticamente a convertirse en caracter o sea de estar posicionado a la derecha del text1 pasa a la izquierda del mismo y me impide realizar sumas ya que lo utilizo como contador.
desde ya muchas gracias por los aportes que me brindaste.-

Valora esta respuesta

Comentar

Pos: 2

Val: 1.011

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por Fidel José (558 intervenciones) el 21/06/2014 13:39:43

Si obtienes un valor de un archivo Txt, ese valor siempre será un Character, no importa su apariencia.
Por ejemplo:
* Archivo.txt (1 sola linea)
<Contador>118</Contador>
* ------------------------------------eof

LOCAL lcFile,lcTag,lcNum,lnNum

lcFile="Archivo.txt"

lcTag=FileToStr(lcFile)

MESSAGEBOX(lcTag)

lcNum=StrExtract(lcTag,"<Contador>","</Contador>")

lnNum=VAL(lcNum)        && convertimos el valor obtenido en un número

MESSAGEBOX("lcNum="+lcNum+" Vartype="+VARTYPE(lcNum);

	+CHR(13);

	+"lnNum="+TRANSFORM(lnNum)+" Vartype="+VARTYPE(lnNUm))

Thisform.txtContador.Value=lnNum

Nota: En un entorno compartido no deberían usarse archivos txt para conservar valores tales como numeradores y otros temas de control de datos, porque no tienes la posibilidad de abrirlos en forma compartida. Deberías crear un administrador de turnos. En cambio no ofrecen problemas para uso exclusivo, por lo que suelen utilizarse para configuración de interface.

Valora esta respuesta

Comentar

cerrar un archivo .pdf desde vfp 9

Publicado por omar (31 intervenciones) el 19/07/2014 05:11:11

HOLA BUENAS NOCHES INTEGRANTES DEL FORO QUISIERA SABER SI ALGUIEN ME PUEDE AYUDAR A RESOLVER UN PROBLEMITA QUE TENGO. TENGO UN PROGRAMA QUE HICE EN VFP 9 QUE PROCESA UNOS ARCHIVO .PDF QUE SE DESCARGAN EN LA CARPETA C:\TEMP, LOS COPIA A OTRA CARPETA Y LOS RENOMBRA Y FUNCIONA MUY BIEN SALVO QUE LOS ARCHIVOS PDF QUE TENGO EN LA CARPETA TEMP A MEDIDA QUE VAN LLEGANDO SE ACUMULAN Y ME DIFICULTAN LA UBICACIÓN DEL ARCHIVO RECIENTE. PARA EVITAR ESTO DESIDI ELIMINARLOS PERO LO HACE SOLO CON LOS QUE NO ESTAN ABIERTO, NO LO PUEDO HACER MIENTRAS ESTÉN ABIERTOS.
MI CONSULTA OBRE ESTE TEMA ES SI HAY UNA FORMA DE CERRAR EL ARCHIVO .PDF ABIERTO PERO DESDE VFP. ASI DESDE EL PROGRAMA LO CIERRA UNA VEZ QUE LO PROCESA Y LO ELIMINA PARA EVITAR QUE SE ACUMULEN EN LA CARPETA.
DESDE YA MUCHAS GRACIAS POR EL GRAN APORTE QUE BRINDAN A ESTE FORO.-

Valora esta respuesta

Comentar

copiar archivos txt en otro txt sin que se sobreescrivan

Publicado por omar (31 intervenciones) el 30/07/2014 17:49:50

hola buenos dias. quisiera saber si hay alguna forma de poder contar las cantidades de lineas que contiene un archivo .txt desde vfp 9 y que el resultado se refleje en un textbox o en un messgebox.-
desde ya muchas gracias por el gran aporte que brindas a este foro.-

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por IGNACIO ALVITES AIQUIPA (1 intervención) el 15/11/2016 00:20:11

gracias por la ayuda, solamente necesitaba que como imprimir el campo memo en archivo de txt

COPY MEMO CAMPOMEMO TO texto2.txt

gracias.

Valora esta respuesta

Comentar

Pos: 51

Val: 20

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Bibiana (12 intervenciones) el 16/01/2020 01:24:21

Gracias!!! Tantos años después, sigues ayudando amigo. Muchas Gracias.

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por santiago (1 intervención) el 19/01/2011 14:59:15

set printer to archivo.txt

do while not eof()
@prow(), 0 say "NOMBRE"+","+"APELLIDO"+","+"TELEFONO"
@prow()+1,0 say NOMBRE+","+APELLIDO+","+TELEFONO
skip
enddo

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Jaime Javier Ortiz (63 intervenciones) el 19/01/2011 21:20:38

HOLA SANTIAGO, GRACIAS POR RESPONDER Y APOYARME.
LA VERDAD QUE NO ENTENDI LO QUE ME QUERIAS DECIR.

GRACIAS POR TU BUENA INTENCIO DE AYUDARME.

SALUDOS
JAIME O.

Valora esta respuesta

Comentar

Pos: 252

Val: 2

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Edgar Zambrano (72 intervenciones) el 31/01/2011 16:13:27

llave esta es la forma de generar archivos planos sin las comillas dobles, espero te sea de gran utilidad.
*
* definicion de variables locales
LOCAL xLinea && obtiene la linea de texto a imprimir
STORE 0 TO l && contador de lineas
*
* selecciono cursor
SELECT (_cAlias)
*
* dirijo el resultado a un archivo de texto
SET DEVICE TO FILE plano.txt
*
* recorrer hasta el final
SCAN FOR !EOF()
*
* obtengo la linea a imprimir
xLinea = NOMBRE+","+APELLIDO+","+TELEFONO
*
* imprimo la linea
@l,0 say xLinea
*
* incremento contador de lineas
l=l+1
ENDSCAN
*
* restauro resultado
SET DEVICE TO SCREEN

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por EDWIN7904 (1 intervención) el 16/08/2012 16:08:54

Una forma mas facil seria

copy to nombre_arcivo.TXT type delimited with "" with character ";"

Funciona .....

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Elkin Jimenez (1 intervención) el 13/02/2013 17:25:34

La primera Solucion

Asunto: RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES
Autor: Javier (90 intervenciones)
Fecha: 20/01/2011 15:59:59

Excelente Hermano funciona Perfectamente Gracias

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Javier Torres (3 intervenciones) el 07/08/2013 18:57:23

GRacias,,!!! EXCELENTE APORTE!! miles de minutos al año, nos acabas de ahorrar

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por RafoSoft (1 intervención) el 13/02/2014 20:41:03

¿Les ha sucedido que cuando crearon el txt solo permitió hasta 2,185 filas?

Eso es porque utilizaron :

SET DEVICE TO PRINTER
SET PRINTER TO (cfile)

SCAN
@ fil, 0 SAY ... etc ...

Para resolverlo, utilicen :

SET CONSOLE OFF
SET ALTERNATIVE (file)
SET ALTERNATIVE ON

...

Saludos.

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por Ramon Alvarez (1 intervención) el 04/02/2016 16:43:15

Excelente respuesta funciona y crea el archivo sin las comillas en los campos tipo caracter... muchas gracias.

Valora esta respuesta

Comentar

RE:CREAR ARCHIVO PLANO SIN COMILLAS DOBLES

Publicado por JAVIER Y (1 intervención) el 26/03/2019 15:13:38

EDWIN7904, tu aporte es excelente, he resuelto un problema con tu gran ayuda, saludos!

Valora esta respuesta

Comentar

do while

postgres y vfp9 - error en conexiones