Excel - sacar texto mayor de una fila

tengo la siguiente lista

3075GX A
7573VC A
7578VC A
7579VC A
7570VC A
7575VC A
7572VC A
7583VT
7574VT
7581VT
7571VC A
7587VC A


como pueden ver contiene números y letras y necesito saber cual es el valor mayor y cual el menor de esta lista sin ordenarla o si la ordena que lo haga internamente solamente para sacar el primer valor ascendente y el ultimo, me podrían ayudar

Muy buenas.

Mira a ver si te sirve esta fórmula matricial:

=K.ESIMO.MENOR(VALOR(IZQUIERDA(A1:A12;4));1)

Como es matricial, tienes que copiarla, tal como está, en la barra de fórmulas, y en vez de validar con "INTRO", validarla con "CONTROL+MAYUSCULAS+INTRO"

Un saludo. Juanjo.

Gracias Juanjo
ya puse la formula si me sale el numero mayor al que corresponde ya solo me falta agregarle el resto del texto y contemplar que hay datos que tienen 3 o 2 números no siempre son 4

Muy buenas.

Para lo que quieres, resultaría más fácil utilizar columnas auxiliares, pero bueno, como ya ha sido cuestión de amor propio, he intentado hacerlo con una única fórmula. El resultado es este:

=INDIRECTO(DIRECCION(COINCIDIR(K.ESIMO.MENOR(SI(CODIGO(EXTRAE(A1:A12;4;1))<58;VALOR(IZQUIERDA(A1:A12;4));SI(CODIGO(EXTRAE(A1:A12;3;1))<58;VALOR(IZQUIERDA(A1:A12;3));VALOR(IZQUIERDA(A1:A12;2))));1);SI(CODIGO(EXTRAE(A1:A12;4;1))<58;VALOR(IZQUIERDA(A1:A12;4));SI(CODIGO(EXTRAE(A1:A12;3;1))<58;VALOR(IZQUIERDA(A1:A12;3));VALOR(IZQUIERDA(A1:A12;2))));0);1))

Esto tiene un problema, y es que solo vale para un número determinado de datos (en este caso 12), pero si añadieras o quitaras datos, tendrías que andar cambiando la fórmula (El “A1:A12” por “A1:Ax”) en los 10 sitios en que aparece.
Para solucionar esto puedes hacer lo siguiente:
-Creas un nombre llamado ambito con esta fórmula:
=DESREF(Hoja1!$A$1;0;0;CONTARA(Hoja1!$A:$A);1)
Luego la fórmula que te dé el resultado sería esta:
=INDIRECTO(DIRECCION(COINCIDIR(K.ESIMO.MENOR(SI(CODIGO(EXTRAE(ambito;4;1))<58;VALOR(IZQUIERDA(ambito;4));SI(CODIGO(EXTRAE(ambito;3;1))<58;VALOR(IZQUIERDA(ambito;3));VALOR(IZQUIERDA(ambito;2))));1);SI(CODIGO(EXTRAE(ambito;4;1))<58;VALOR(IZQUIERDA(ambito;4));SI(CODIGO(EXTRAE(ambito;3;1))<58;VALOR(IZQUIERDA(ambito;3));VALOR(IZQUIERDA(ambito;2))));0);1))

Tanto en este caso, como en el anterior, se trata de una fórmula matricial, por lo que tienes que tenerlo en cuenta a la hora de validarla.

Para el obtener el mayor valor solo tienes que cambiar “K.ESIMO.MENOR” por “K.ESIMO.MAYOR”

Un saludo. Juanjo.

Gracias juanjo, voy a hacer la prueba y te digo resultados.

eres muy amable