FoxPro/Visual FoxPro - VER CONECCION DE RED EN VFP

* Rutina de inicio del sistema

LOCAL loObjREsp as Object,;

	lcFolder_InServer,lcFileName,;

	lcString,;

	lQuit

* En la carpeta local de inicio tendrás algún archivo o tabla

* donde está guardado el acceso al servidor.

* Acá supongo que es un archivo de texto llamado "server_access.cfg" y tiene una tag:

* <folder>\\central\theodore</folder>

* lcFileName puede ser constante

lcFileName = "plancon\control.dbf"	&& en este caso está en una subcarpeta

IF FILE("server_access.cfg")

	lcFolder_InServer = STREXTRACT(FILETOSTR("server_access.cfg"),"<folder>","</folder>")

ENDIF

loObjResp = thisform.test_server(m.lcFolder_InServer, m.lcFileName)

IF VARTYPE(loObjREsp)="O"

	IF loObjResp.REsult

                * Si el resultado es exitoso, se graba el archivo "server_acces.cfg"

		STRTOFILE("<folder>"+loObjResp.Root+"</folder>","server_access.cfg")

	ELSE

		lQuit = .t.  && lo único razonable para hacer si no se puede establecer la conexión.

	ENDIF

ENDIF

loObjResp = null

IF m.lQuit

	QUIT	&& no hay qué hacer, más que salir del sistema

ENDIF

PROCEDURE Test_Server

*---------------------------------------------------

LPARAMETERS tcRoot_Server,tcFileTest

TRY

	LOCAL loFso as Object,;

		loex as Exception,;

		lcFileName_Test as String,;

		lcMessage as String,;

		lDoit as Boolean,;

		lnMess as Number,;

		loResp as Object

	loResp = NEWOBJECT("Empty")

	ADDPROPERTY(loResp,"Result",.f.)

	ADDPROPERTY(loResp,"Root",m.tcRoot_Server)

	loFso = NEWOBJECT("Scripting.FileSystemObject")

	*<solo para la prueba>

		tcRoot_Server = EVL(m.tcRoot_Server, "\\Server_Name\Shared_resource\Folder_Name")

		tcFileTest = EVL(m.tcFileTest,"control.dbf")

	*</solo para la prueba>

	lcFileName_Test = ADDBS(m.tcRoot_Server)+m.tcFileTest

	lcMessage = "Ruta Indefinida"

	ldoit = !EMPTY(m.tcRoot_Server)

	IF m.lDoit

		lcMessage = "No se encuentra la ruta "+m.tcRoot_Server

		lDoit = loFso.FolderExists(ADDBS(m.tcRoot_Server))

	ENDIF

	IF m.lDoit

		lcMessage = "La carpeta indicada no parece el destino correcto"+CHR(13);

				+ "TestFile="+m.lcFileName_Test

		lDoit = loFso.fileExists(m.lcFileName_Test)

	ENDIF

	IF !m.lDoit

		DO WHILE .t.

			lcMessage = m.lcMessage + CHR(13) ;

				+ "Desea buscar la ruta de acceso?"

			lnMess = MESSAGEBOX(m.lcMessage,4,"Mensage de Sistema")

			IF m.lnMess # 6

				EXIT

			ENDIF

			tcRoot_Server=GETDIR(FULLPATH(""),"Carpeta de archivos del sistema","Sistema » Ubicación de los Datos",16+32+64)

			IF !EMPTY(m.tcRoot_Server)

				lcFileName_Test = ADDBS(m.tcRoot_Server)+m.tcFileTest

				lcMessage = "La carpeta indicada no parece el destino correcto"+CHR(13);

					+ "TestFile="+m.lcFileName_Test

				lDoit = loFso.fileExists(m.lcFileName_Test)

				IF m.lDoit

					lcMessage = ""

					EXIT

				ENDIF

			ENDIF

		ENDDO

	ENDIF

	loResp.result = m.lDoit

	loResp.Root = m.tcRoot_Server

CATCH TO loex

	loex.UserValue = PROGRAM()

	ShowError(loex)

	lDoit = .f.

FINALLY

	loFso = null

ENDTRY

RETURN loResp