Visual Basic - Alguien me puede ayudar?

Necesito accesar mi aplicación Vb con una combinación de teclas desde cualquier parte de Windows, por ej. con CTRL+ALT+A, y que se active mi aplicación que ya se esta ejecutandose.
Yo tengo mi aplicación en la barra de Iconos del Sistema.

Gracias

Prueba con este código porque funciona:

Option Explicit

Private Declare Function RegisterHotKey Lib "user32" _
(ByVal hWnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Private Declare Function UnregisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long) As Long

Private Const MOD_ALT = &H1
Private Const MOD_CONTROL = &H2
Private Const MOD_SHIFT = &H4

Private Const WM_HOTKEY = &H312

'Tipos de datos para las funciones del API
Private Type POINTAPI
x As Long
y As Long
End Type

Private Type Msg
hWnd As Long
message As Long
wParam As Long
lParam As Long
time As Long
pt As POINTAPI
End Type 'MSG

Private Const PM_REMOVE = &H1

'funciones para recibir los mensajes de windows
Private Declare Function PeekMessage Lib "user32" Alias "PeekMessageA" _
(lpMsg As Msg, ByVal hWnd As Long, ByVal wMsgFilterMin As Long, _
ByVal wMsgFilterMax As Long, ByVal wRemoveMsg As Long) As Long
Private Declare Function WaitMessage Lib "user32" () As Long

Private Termina As Boolean

Private Sub ProcesaMensajes()
'Para leer mensajes de la cola
Dim Mensaje As Msg

'Mientras Termina no sea True
Do While Not Termina
'esperamos a que llegue un mensaje
WaitMessage
'Si ese mensaje es WM_HOTKEY
If PeekMessage(Mensaje, Me.hWnd, WM_HOTKEY, WM_HOTKEY, PM_REMOVE) Then
'Restauramos el formulario al estado normal
'por si

'por si está minimizado
WindowState = vbNormal
'Mostramos el form
Show
End If
'permitimos el trabajo de otros procesos
DoEvents
Loop
End Sub

Private Sub Form_Load()
'registrar las teclas para activación de esta aplicación
Dim ret As Long

Termina = False

'La tecla Crtl+F será la que activará este formulario
ret = RegisterHotKey(Me.hWnd, &HBFFF&, MOD_CONTROL + MOD_ALT, vbKeyA)
'If ret Then
' Label2 = "Se ha registrado de forma correcta el Hot-Key"
'Else
' Label2 = "No se ha registrado el Hot-Key"
'End If

'Hay que mostrar el form
'sino entrará en el bucle de espera de mensajes sin mostrarse
Show
ProcesaMensajes
End Sub

Private Sub Form_Unload(Cancel As Integer)
Termina = True
'Quitar la Hot-Key registrada
Call UnregisterHotKey(Me.hWnd, &HBFFF&)
End Sub

Esta rutina es para cuando está minimizado pero he probado con el icono en la barra de tareas y también activa la aplicación.

Un saludo