Iniciar sesiónCerrar
Correo:
Contraseña:
Entrar
Recordar sesión en este navegador
Iniciar sesiónIniciar sesiónCrear cuentaCrear cuenta
LWP » Foros » Excel » Solucionar error Value

Excel - Solucionar error Value

Volver
Nuevo Tema
<<>>
 
Vista:
sin imagen de perfil

Solucionar error Value

Publicado por Emma (12 intervenciones) el 15/05/2025 15:10:11
Hola,

Muy buenos dias, esperro que se encuentren muy bien.

Tengo un file con varias formulas.

En la colunma "I" tengo los datos principales. El tema es que tengo varios cirterios de busqueda para resultados:

1 US&Canada = -
2 To Review = -
3 Trusly = -
4 941888 = 311201941888
5 943884 = 311201943884
6 903885 = 311162903885
7 Cualquier dato que no este dentro de la lista anterior = -

Tengo una formula pero me esta dando un error de Value que no se como resolverlo.

=+IFERROR(IF(K2="US&Canada","-",IFERROR(IF(SEARCH("941888",I2)>0,"311201941888","Not Found"),IF(SEARCH("943884",I2)>0,"311201943884","Not Found"))),IF(K2="To Review","-",IFERROR(IF(SEARCH("903885",I2)>0,"311162903885","Not Found"),IF(SEARCH("-",I2)>0,"-","Not Found"))))

Si me pudiesen ayudar a corregir el error de la formula o bien alguna nueva formula que solucione este error se los agradeceria mucho.

Adjunto el file para que puedan ver el mismo
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder
Imágen de perfil de Antoni Masana
Val: 4.908
Oro
Ha mantenido su posición en Excel (en relación al último mes)
Gráfica de Excel

Solucionar error Value

Publicado por Antoni Masana (2547 intervenciones) el 15/05/2025 23:20:28
Te explico la formula.

Basicamente la formula es esta:

1
2
3
4
5
6
= SI(K2 = "US&Canada"      ; "-"             ;
  SI(K2 = "To Review"      ; "-"             ;
  SI(K2 = "Trusly"         ; "-"             ;
  SI(HALLAR("941888";I2)>0 ; "311201941888") ;
  SI(HALLAR("943884";I2)>0 ; "311201943884") ;
  SI(HALLAR("903885";I2)>0 ; "311162903885") ; "Not Found")))))

El Else del 1º Si es el 2º Si.
El Else del 2º Si es el 3º Si.
El Else del 3º Si es el 4º Si.
El Else del 4º Si es el 5º Si.
El Else del 5º Si es el 6º Si.
El Else del 6º Si es el Texto "Not found"

Hasta aquí bien, pero la función hallar si no encuentra el texto NO devuelve CERO devuele un error.

Lo solucionamos así:

1
2
3
4
5
6
= SI(K2 = "US&Canada"               ; "-"             ;
  SI(K2 = "To Review"               ; "-"             ;
  SI(K2 = "Trusly"                  ; "-"             ;
  SI.ERROR(SI(HALLAR("941888";I2)>0 ; "311201941888") ;
  SI.ERROR(SI(HALLAR("943884";I2)>0 ; "311201943884") ;
  SI.ERROR(SI(HALLAR("903885";I2)>0 ; "311162903885") ; "Not Found"))))))))

Ahora el SI(HALLAR() no tiene ELSE. Si se cumple la condición del HALLAR pone el valor y si da error salta al siguiente sI.ERROR

Podemos hacerlo de otra forma. Cambiamos la condición del SI:

1
SI.ERROR(HALLAR("941888";I2)>0;0)

Esta condicion devuel VEDADERO si HALLAR encuenta el texto o FALSO si da error, porque 0=FALSO

1
2
3
4
5
6
= SI(K2 = "US&Canada"                  ; "-"            ;
  SI(K2 = "To Review"                  ; "-"            ;
  SI(K2 = "Trusly"                     ; "-"            ;
  SI(SI.ERROR(HALLAR("941888";I2)>0;0) ; "311201941888" ;
  SI(SI.ERROR(HALLAR("943884";I2)>0;0) ; "311201943884" ;
  SI(SI.ERROR(HALLAR("903885";I2)>0;0) ; "311162903885" ; "Not Found")))))

Y para acaba podemos simplificar los tres primeros SI porque el resultado es el mismo

1
2
3
4
= SI(O(K2 = "US&Canada" ; K2 = "To Review" ; K2 = "Trusly") ; "-" ;
  SI.ERROR(SI(HALLAR("941888";I2)>0 ; "311201941888") ;
  SI.ERROR(SI(HALLAR("943884";I2)>0 ; "311201943884") ;
  SI.ERROR(SI(HALLAR("903885";I2)>0 ; "311162903885") ; "Not Found"))))))))


1
2
3
4
= SI(O(K2 = "US&Canada" ; K2 = "To Review" ; K2 = "Trusly") ; "-" ;
  SI(SI.ERROR(HALLAR("941888";I2)>0;0) ; "311201941888" ;
  SI(SI.ERROR(HALLAR("943884";I2)>0;0) ; "311201943884" ;
  SI(SI.ERROR(HALLAR("903885";I2)>0;0) ; "311162903885" ; "Not Found")))))

Saludos.
\\//_
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
1
Comentar
sin imagen de perfil

Solucionar error Value

Publicado por Emma (12 intervenciones) el 15/05/2025 23:47:49
Muchisimas gracias; ya con lo que me enviaste se soluciono por completo la formula
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar