Visual Basic - desactivar botones minimizar y maximizar

necesito desactivar los botones de maximizar y minimizar de un formulario MDI pero en este tipo de formularios no exiten estaa propiedades, de que forma podría desactivarlos.

GRACIAS!!!

Se puede hacer con funciones API, el único problema es que además de los botones, hay que eliminar los elementos de maximizar y minimizar del menu de sistema, ese que aparece cuando haces clic en el icono de la ventana al lado del título.

Pero todo tiene solución y eso último también se puede resolver con la API de windows. Te pondre un ejemplo en otro mensaje que en este seguramente ya no me cabe.

Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Private Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
' Funciones para cambiar el estilo
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long

Private Const GWL_STYLE = (-16)
Private Const WS_MAXIMIZEBOX = &H10000
Private Const WS_MINIMIZEBOX = &H20000
Const MF_BYPOSITION = &H400&
Private Sub MDIForm_Load()
Dim aux As Long
Dim hSysMenu As Long, nCnt As Long
' Elimina los botones
aux = GetWindowLong(Me.hwnd, GWL_STYLE)
SetWindowLong Me.hwnd, GWL_STYLE, aux Xor (WS_MAXIMIZEBOX Or WS_MINIMIZEBOX)
' Elimina los elementos en el menu
hSysMenu = GetSystemMenu(Me.hwnd, False)
If hSysMenu Then
nCnt = GetMenuItemCount(hSysMenu)
If nCnt Then
RemoveMenu hSysMenu, nCnt - 3, MF_BYPOSITION
RemoveMenu hSysMenu, nCnt - 4, MF_BYPOSITION
End If
End If
End Sub