RESPUESTA A LA PREGUNTA 539 DE VISUAL FOXPRO


** Prueba.prg
 
OLDGENPD  = _GENPD
OLDSETUP  = _PDSETUP
 
_GENPD="GENRICPD.APP"
_PDSETUP="Generic"

SET CONSOLE OFF
SET DEVICE TO PRINTER
SET PRINTER TO LPT1
SET PRINTER ON
 
@ 1, 1 SAY CHR(27)+"C"+CHR(22)   && Jump Each  22 lines
FOR R=1 TO 3
 @ PROW()+1, 20 SAY "ROBERT MARTINEZ"
 @ 0, 0 SAY ""
ENDFOR 
 
SET DEVICE TO SCREEN
SET PRINTER OFF
set console on
set printer to
set printer to
_GENPD   = OLDGENPD  
_PDSETUP = OLDSETUP  
 
 
 
Pone en un Proyecto lo siguiente.
 
  *
  * GENRICPD.PRG -  
  *
  PARAMETERS calltype,pdname
  PRIVATE retval
  IF PARAMETERS()=0   &&Called from CONFIG.FP(W)
    calltype=0
    pdname=""
  ENDIF
  IF calltype=2       &&Called from FPD Report/Label Setup
    RETURN IIF(EMPTY(pdname),"Generic","")    &&Toggle
  ENDIF
  retval=""
  IF pdname="?"       &&Called from FPD File/Printer Setup Menu Option
    retval=IIF(EMPTY(_PDSETUP),"Generic","")  &&Toggle
  ELSE
    retval="Generic"
  ENDIF
  _PDRIVER=""         &&Close current Printer Driver (calls PDONUNLOAD)
  IF NOT EMPTY(retval)  
    PUBLIC _PDPARMS[3]
    _PDPARMS[1]="Generic"
    _PDPARMS[2]=.F.      &&PdPageEnd() just executed?
    _PDPARMS[3]=.F.      &&PdLineEnd() just executed?
    _PDRIVER="GENRICDV.PRG"  &&Open Printer Driver (calls PDONLOAD if exists)
  ENDIF
  _PDSETUP="-"+retval    &&The "-" prevents a recursive call to GENRICPD again
  RETURN retval
 
  
 
 
Crea el siguiente programa y lo adiciona al proyecto
  *
  * GENRICDV.PRG - Generic Printer Driver Procedures/Functions
  *
  PROCEDURE PdOnUnload
    RELEASE _PDPARMS
  RETURN
 
  FUNCTION PdDocSt
  PARAMETERS height,width
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.F.
  RETURN ""
 
  FUNCTION PdPageSt
    PRIVATE ctlchars
    ctlchars=IIF(_PDPARMS[2],CHR(12)+CHR(13),"")
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.F.
  RETURN ctlchars
 
  FUNCTION PdPageEnd
    _PDPARMS[2]=.T.
    _PDPARMS[3]=.F.
  RETURN ""
 
  FUNCTION PdLineSt
    PRIVATE ctlchars
    ctlchars=IIF(_PDPARMS[3],CHR(13)+CHR(10),"")
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.F.
  RETURN ctlchars
 
  FUNCTION PdLineEnd
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.T.
  RETURN ""
 
  FUNCTION PdAdvPrt
    PARAMETERS here,there
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.F.
  RETURN IIF(here>there,CHR(13)+SPACE(there),SPACE(there-here))
 
  FUNCTION PdObject
  PARAMETERS theobj,objstyle
    _PDPARMS[2]=.F.
    _PDPARMS[3]=.F.
  RETURN theobj

Haces a GENRICPD.PRG  el programa principal del proyecto y nombra el proyecto como
genridcpd.app y tendras un control total sobre la impresora, podras imprimir directo
y con los fuentes de la impresora, esto lo utilizo para imprimir facturas, recibos y
comprobante en impresoras matriciales que requieren de una velocidad que los driver
de windows no me la pueden dar.


ROBERT
soluciones64@codetel.net.do