Excel - Aportacion: Suma Condicional

 
Vista:

Aportacion: Suma Condicional

Publicado por Raziel (245 intervenciones) el 05/12/2011 21:18:23
He notado estos dias una pregunta muy recurrente en el foro, sumar dependiendo de mas de una condicion, a continuacion pondre una tabla de datos y los usos que le podriamos dar a la funcion SUMAPRODUCTO para sacarnos del apuro, aclaro, talvez lo mismo se podria hacer con otras formulas, solo ejemplifico el potencial que esta funcion tiene.

A1 01/01/2011 B1 ALFA C1 3
A2 02/01/2011 B2 BRAVO C2 5
A3 03/01/2011 B3 CHARLIE C3 2
A4 01/02/2011 B4 CHARLIE C4 -7
A5 02/02/2011 B5 ALFA C5 5
A6 03/02/2011 B6 BRAVO C6 4
A7 01/03/2011 B7 BRAVO C7 6
A8 02/03/2011 B8 CHARLIE C8 1
A9 03/03/2011 B9 ALFA C9 -8

Casos
Solo enero:
=SUMAPRODUCTO((MES(A1:A9)=1)*C1:C9)

Solo febrero y marzo:
=SUMAPRODUCTO(((MES(A1:A9)=2)+(MES(A1:A9)=3))*C1:C9)

Todo menos febrero:
=SUMAPRODUCTO((MES(A1:A9)<>2)*C1:C9)

Solo enero y marzo:
=SUMAPRODUCTO(((MES(A1:A9)=1)+(MES(A1:A9)=3))*C1:C9)

Del 02.ene al 02.feb:
=SUMAPRODUCTO((A1:A9>=FECHANUMERO("2/1/2011"))*(A1:A9<=FECHANUMERO("2/2/2011"))*C1:C9)

Solo dia 1 de cada mes:
=SUMAPRODUCTO((DIA(A1:A9)=1)*C1:C9)

Solo dia 1 y ALFA:
=SUMAPRODUCTO((MES(A1:A9)=1)*(B1:B9="ALFA")*C1:C9)

Solo ALFA:
=SUMAPRODUCTO((B1:B9="ALFA")*C1:C9)

Cantidades menores o iguales a 5:
=SUMAPRODUCTO((C1:C9<=5)*C1:C9)


Mi pequeño aporte, espero que sea de utilidad
Saludos.
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

Aportacion: Suma Condicional

Publicado por Angel Rodriguez (5 intervenciones) el 15/12/2011 16:53:54
Buenos dias amigo,
La mejor opcion es usar el complemento de suma condicional, que lo puedes activar por las opciones en el menu herramienta....

Saludos
Angel rodriguez
Caracas - Venezuela
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar