Access - Toma de datos para dni/nif/nie

Private Sub DNINIE_KeyPress(KeyAscii As Integer)

    Const CarValidos = "0123456789XYZ"

    Dim Letra As String * 1

    'Si estamos en la primera posición y se pulsa una tecla de carácter

    If Me.DNINIE.SelStart = 0 And KeyAscii > 31 Then

        'Si no es uno de los caracteres válidos

        If InStr(1, CarValidos, Chr(KeyAscii)) = 0 Then

            'Anulamos la pulsación

            KeyAscii = 0

            'Aquí se puede poner algún tipo de mensaje

        End If

            'Si es la última posición

    ElseIf Me.DNINIE.SelStart = 8 And KeyAscii > 31 Then

        'Calculamos la letra por medio de una función

        Letra = CálculoLetra(Left(Me.DNINIE.Text, 8))

        'Si la letra no coincide con la que hemos pulsado

        If Letra <> UCase(Chr(KeyAscii)) Then

            'Anulamos la pulsación

            KeyAscii = 0

        End If

    End If

End Sub

Private Function CálculoLetra(DNI As String) As String

    Dim nDNI As Long

    'Estas son las letras que corresponden a los 23 restos

    Const Letras = "TRWAGMYFPDXBNJZSQVHLCKE"

    DNI = Left(DNI, 8) 'Nos quedamos con los primeros 8 caracteres

    nDNI = Val(DNI) 'Asignamos el valor numérico

    'Si es 0 es que empieza por letra

    If nDNI = 0 Then

        'Asignamos el valor numérico desde el segundo carácter más

        'el valor de la letra

        nDNI = Val(Mid(DNI, 2)) + (Asc(Left(DNI, 1)) - 88) * 10000000#

    End If

    'Devolvemos la letra correspondiente al resto del valor del DNI

    'al dividirlo entre 23

    CálculoLetra = Mid(Letras, (nDNI Mod 23) + 1, 1)

End Function