Access - Insertar una imagen desde VBA

Hola.

Sabe alguien como se puede insertar un objeto OLE en una tabla desde código de VBA ?.

Es facil hacerlo desde el menú insertar. Pero desde código ?

Saludos

Hola
He aqui una solucion que automatiza el proceso de incrustado,
Dim sFoto as string
' * Aqui puede usarse un InputBox() o un campo independiente
sFoto = "C:\Mis Imagenes\FOTO.BMP"
' * Verifica que la foto exista, de no existir no hace nada
If Len(Dir(sFoto)) > 0 Then
' * Para poder usar el campo desbloqueamos
Me.FOTO.Locked = False
' * No hay OLE Incrustado?
If Me.FOTO.OLEType = acOLENone Then
' *Si vas a usar solo BMP o PCX no hace llamar la clase indicada
' *en la siguiente linea, en cambio para usar JPG o GIF debes
' *usar la clase correspondiente por ejemplo Photo Edit.
' *Me.FOTO.Class = "Paint.Picture"
' * Apuntamos a la imagen
Me.FOTO.SourceDoc = sFoto
' * Le decimos que es incrustado
Me.FOTO.OLETypeAllowed = acOLEEmbedded
' * Actualizamos nuestro campo
Me.FOTO.Action = acOLECreateEmbed
Else
' * El campo tiene un OLE que ha sido creado antes
' * Esto es util si tienes una foto mas reciente que quieras
' * actualizar en tu base de datos
Me.FOTO.SourceDoc = sFoto
' * Entonces solo actualizamos la imagen
Me.FOTO.Action = acOLEUpdate
End If
' * Bloqueamos para no editarlo con el boton derecho del raton
Me.FOTO.Locked = True
End If

Este proceso lo incluyes por ejemplo en un evento como AlActivarRegistro()o en un boton personalizado o donde tu creas conveniente

Saludos, espero que te sirva el ejemplo

excelente ejemplo mi hermano funciona a la perfeccion