FoxPro/Visual FoxPro - consutas actualizables sql

Hola una consulta amigos. Quiero hacer una consulta actualizable de una tabla de SQL sever 2000, pero no quiero usar bases de datos de vfp sino una consulta con SQL pass through que me proporciona un cursor que cuando se cambie la información en él , ésta se refleje en la base de datos de sql server.

Actualmente me conecto a sql mediante esta orden:

* esta es mi forma de conectarme a sql
vCnx= SQLSTRINGCONNECT("Driver=SQL Server; Server=ATHLON; uid=;pwd=; database=SISALMAC")

* esta es la forma en que consulto una tabla y produzco un cursor
SQLEXEC(VCNX,"select * from zonas","cZonas")

Pero ahora quiero que al hacer los cambios en el cursor, se cambie también la tabla ZONAS en sql server 2000.

Agradeceré cualquier colaboración o sugerencia.

Utiliza UPDATE SQL

Suerte

Para lograr lo que quieres checa este comando con los argumentos que les pongo...

Tines que usar el TABLEUPDATE para grabar los cambios...

Gracias muchachos, ya obtuve la respuesta para hacer mi cursor actualizable, sin usar las bases de datos de VFP ni los remote views.
El código es el siguiente

PUBLIC vCnx
vCnx= SQLSTRINGCONNECT("Driver=SQL Server; Server=ATHLON; uid=;pwd=; database=SISALMAC")
SQLEXEC(VCNX,"select * from zonas","cZonas")

*list of the names of remote tables. No default.
*You must include a list of table names for updates to work when using automatic updating.
CURSORSETPROP("Tables","dbo.zonas", "czonas")

*Specifies a comma-delimited list of primary fields for the cursor.
*No default. You must include a list of field names for updates to work when using automatic updating.
CURSORSETPROP("KeyfieldList","zona_codigo", "czonas")

*Specifies a comma-delimited list of fields in the view.
*This list can include fields from local and remote tables.
*You must include a list of fields for updates to work when using automatic updating.
CURSORSETPROP("UpdaTableFieldList","zona_codigo, zona_nombre", "czonas")

*Specifies a comma-delimited list of remote field names and the local field names assigned to the cursor
CURSORSETPROP("UpdateNameList","zona_codigo dbo.zonas.zona_codigo, "+"zona_nombre dbo.zonas.zona_Nombre", "czonas")

* Specifies that a SQL update query is sent to update tables when an update is made using the view
CURSORSETPROP("SendUpdates",.T., "czonas")

* buffering by record, optimistic
SET MULTILOCKS ON
CURSORSETPROP("buffering",3, "czonas")

* Update old data with new data (1)
CURSORSETPROP("UpdateType", 1, "cZonas")

*The WHERE clause (3) used to update remote tables consists of the primary fields
*specified with the KeyFieldList property and any other fields that are modified.
CURSORSETPROP("WhereType",3,"cZonas")

Excelente solución me sirvió para un proyecto que estamos montando en la empresa.
Mil gracias.

Nose porque no colocan las cosas en español. havemos personas que no hablamos muy bien el ingles