Visual Basic - analista de sistemas

deseo saber como editar una grilla que no sea la dbgrid
puede ser la msflexgrid 6.0 o mshflexgrid

Esto creo que ya lo rspondí, de echo tengo un ejemplo con el que acompañé aquella respuesta, pero no se si eras tú o otra persona. De todas formas te pongo el ejemplo.

Para usar el código inserta un msFlexGrid llamado msfg, y también un textbox con las siguientes propiedades:
name=txtEditaCelda
borderstyle=0-none
backcolor=(cualquiera distinto del fondo del flexGrid, para diferenciar)

El código lo que hace es ir colocando el textBox sobre la celda activa del
flexGrid y cambiar el texto de dicha celda con el que se va escribiendo.

El código te lo pongo en otro mensaje por si no cabe.

Private Sub msfg_EnterCell()
colocaText
End Sub
Private Sub txtEditaCelda_Change()
msfg.Text = txtEditaCelda.Text
End Sub
Private Sub txtEditaCelda_KeyDown(KeyCode As Integer, Shift As Integer)
Select Case KeyCode
Case vbKeyUp
If msfg.Row > 0 Then
msfg.Row = msfg.Row - 1
End If
Case vbKeyDown
If msfg.Row < msfg.Rows - 1 Then
msfg.Row = msfg.Row + 1
End If
Case vbKeyLeft
If txtEditaCelda.SelStart = 0 Then
If msfg.Col > 0 Then
msfg.Col = msfg.Col - 1
End If
End If
Case vbKeyRight
If txtEditaCelda.SelStart = Len(txtEditaCelda.Text) Then
If msfg.Col < msfg.Cols - 1 Then
msfg.Col = msfg.Col + 1
End If
End If
End Select
End Sub
' Coloca el textBox sobre la celda actual
Private Sub colocaText()
With txtEditaCelda
.Move msfg.CellLeft + msfg.Left, msfg.CellTop + msfg.Top, msfg.CellWidth, msfg.CellHeight
.Visible = True
.ZOrder 0
.Text = msfg.Text
.SetFocus
.SelStart = Len(txtEditaCelda.Text)
End With
End Sub