RESPUESTA A LA PREGUNTA 974 DE VISUAL BASIC

Para crear un programa en segundo plano con un icono en el systray tienes
que crear un exe normal y ocultar la ventana. Para poner el icono aqui está
el código que puedes modificar, estudiar y usar a tu preferencia.
 
1) Agrega este codigo en la sección de declaración.
 
Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias _
"Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As _
NOTIFYICONDATA) As Long
 
Public Type NOTIFYICONDATA
    cbSize As Long
    hwnd As Long
    uID As Long
    uFlags As Long
    uCallbackMessage As Long
    hIcon As Long
    szTip As String * 64
End Type
 
Public Const NIM_ADD = &H0
Public Const NIM_MODIFY = &H1
Public Const NIM_DELETE = &H2
Public Const NIF_MESSAGE = &H1
Public Const NIF_ICON = &H2
Public Const NIF_TIP = &H4
 
Public Const NIF_DOALL = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
 
Public Const WM_MOUSEMOVE = &H200
Public Const WM_LBUTTONDBLCLK = &H203
Public Const WM_LBUTTONDOWN = &H201
Public Const WM_RBUTTONDOWN = &H204  

2) Agrega un formulario al proyecto y anexale el siguiente código
Public Sub CreateIcon()
Dim Tic As NOTIFYICONDATA
Tic.cbSize = Len(Tic)
Tic.hwnd = Picture1.hwnd
Tic.uID = 1&
Tic.uFlags = NIF_DOALL
Tic.uCallbackMessage = WM_MOUSEMOVE
Tic.hIcon = Picture1.Picture
Tic.szTip = "Visual Basic Demo Project" & Chr$(0)
erg = Shell_NotifyIcon(NIM_ADD, Tic)
End Sub
 
Public Sub DeleteIcon()
Dim Tic As NOTIFYICONDATA
Tic.cbSize = Len(Tic)
Tic.hwnd = Picture1.hwnd
Tic.uID = 1&
erg = Shell_NotifyIcon(NIM_DELETE, Tic)
End Sub      
3) Agrega dos botones (command1 y command2) y un picture box (picture1) al
formulario.  Selecciona un uicono para la propiedad picture.
 
Agrega el siguiente código a el evento click de Command1.
CreateIcon      

Agrega el siguiente código a el evento click de Command2.
DeleteIcon      

Agrega el siguiente código a el evento MouseMove de Picture1.
X = X / Screen.TwipsPerPixelX  
Select Case X
Case WM_LBUTTONDOWN
Caption = "Left Click"
Case WM_RBUTTONDOWN
Caption = "Right Click"
Case WM_MOUSEMOVE
Caption = "Move"
Case WM_LBUTTONDBLCLK
Caption = "Double Click"
End Select      
4) Ejecuta el proyecto presiona los botones y pasa el puntero del mouse sobre
el icono que debe aparecer en el systray.
 
Si tienes alguna pregunta más epecífica puedes escribirme.


Angel Elía
overpack@mixmail.com