Clipper/FiveWin - contraseña con asteriscos.

   
Vista:

contraseña con asteriscos.

Publicado por popa (2 intervenciones) el 16/10/2009 05:10:37
hola!!!
quisiera saver si hay algun comando de que cuando escrivis la contraseña que te la muestre con asteriscos enves de escrivirtela.

salu2
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:contraseña con asteriscos.

Publicado por antonio (216 intervenciones) el 16/10/2009 10:19:27
GETCRIPT(@WCLAVE,"*",10,38)

PROCEDURE MAIN
CLEAR
USE CLAVE EXCLUSIV
@ 10,22 SAY "TECLEE NUEVA "
WCLA=SPACE(12)
GETCRIPT(@WCLA,"*",10,38)
REPLACE CLAVE WITH CRIPT(WCLA)
RETURN
**************
function cript
parameters cad1
private long, car, pos
long = len (cad1)
pos = 1
for pos = 1 to long
car = chr (asc (substr (cad1, pos, 1)) + long)
cad1 = stuff (cad1, pos, 1, car)
next
return cad1
******************
function getcript
parameters cad1, car, fila, col
do case
case pcount () = 1
private car, fila, col
car = '*'
fila = row ()
col = col ()
case pcount () = 2
private fila, col
fila = row ()
col = col ()
endcase
private contador, long
long = len (cad1)
cad1 = space (0)
contador = 1
@ fila, col say space (long)
@ fila, col say space (0)
do while contador <= long
cad1 = cad1 + chr (inkey (0))
if lastkey () = 13 .or. lastkey () = 27
exit
endif
@ fila, col + contador - 1 say car
contador = contador + 1
enddo
return cad1
***************************************
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:contraseña con asteriscos.

Publicado por marcelo (1 intervención) el 22/10/2009 00:30:45
@ F,C get Variable size X,Y Pass

agregando pass al final del get muestra asteriscos.

Saludos
Marcelo
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:contraseña con asteriscos.

Publicado por Manuel (5 intervenciones) el 17/10/2009 11:52:18
Si estás usando recursos para definir el EditBox, sólo tienes que poner la propiedad password a "Yes".

Si no usas recursos:

#include "Getpass.ch"

@ 12,36 GET clave PASSWORD PICTURE "@!" COLOR "GR+/GR"

******************************
FUNCTION GetPassword( oGet )
******************************
LOCAL nKey, ;
nChar, ;
cKey

// Leer el GET si se satisface la condición WHEN
IF ( GetPreValidate(oGet) )
// activar el GET para lectura
oGet:SetFocus()

oGet:cargo := ""
DO WHILE ( oGet:exitState == GE_NOEXIT )
// comp. posc. inicial (posiciones no editables)
IF ( oGet:typeOut )
oGet:exitState := GE_ENTER
ENDIF

// aplicar pulsaciones de teclas hasta finalizar
DO WHILE ( oGet:exitState == GE_NOEXIT )
nKey := InKey(0)
IF nKey >= 32 .AND. nKey <= 255
oGet:cargo += Chr(nKey)
GetApplyKey(oGet, Asc("*"))
ELSEIF nKey == K_BS
oGet:cargo := Substr(oGet:cargo, 1, Len(oGet:cargo) - 1)
GetapplyKey(oGet, nKey)
ELSEIF nKey == K_ENTER
GetApplyKey(oGet, nKey)
ENDIF
ENDDO

// no salir si no se cumple la condición VALID
IF ( !GetPostValidate(oGet) )
oGet:exitState := GE_NOEXIT
ENDIF
ENDDO
// desactivar el GET
oGet:KillFocus()
ENDIF
IF oGet:exitState != GE_ESCAPE
oGet:varPut(oGet:cargo)
ENDIF

RETURN NIL

El contenido de GETPASS.CH es este:

/***
* Getpass.ch
*
* Definici¢n del comando GET PASSWORD.
*/

#command @ <row>, <col> GET <var> ;
[<clauses,...>] ;
PASSWORD ;
[<moreClauses,...>] ;
;
=> @ <row>, <col> GET <var> ;
[<clauses>] ;
SEND reader := {|oGet| ;
GetPassword(oGet) } ;
[<moreClauses>]
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:contraseña con asteriscos.

Publicado por popa (2 intervenciones) el 22/10/2009 04:37:48
hola, miren no entiendo mucho de lo que me pusieron porque hace poco que empese con clipper y se lo basico nada mas.

si me pueden explicar un poco mejor como hacerlos se los agradeceria.
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

contraseña con asteriscos.

Publicado por raul andrade (14 intervenciones) el 23/03/2010 21:52:03
contraseña con asteriscos pero para clipper 5.0 podrian ayudarme he estado buscando por todos lados y no encuentro les agradeceria infinitamente
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar