Visual Basic - Desaparecer Maximizar en MDI VB60

Porfa Ayudenme porfavor necesito hacer desaparecer el botoincito de maximizar en el formulario MDI poraf ayudenme es urgentismo, de antemano muchas gracias por su cooperacion y el gran favor que me hacen al educarme.

prueba con este codigo

Private Sub MDIForm_Resize()
Me.WindowState = 0
Me.Height = 8600
Me.Width = 11990
End Sub

evita agrandar o achicar formularios

La idea es buena, pero el efecto No!
Con unas llamas a la API y un poco más de código se puede conseguir un efecto más profesional:
Private Declare Function SetWindowLong Lib "user32" Alias _
"SetWindowLongA" (ByVal hwnd As Long, _
ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias _
"GetWindowLongA" (ByVal hwnd As Long, _
ByVal nIndex As Long) As Long
Private Declare Function GetSystemMenu Lib "user32" _
(ByVal hwnd As Long, ByVal bRevert As Long) As Long

Private Declare Function RemoveMenu Lib "user32" _
(ByVal hMenu As Long, ByVal nPosition As Long, _
ByVal wFlags As Long) As Long

Private Const WS_MAXIMIZEBOX = &H10000 'Disables Maximize Button
Private Const GWL_STYLE = (-16)
Private Const MF_BYPOSITION = &H400&

Private Sub MDIForm_Load()
Dim lRet As Long
Dim hSysmenu As Long

' Desactiva el botón de maximizar
lRet = GetWindowLong(Me.hwnd, GWL_STYLE)
lRet = lRet And Not (WS_MAXIMIZEBOX)
' Elimina en el menú la opción de maximizar
hSysmenu = GetSystemMenu(Me.hwnd, 0)
RemoveMenu hSysmenu, 4, MF_BYPOSITION
lRet = SetWindowLong(Me.hwnd, GWL_STYLE, lRet)
End Sub
Lo mismo para los botones (y menús) de Minimizar y Cerrar
Saludos