Access - Saldo por Cliente

Private Sub cmdSaldos_Click()

'---Requiere tener registrada la referencia "Microsoft DAO 3.6 Object Library"

'---o biblioteca equivalente---------------------------------------------------

        'Declaramos las variables

    Dim rst As DAO.Recordset

    Dim vIng As Currency, vGto As Currency

    Dim vSaldo As Currency

    Dim miSql As String

        'Creamos la consulta para ordenar los movimientos por fecha

    miSql = "SELECT * FROM TMovimientos ORDER BY TMovimientos.Fecha"

            'Inicializamos vSaldo

    vSaldo = 0

        'Creamos el recordset sobre la SQL

    Set rst = CurrentDb.OpenRecordset(miSql)

        'Si no hubiera registros saltamos a Salida

    If rst.RecordCount = 0 Then GoTo Salida

        'Iniciamos el proceso de actualización de [Saldo]

    With rst

        .MoveFirst

        Do Until .EOF

                'Cogemos el valor del ingreso. Si no hay valor hacemos que el valor por defecto sea cero

            vIng = Nz(.Fields("Ingreso").Value, 0)

                'Cogemos el valor del gasto. Si no hay valor hacemos que el valor por defecto sea cero

            vGto = Nz(.Fields("Gasto").Value, 0)

                'Calculamos el saldo del movimiento

            vSaldo = vSaldo + vIng - vGto

                'Escribimos dicho valor en la tabla

            .Edit

            .Fields("Saldo").Value = vSaldo

            .Update

                'Nos movemos al siguiente registro

            .MoveNext

        Loop

    End With

        'Cerramos el formulario actual

    'DoCmd.Close acForm, Me.Name

        'Abrimos FMovUpdated con la información actualizada en vista sólo lectura

    DoCmd.OpenForm "FMovUpdated", , , , acFormReadOnly

Salida:

        'Cerramos conexiones y liberamos memoria

    rst.Close

    Set rst = Nothing

End Sub