Word - Exportar multiples PDF con nombres distintos

 
Vista:

Exportar multiples PDF con nombres distintos

Publicado por Eduardo González (2 intervenciones) el 08/07/2020 18:36:50
Hola, buenos días.
He tenido que hacer una gran cantidad de diplomas en Word usando un enlace a Excel y generando multiples archivos de Word que a su vez luego los exporto a PDF.

Mi problema es que me solicitan hacer archivos individuales con el nombre de cada uno de los participantes a una conferencia y pueden llegar a ser 400 o 500 archivos de PDF.

El proceso que tengo que hacer es:
1. Enlazar el diploma de Word a un archivo de Word en el cual tengo los nombres de los participantes.
2. Crear páginas para cada uno de los participantes en word.
3. Exportar el PDF
4. Abrir el documento en Acrobat y salvar los archivos individuales.
5. Acrobat genera 400 archivos separados con un nombre genérico.
6. Reemplazar los nombres de cada uno de los 400 diplomas a mano, por cada uno de los nombres de los participantes.

¿Hay alguna manera, acción o programación para que Word exporte cada diploma en PDF con el nombre del participante correspondiente?
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder
Imágen de perfil de wordexperto.com
Val: 2.216
Oro
Ha mantenido su posición en Word (en relación al último mes)
Gráfica de Word

Exportar multiples PDF con nombres distintos

Publicado por wordexperto.com (888 intervenciones) el 09/07/2020 13:24:41
Hola Eduardo:
Yo usé esta macro para una combinación de certificados. La base de datos la tenía en Excel.
Adapta a tus circunstancias.
https://www.youtube.com/channel/UCxgRcbeR2q4PpE1Pgft74Iw

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub Merge_To_Individual_Files()
'Combina cada registro, en formato pdf, con el nombre del campo CORREO, a la carpeta en la que está este documento de combinación
'Creado por https://wordexperto.com/
Application.ScreenUpdating = False
Dim StrFolder As String, StrName As String, MainDoc As Document, i As Long, j As Long
Const StrNoChr As String = """*./\:?|"
Set MainDoc = ActiveDocument
With MainDoc
  StrFolder = .Path & Application.PathSeparator
  For i = 1 To .MailMerge.DataSource.RecordCount
    With .MailMerge
      .Destination = wdSendToNewDocument
      .SuppressBlankLines = True
      With .DataSource
        .FirstRecord = i
        .LastRecord = i
        .ActiveRecord = i
        If Trim(.DataFields("CORREO")) = "" Then Exit For
        'StrFolder = .DataFields("Folder") & Application.PathSeparator
        StrName = .DataFields("CORREO")
      End With
      On Error Resume Next
      .Execute Pause:=False
      If Err.Number = 5631 Then
        Err.Clear
        GoTo NextRecord
      End If
    End With
      For j = 1 To Len(StrNoChr)
        StrName = Replace(StrName, Mid(StrNoChr, j, 1), "_")
      Next
    StrName = Trim(StrName)
    With ActiveDocument
      .SaveAs FileName:=StrFolder & StrName & ".pdf", FileFormat:=wdFormatPDF, AddToRecentFiles:=False
      .Close SaveChanges:=False
    End With
NextRecord:
  Next i
End With
Application.ScreenUpdating = True
End Sub
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

Exportar multiples PDF con nombres distintos

Publicado por Eduardo González (2 intervenciones) el 04/08/2020 05:41:11
Gracias lo voy a probar.
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar