Visual Basic - de internet al picturebox

Necesito ayuda urgente ja que estoy haciendo un programa "album" y necesito saber como puedo acer que un "picturebox" o un "image" reproduzcan una imagen de una direccion web.
gracias

Fijate con esto:

Private Declare Function GetTempPath Lib "kernel32" Alias "GetTempPathA" (ByVal nSize As Long, ByVal lpBuffer As String) As Long
Private Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

Public Sub URL_To_Picture(ByVal sURL As String, pb As PictureBox)
Dim sTemp As String, sHTML As String
sTemp = GetTempDir
If Right(sTemp,1) <> "\" Then sTemp = sTemp & "\"
sTemp = sTemp & "dummy"
If Dir$(sTemp) <> "" Then Kill sTemp
Save_File_URL sTemp, sURL
pb.Picture = LoadPicture(sTemp)
Kill sTemp
End Sub

Private Function Save_File_URL(ByVal sFileName As String, ByVal sURL As String) As Long
Call URLDownloadToFile(0&, sURL, sFileName, 0, 0)
End Function

Private Function GetTempDir() As String
Dim tmp As String
tmp = Space$(256)
Call GetTempPath(Len(tmp), tmp)
GetTempDir = TrimNull(tmp)
End Function

Private Function TrimNull(item As String)
Dim pos As Integer
pos = InStr(item, Chr$(0))
If pos Then
TrimNull = Left$(item, pos - 1)
Else
TrimNull = item
End If
End Function

me puedes decir donde pongo la direccion de la imagen,por favor

En la llamada a la función:

URL_To_Picture "http://www.mipagina.com/imagenes/imagen1.jpg", Picture1

Muchas gracias por todo pero tengo una ultima pregunta, por que no puedo canviar la imagen, y quiero que al apretar un boton canvie la imagen, gracias.

El código lo puedes colocar en un módulo y la llamada a la función en el evento Click de tu botón, ahí indicas diferentes direcciones de imágenes y cambiará.