RE:(CREAR) CONEXION ODBC DESDE VISUAL BASIC 6, URG
Esto si funciona, pruebenlo por favor. Espero que les sirva.
Procedimientos paso a paso
1. Abra un proyecto nuevo Visual Basic. Se creará Form1 de manera predeterminada Colocado un CommandButton en Form1 (Command1) y coloca el código siguiente en la sección Declaraciones generales del código para Form1: Option Explicit
Private Const REG_SZ = 1 'Constant for a string variable type.
Private Const HKEY_LOCAL_MACHINE = &H80000002
Private Declare Function RegCreateKey Lib "advapi32.dll" Alias _
"RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, _
phkResult As Long) As Long
Private Declare Function RegSetValueEx Lib "advapi32.dll" Alias _
"RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, _
ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal _
cbData As Long) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" _
(ByVal hKey As Long) As Long
2. Incluya el código siguiente en el evento Click del botón Command1 en Form1:
Cambie los valores de las variables de Nombredeorigendedatos, de DatabaseName, de Descripción, de DriverPath, de LastUser y de Servidor de acuerdo con su entorno. Cualquiera de los controladores enumerados en la ficha Controladores ODBC de la ventana Administrador de orígenes de datos ODBC se pueden usar como parte de la variable DriverPath. Todos estos controladores se pueden encontrar en equipos de Windows 95 para de C:\Windows\System o Windows 98 y Windows NT para de C:\Winnt\System32. Private Sub Command1_Click()
Dim DataSourceName As String
Dim DatabaseName As String
Dim Description As String
Dim DriverPath As String
Dim DriverName As String
Dim LastUser As String
Dim Regional As String
Dim Server As String
Dim lResult As Long
Dim hKeyHandle As Long
'Specify the DSN parameters.
DataSourceName = "<the name of your new DSN>"
DatabaseName = "<name of the database to be accessed by the new DSN>"
Description = "<a description of the new DSN>"
DriverPath = "<path to your SQL Server driver>"
LastUser = "<default user ID of the new DSN>"
Server = "<name of the server to be accessed by the new DSN>"
DriverName = "SQL Server"
'Create the new DSN key.
lResult = RegCreateKey(HKEY_LOCAL_MACHINE, "SOFTWARE\ODBC\ODBC.INI\" & _
DataSourceName, hKeyHandle)
'Set the values of the new DSN key.
lResult = RegSetValueEx(hKeyHandle, "Database", 0&, REG_SZ, _
ByVal DatabaseName, Len(DatabaseName))
lResult = RegSetValueEx(hKeyHandle, "Description", 0&, REG_SZ, _
ByVal Description, Len(Description))
lResult = RegSetValueEx(hKeyHandle, "Driver", 0&, REG_SZ, _
ByVal DriverPath, Len(DriverPath))
lResult = RegSetValueEx(hKeyHandle, "LastUser", 0&, REG_SZ, _
ByVal LastUser, Len(LastUser))
lResult = RegSetValueEx(hKeyHandle, "Server", 0&, REG_SZ, _
ByVal Server, Len(Server))
'Close the new DSN key.
lResult = RegCloseKey(hKeyHandle)
'Open ODBC Data Sources key to list the new DSN in the ODBC Manager.
'Specify the new value.
'Close the key.
lResult = RegCreateKey(HKEY_LOCAL_MACHINE, _
"SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources", hKeyHandle)
lResult = RegSetValueEx(hKeyHandle, DataSourceName, 0&, REG_SZ, _
ByVal DriverName, Len(DriverName))
lResult = RegCloseKey(hKeyHandle)
End Sub
3. Ejecute el proyecto y haga clic en el botón de comando Command1. A continuación, abra el Administrador de orígenes de datos ODBC desde el Panel de control (o Herramientas de administrador en Windows 2000). Su DSN nuevo aparecerá junto con los DSN de otro sistema que ya ha creado.