FoxPro/Visual FoxPro - Foxpro 9 en red con tablas shared y exclusive

PROCEDURE pack_table

*-------------------

LPARAMETERS tcTabla

TRY

	LOCAL lnTypeUse,;

		loError as Exception,;

		loUse as Exception

	lnTypeUse = 0

	* Si tengo la tabla abierta la cierro

	IF USED(m.tcTabla)

		lnTypeUse = IIF(ISEXCLUSIVE(m.tcTabla),2,1)

		USE IN SELECT (m.tcTabla)

	ENDIF

	* Intento abrir en modo exclusivo

	* si no se puede salta al CATCH

	USE (m.tcTabla) IN 0 EXCLUSIVE

	* Si no hubo error, hago el PACK y vuelvo a cerrar la tabla

	SELECT (m.tcTabla)

	PACK

	USE IN SELECT (m.tcTabla)

CATCH TO loError

	loError.UserValue = PROGRAM()

	MESSAGEBOX("La tabla "+m.tcTabla+" está en uso por otro usuario",0,LOWER(PROGRAM()),2000)

FINALLY

	* Vuelvo a abrir la tabla (si estaba abierta)

	* en el modo indicado por lnTypeUse

	TRY

		DO CASE

			CASE EMPTY(m.lnTypeUse)

			CASE m.lnTypeUse = 1

				USE (m.tcTabla) IN 0 SHARED

			CASE m.lnTypeUse = 2

				USE (m.tcTabla) IN 0 EXCLUSIVE

		ENDCASE

	CATCH TO loUse

		MESSAGEBOX("No se pudo reabrir la tabla "+m.tcTabla,0,LOWER(PROGRAM()),2000)

	FINALLY

	ENDTRY

ENDTRY

ENDPROC

Try

    Select Select(1)

    Use <Tabla> Exclusive

    Pack

Catch To oError

	Wait Window "Tabla en uso"+Chr(13)+oError.Message Timeout 0.5

Endtry

SELECT <TablaConNombresDeTablas>

SCAN

    Try

        Select Select(1)

        Use (TablaConNombresDeTablas.CampoNombre) Exclusive

        Pack

    Catch To oError

        Wait Window "Tabla en uso"+Chr(13)+oError.Message Timeout 0.5

    Endtry

ENDSCAN