FoxPro/Visual FoxPro - Sumar columnas de grid: y mostrar el resultado en otra columna

PROCEDURE show_Sum_InColumn

*---------------------------

LPARAMETERS toGrid,tcListColumn,tnColumnSum

*!*	toGrid			Referencia al objeto grid	(Object)

*!*	tcListColumn	        Lista de números de columnas (1,3,4,etc) (Character)

*!*	tcColumnSum		Número de Columna donde se muestra la suma de columnas (numeric)

*!*					Si se omite, intenta sumar en la última columna

*!*

TRY

	LOCAL lnColumns,;

		i,;

		lnSuma,;

		lnRecno,;

		loex as Exception

	LOCAL ARRAY laColumns(1)

	IF VARTYPE(toGrid)="O"

		tnColumnSum = EVL(m.tnColumnSum,toGrid.ColumnCount)

		lnColumns = ALINES(laColumns,tcListColumn,1+4,CHR(44))

		SELECT (toGrid.RecordSource)

		lnRecno = RECNO()

		SCAN

			lnSuma = 0

			FOR i = 1 TO lnColumns

				lnSuma = m.lnSuma + EVALUATE(toGrid.Columns(VAL(laColumns[m.i])).ControlSource)

			NEXT

			replace (toGrid.Columns(m.tnColumnSum).ControlSource) WITH m.lnSuma

		ENDSCAN

		IF !EMPTY(m.lnRecno)

			GO m.lnRecno

		ELSE

			GO top

		ENDIF

		toGrid.Refresh

		toGrid.SetFocus()

	ENDIF

CATCH TO loex

	loex.UserValue = PROGRAM()

	*ShowError(loex)  && rutina que muestra un error producido

FINALLY

	toGrid = null

ENDTRY

ENDPROC

* En este caso, se usan dos palabras.

SELECT (thisform.grid1.recordSource)

SCAN

	REPLACE ESTADO WITH IIF(Vencimiento < DATE(),"Vencido","Corriente")

ENDSCAN

* En este caso, se utiliza una sola palabra, como propones.

SELECT (thisform.grid1.recordSource)

SCAN FOR vencimiento < DATE()

	REPLACE ESTADO WITH "Vencido"

ENDSCAN

Thisform.Grid1.Refresh