Visual Basic para Aplicaciones - Save as en excel

Tengo el siguiente código para guardar una hoja en específico de un workbook a un nuevo wokbook:

Sub guardarNóminaSemanal()
On Error GoTo errorhandler
Sheets("Nómina Semanal").Copy
Dim fechaNS As String
fechaNS = Sheets("Nómina Semanal").Range("A3").Formula
ActiveWorkbook.SaveAs "C:\Documents and Settings\roxy_rose\Desktop\Nóminas\" & fechaNS & ".XLS"
ActiveWorkbook.Save
ActiveWorkbook.Close

Exit Sub
errorhandler:
MsgBox ("Un error ha ocurrido, la hoja no pudo ser guardada.")
End Sub

Sé que esta no es la mejor manera de hacerlo, incluso algunas veces me tira error.
¿Alguien me provee alguna opción más efictiva para hacerlo?

Les agradecería mucho su ayuda.

Rocío

Hola Rocio, el codigo se ve bien, que error te muestra??, checa que tu variable donde guardar la fecha, este bien formateda, recuerda que algunos caracteres no los acepta windows como nombres de archivo...

Saludos

Los errores q me tiran son cuando el archivo ya ha sido creado o cuando el folder no existe, me gustaría q creara el folder si no existe.

Hola Rocio, como vez, entre mas clara sea tu exposicion del problema, mas rapido alguien en el foro te puede contestar...

La siguiente macro hace lo que quieres...
Si no existe la carpeta, pregunta si deseamos crearla
Si existe el archivo, pregunta si lo sobreescribimos...

Saludos...

Option Explicit

Public Sub GuardarNominaSemanal()
Dim sRuta As String
Dim sRutaCompleta As String
Dim iRes As Integer
Dim sCarpeta As String
Dim sTmp As String
Dim sArchivo As String

sArchivo = Format(Date, "dd-mmm-yy") & ".xls"
sCarpeta = "Nomina"
sRuta = ActiveWorkbook.Path
sTmp = sRuta & Application.PathSeparator & sCarpeta
If Len(Dir(sTmp, vbDirectory)) = 0 Then
iRes = MsgBox("No existe la carpeta: " & sCarpeta & vbCrLf & _
"En la ruta: " & sRuta & vbCrLf & vbCrLf & _
"Deseas crearla", vbYesNo, "Crear carpeta")
If iRes = vbYes Then
MkDir sTmp
Else
MsgBox "El archivo NO se guardo"
Exit Sub
End If
End If
sRutaCompleta = sTmp & Application.PathSeparator & sArchivo
If Len(Dir(sRutaCompleta)) = 0 Then
Worksheets("Nomina").Copy
ActiveWorkbook.SaveAs sRutaCompleta
ActiveWorkbook.Close
Else
iRes = MsgBox("El archivo: " & sArchivo & vbCrLf & _
"En la ruta: " & sRuta & vbCrLf & vbCrLf & _
"YA existe, deseas sobreescribirlo", vbYesNo, "Archivo existente")
If iRes = vbYes Then
Kill sRutaCompleta
Worksheets("Nomina").Copy
ActiveWorkbook.SaveAs sRutaCompleta
ActiveWorkbook.Close
Else
MsgBox "El archivo NO se guardo"
End If
End If

End Sub

Muchísimas gracias Mauricio!!