FoxPro/Visual FoxPro - Modificar tabla desde cuadro de comandos

TRY

	LOCAL i,lnFields,;

		lcEnd_tag,;

		lcfield_Tag,;

		lcRooler,;

		lcValidation_Rool,;

		lxValue,lcVartype,lcType,lnLenght,lcPadl,lxDefault_Value,;

		loex as Exception

	*<simulando cursor importado>

	CREATE CURSOR curImport ;

	("A" N(8,0),;

	"B" C(8),;

	"C" N(10,4))

	INSERT INTO CURIMPORT (A,B,C) ;

		VALUES (7485, "20170128", 2436.1548)

	INSERT INTO CURIMPORT (A,B,C) ;

		VALUES (748, "20170131", 7684.368)

	INSERT INTO CURIMPORT (A,B,C) ;

		VALUES (9768, "20170215", 5440.28)

	*<crear cursor con campos correctos>

	CREATE CURSOR curCorrect ;

	("ID_" c(6),;

	"Fecha" d, ;

	"Importe" n(12,2))

	*<Regla de Validación>

	lcValidation_rool = "<field:1><type>C</type><lenght>6</lenght><padl>0</padl></field>" ;

			+"<field:2><type>D</type></field>"  ;

			+"<field:3><type>N</type><lenght>12</length><decimal>2</decimal></field>"

	*<Recorrer archivo importado>

	lcEnd_Tag = "</field>"

	SELECT curImport

	lnFields = AFIELDS(curImport)

	DIMENSION laValues(m.lnFields)

	SCAN

		laValues = null

		FOR i = 1 TO m.lnFields

			lxValue = EVALUATE(FIELD(i))

			lcVartype = VARTYPE(m.lxValue)

			lcfield_Tag = "<field:"+TRANSFORM(i)+">"

			lcRooler = STREXTRACT(m.lcValidation_rool,m.lcField_Tag,m.lcEnd_tag)

			IF !EMPTY(m.lcRooler)

				lcType = STREXTRACT(m.lcRooler,"<type>","</type>")

				lnLenght = VAL(STREXTRACT(m.lcRooler,"<lenght>","</lenght>"))

				lnDecimal = VAL(STREXTRACT(m.lcRooler,"<decimal>","</decimal>"))

				lcPadl = STREXTRACT(m.lcRooler,"<padl>","</padl>")

				lxDefaul_Value = ICASE(m.lcType="C","",;

									lcType$'IN',0,;

									lcType = "D",{},;

									lcType = "T",{//::},;

									lctype = "L",.F.)

				DO CASE

					CASE m.lcVartype = "N" AND m.lctype = "C"

						lxValue = ;

							IIF(EMPTY(m.lcPadl),;

								TRANSFORM(m.lxValue),;

								PADL(TRANSFORM(m.lxValue),m.lnLenght,m.lcPadl))

					CASE m.lcVartype = "C" AND m.lcType = "N"

						lxValue = VAL(m.lxValue)

					CASE m.lcVartype = "N" AND m.lctype = "N"

						lxValue = ROUND(lxValue,m.lnDecimal)

					CASE m.lcVartype = "C" AND m.lcType = "C"

						lxValue = ALLTRIM(m.lxValue)

					CASE m.lcVartype = "C" AND m.lcType = "D"

						lxValue = DATE(VAL(LEFT(m.lxValue,4)),;

									VAL(SUBSTR(m.lxValue,5,2)),;

									VAL(RIGHT(m.lxvalue,2)))

					OTHERWISE

						lxValue = m.lxDefaul_Value

				ENDCASE

			ENDIF

			laValues[i] = m.lxValue

		NEXT

		INSERT INTO curCorrect FROM ARRAY laValues

	ENDSCAN

	SELECT curImport

	BROWSE

	SELECT curCorrect

	BROWSE

CATCH TO loex

	loex.UserValue = PROGRAM()

	*ShowERror(loex)

FINALLY

	IF USED("curIMport")

		USE IN curimport

	ENDIF

	IF USED("curCorrect")

		USE IN curCorrect

	ENDIF

ENDTRY