RE:Manejo de Impresora Fiscal Bixolon 350 en acces
Es una impresora de matríz de punto o de impacto, ¿cierto? de ser así lo mejor para dimensionar margenes, tamaños de papel específicos, etiquetas, etc, es un trozo de código en VBA que viene en la ayuda de éste lenguaje en la parte de módulos.
Ejemplo
El siguiente ejemplo de la propiedad PrtMip muestra cómo configurar el informe con dos columnas horizontales.
Private Type str_PRTMIP
strRGB As String * 28
End Type
Private Type type_PRTMIP
xLeftMargin As Long
yTopMargin As Long
xRightMargin As Long
yBotMargin As Long
fDataOnly As Long
xWidth As Long
yHeight As Long
fDefaultSize As Long
cxColumns As Long
yColumnSpacing As Long
xRowSpacing As Long
rItemLayout As Long
fFastPrint As Long
fDatasheet As Long
End Type
Public Sub PrtMipCols(ByVal strName As String)
Dim PrtMipString As str_PRTMIP
Dim PM As type_PRTMIP
Dim rpt As Report
Const PM_HORIZONTALCOLS = 1953
Const PM_VERTICALCOLS = 1954
' Open the report.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
PrtMipString.strRGB = rpt.PrtMip
LSet PM = PrtMipString
' Create two columns.
PM.cxColumns = 2
' Set 0.25 inch between rows.
PM.xRowSpacing = 0.25 * 1440
' Set 0.5 inch between columns.
PM.yColumnSpacing = 0.5 * 1440
PM.rItemLayout = PM_HORIZONTALCOLS
' Update property.
LSet PrtMipString = PM
rpt.PrtMip = PrtMipString.strRGB
Set rpt = Nothing
End Sub
El siguiente ejemplo de la propiedad PrtMip muestra cómo establecer los márgenes a 1 pulgada.
Public Sub SetMarginsToDefault(ByVal strName As String)
Dim PrtMipString As str_PRTMIP
Dim PM As type_PRTMIP
Dim rpt As Report
' Open the report.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
PrtMipString.strRGB = rpt.PrtMip
LSet PM = PrtMipString
' Set margins.
PM.xLeftMargin = 1 * 1440
PM.yTopMargin = 1 * 1440
PM.xRightMargin = 1 * 1440
PM.yBotMargin = 1 * 1440
' Update property.
LSet PrtMipString = PM
rpt.PrtMip = PrtMipString.strRGB
Set rpt = Nothing
End Sub
Desifra el código y trata de entender como funciona, un poco de paciencia que vale la pena. Desconecta las lines de código que no utilices. Debes transformar las pulgadas a centimetros. Te recomiendo usar la fuente "fast font" para una impresión rápida.
Así te olvidas de configurar las hojas y margenes con los cuadros de diálogo de access que no son muy exactos.