FoxPro/Visual FoxPro - AYUDA URGENTE POR FAVOR

Hola a todos, por quei les dejo una consultica:

Tengo una sentencia SQL que me trae los datos de una tabla y estos los mete a un cursor que he creado previamente, el cual tiene un campo de tipo general en donde meto las imagenes que provienen de la tabla, el problema es que esa consulta debo ponerla en un grid y a su vez lograr que en el grid me muestre las imagenes, ya incruste dentro del grid un contenedor de imagenes, y carga el cursor bien, pero no me muestra las imagenes que estan dentro del cursor, como logro hacer esto?

basicamente es poner dentro de un grid todas las imagenes que dentro de una tabla a cursor.

De antemano gracias a todos lo que me puedan colaborar.

Carlos Restrepo

Se puede, pero te va funcionar horrible....sera lento y dependiendo el tamaño de las fotos el grid se mirara feo. Igua prueba esta solucion dada por Cetin Basoz en universthread:

lcPath = getdir()
lnFiles = adir(aImageList, lcPath+'*.*')
Create cursor myImageList (FileName m)
For ix=1 to alen(aImageList,1)
Insert into myImageList values (lcPath+aImageList[ix,1])
Endfor
Go top
oForm = createobject('myForm')
With oForm
.Lockscreen = .t.
.Height = 400
.Width = 600
.Addobject('myGrid','Grid')
.Addobject('clbutton','closebutton')
.clbutton.visible = .t.
With .myGrid
.Left = 0
.Top = 20
.Height = 370
.Width = 590
.Columncount = -1
.Recordsource = 'myImageList'
.Columncount = 2
.RowHeight = .RowHeight * 7
With .Columns(2) .
.Addobject('myContainer','Container')
.CurrentControl = 'myContainer'
.Sparse = .f.
With .myContainer
.Addobject('myImage','Image')
.myImage.Visible = .t.
Endwith
.Dynamicbackcolor = 'thisform.fake()'
Endwith
.Visible = .t.
Endwith
.Lockscreen = .f.
Endwith
oForm.Show
Read events

Define class myForm as Form
Procedure fake
Thisform.myGrid.Columns(2).myContainer.myImage.Picture = myImageList.FileName
Return thisform.myGrid.Backcolor
Endproc
Enddefine
Define class CloseButton as commandbutton
Height = 15
Caption ='close'
Procedure click
Clear events
Thisform.release
Endproc
Enddefine

Ojo, esta solucion funciona para direcciones de fotos y no para campos tipo general, igual siempre es facil entenderlo para tu caso. Te recomendaria mejor tener un control fuera del grid donde se vaya mostrando la foto correspondiente al registro actual del grid...

Simplemente dale un doble clic al campo de tipo GENERAL que se presenta en la GRILLA (Gen) y se presentará la imagen correspondiente

El SELEC a la Tabla sería algo asi:

SELE m.cedula,m.Nombre,m.apellido,m.foto FROM LaTabla m INTO CURSOR Album
thisform.grid1.recordsource='Album'

En el INIT del Formulario pon: thisform.grid1.recordsource=''