RE:Usar un combobox dentro de un MsFlexGrid
Puedes probar con esto:
Private Sub Form_Load()
'Llenamos el combo con las opciones
For I = 1 To 10
Combo1.AddItem "Valor" & CStr(I)
Next I
Combo1.Visible = False
End Sub
Private Sub MSHFlexGrid1_DblClick()
MSHFlexGrid1_KeyDown 13, 0
End Sub
Private Sub MSHFlexGrid1_KeyDown(KeyCode As Integer, Shift As Integer)
With MSHFlexGrid1
Select Case KeyCode
Case 13
Select Case .Col
Case 0 'Numero Patentes
Combo1.Visible = False
MSHFlexGridEdit MSHFlexGrid1, Combo1, 32
End Select
End Select
End With
End Sub
Sub MSHFlexGridEdit(ByRef MSHFlexGrid As Control, Edt As Control, KeyAscii As Integer)
Select Case KeyAscii
Case 0 To 32
Edt = MSHFlexGrid
Case Else
Edt = Chr(KeyAscii)
Edt.SelStart = 1
End Select
Edt.Move MSHFlexGrid.Left - 20 + MSHFlexGrid.CellLeft, _
MSHFlexGrid.Top - 10 + MSHFlexGrid.CellTop, _
MSHFlexGrid.CellWidth + 5
Edt.Visible = True
Edt.SetFocus
End Sub
Private Sub Combo1_KeyPress(KeyAscii As Integer)
Select Case KeyAscii
Case 13
MSHFlexGrid1.TextMatrix(MSHFlexGrid1.Row, 0) = Combo1.Text
Combo1.Visible = False
End Select
End Sub
Private Sub Combo1_LostFocus()
Combo1.Visible = False
End Sub