Visual Basic para Aplicaciones - Problema con Worksheet_SelectionChange en Excel

Life is soft - evento anual de software empresarial
   
Vista:

Problema con Worksheet_SelectionChange en Excel

Publicado por Joel (9 intervenciones) el 31/08/2007 17:32:38
Mi problema es con la macro Select_Row_Column, si la pruebo sola Funciona perfecto, pero al integrarla en Sub Worksheet_SelectionChange ya no hace lo que tiene que hacer

Debe de seleccionar una columna y una fila completas tomando como referencia la celda activa, pero al integrarla en Worksheet_SelectionChange pierde la referencia y seleciona otra fila ¿? alguien puede decirme que es lo que esta pasando

Anexo el código, agradeciendo su apoyo!

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Call Select_Row_Column
End Sub

Sub Select_Row_Column()

Dim lugar2 As String
Dim CntCadena As Long
Dim Compara As String
Dim Chango As String
Dim PosRenglon As Long

PosRenglon = ActiveCell.Row
'Este procedimiento devuelve la posicion de la columna con carateres
'por ejemplo devuelve "A" en lugar de 1 si esta seleccionada una celda en A

lugar2 = ActiveCell.Address(False, False)
Chango = "Entrar"
Do
CntCadena = Len(lugar2)
Compara = Right(lugar2, 1)
Select Case Compara
Case 0 To 9
lugar2 = Left$(lugar2, CntCadena - 1)
Case Else
Chango = "salir"
End Select
Loop Until Chango = "salir"


'seleciona toda la columna correspondiente a la celda seleccionada
'y todo el renglon de la selda seleccionada
ActiveSheet.Range(lugar2 & ":" & lugar2 & "," & PosRenglon & ":" & PosRenglon & "," & lugar2 & PosRenglon).Select
ActiveSheet.Range(lugar2 & PosRenglon).Activate

End Sub
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:Problema con Worksheet_SelectionChange en Excel

Publicado por JuanC (243 intervenciones) el 31/08/2007 23:23:29
Option Explicit

Private bFlg As Boolean

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If bFlg Then Exit Sub
Call Select_Row_Column
End Sub

Private Sub Select_Row_Column()
bFlg = True
With ActiveCell
Union(.EntireRow, .EntireColumn).Select
.Activate
End With
bFlg = False
End Sub

Saludos desde Baires, JuanC
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Problema con Worksheet_SelectionChange en Excel

Publicado por Joel (9 intervenciones) el 04/09/2007 17:31:43
Muchas gracias

Funciono a la perfeccion!
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar