FoxPro/Visual FoxPro - justificar un reporte

hola amigos fijense que nesecito justificar dentro de un reporte un campo memo pero no se como hacerlo yo pense que con mandar cadenas de un mismo tamaño lo haria y no fue asi. espero me puedar dar ayuda o unos tips para poder hacer que el texto que esta dentro del campo memo se imprima justificado, gracias

Por que mejor no crear un reporte en word y le das el formato que quieras


chequa esto si te sirve

**************************************************
*-- Class: WordReport
*-- ClasePadre: Custom
*--ClaseBase: Custom

DEFINE CLASS WordReport AS custom
Name = "WordReport"
*-- Template file name
TemplateFile = ''
*-- Report file name
ReportFile = ''
*-- MS Word application object
PROTECTED WordApplication
*-- MS Word document object
PROTECTED WordDocument
*-- Reference to MS Word application object
Reference = .F.
*-- Create document from template
PROCEDURE create
* It is the code handling the template and creating
* the document.
LOCAL loApp, loDoc
loApp=THIS.WordApplication
loDoc=THIS.WordDocument
loDoc.SaveAs(THIS.ReportFile)
local lcFoundText, lcCommand
loApp.Selection.Find.Execute('\<*\>',,,.T.,,,.T.,1)
lcFoundText=loApp.Selection.Text
DO WHILE SUBSTR(lcFoundText,1,1)='<' AND ;
SUBSTR(lcFoundText,LEN(lcFoundText),1)='>'
lcCommand=loApp.Selection.Text
lcCommand=SUBSTR(lcCommand,1,LEN(lcCommand)-1)
lcCommand=SUBSTR(lcCommand,2)
loApp.Selection.Text=EVALUATE(lcCommand)
loApp.Selection.Find.Execute('\<*\>',,,.T.,,,.T.,1)
lcFoundText=loApp.Selection.Text
ENDDO
loDoc.Save()
ENDPROC

*-- Show MS Word window
PROCEDURE show
LPARAMETERS nStyle
LOCAL loApp
loApp=this.WordApplication
loApp.Visible=.T.
ENDPROC

*-- Hide MS Word window
PROCEDURE hide
LOCAL loApp
loApp=THIS.WordApplication
loApp.Visible=.F.
ENDPROC

*-- Print report
PROCEDURE print
LPARAMETERS cText
LOCAL loApp
loApp=THIS.WordApplication
IF loApp.Visible
loApp.Dialogs(88).Show()
ELSE
THIS.Show()
loApp.Dialogs(88).Show()
THIS.Hide()
ENDIF
ENDPROC

PROCEDURE reference_access
RETURN THIS.WordApplication
ENDPROC

PROCEDURE reference_assign
LPARAMETERS vNewVal
ENDPROC

PROCEDURE Init
LPARAMETERS lcTempaleName, lcReportName
THIS.TemplateFile=lcTempaleName
THIS.ReportFile=lcReportName
THIS.WordApplication=CREATEOBJECT('Word.Application')
LOCAL loApp
loApp=THIS.WordApplication
THIS.WordDocument=loApp.Documents.Open(THIS.TemplateFile)
ENDPROC

PROCEDURE Destroy
LOCAL loApp
loApp=THIS.WordApplication
loApp.Quit()
ENDPROC
ENDDEFINE

Suerte

http://www.codefox.net/importan/TXT/JUSTIFICARMEMO.txt