Access - Consultas para ir a formulario

Buenas tardes a todos los usuarios y expertos de la web. Tengo una gran duda con respecto a las consultas en vba. La consulta la realizao desde una formulario llamado abrir por nif, en este introducimos el nif de un usuario. Y lo que yo pretendo esque si el nif no esta registrado me quede en este formulario y sino que me llebe a otro formulario donde estan todos sus datos este formulario se llama Usuarios Orienta. Como hago para que esto m lo realice correctamente. A continuacion pongo el evento Click mouse que le tengo puesto en el boton del formulario Abrir por nif:

DoCmd.OpenForm "Usuarios Orienta", acNormal, "", "", acEdit, acNormal
DoCmd.GoToControl "[NIF]" Rem cuadro de texto donde introducimos el Nif
DoCmd.FindRecord Forms![Abrir por nif]!NIF, acEntire, False, , False, acCurrent, True
DoCmd.Close acForm, "Abrir por nif"

Alguien sabria darme alguna idea de como acerlo.
Saludos y gracias a todos
Espero respuestas

Buenas amigo RafaCM...

Asumo que la tabla de donde sale el Nif se llama Usuarios de NO ser asi cambiala por el nombre correspondiente, en tu evento pega esto

Dim BUSCAR As String
Dim CriterioBusqueda As String

'*********************************************
'Codigo Simple Cortesia de Jefferson Jimenez *
'*********************************************
If IsNull(Nif) Then
MsgBox "No ha ingresado nada" & vbCrLf & _
"vuelva a intentarlo", vbCritical, "Campo Nulo"
Nif.SetFocus
Exit Sub
End If
BUSCAR = Me.Nif.Value
CriterioBusqueda = "[Nif]=" & "'" & Nif & "'"

'Comprobamos si existe el Nif del Usuario
If DCount("Nif", "Usuarios", CriterioBusqueda) > 0 Then
'Abrimos una caja de mensajes indicamos que lo encontramos
MsgBox "Vamos a abrir el Form Usuarios Orienta" & vbCrLf & _
"cuyo Nif pertenece a :" & vbCrLf & _
Nif, vbExclamation, "Nif Encontrado"
'Y abrimos
DoCmd.OpenForm "Usuarios Orienta", acNormal, "", "", acEdit, acNormal
DoCmd.GoToControl "Nif" 'Rem cuadro de texto donde introducimos el Nif
DoCmd.FindRecord Forms![Abrir por nif]!Nif, acEntire, False, , False, acCurrent, True
DoCmd.Close acForm, "Abrir por nif"
Else
'De no existir lanzamos un Mensaje
MsgBox "El Usuario solicitado : " & Nif & vbCrLf & _
"no existe, por favor refine la busqueda", vbCritical, "No Encontrado"
Nif.SetFocus
End If

Un Placer colaborar
Desde Venezuela
Jefferson

Muchas gracias Jefferson. Me a salido estupendo. Eres un maquina
Gracias