Excel - Hallar y extraer datos de rutas carpetas Windows

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 27/01/2022 13:58:29

Hola,
Hace muuuucho que no uso Excel con funciones y ayer me vi en la necesidad, así que, con mi poca experiencia y mucha búsqueda, intenté hacer lo siguiente.

Tengo una carpeta con más de 1500 subcarpetas que quiero listar en Excel con otras propiedades. Antes, lo que hacía, era copiar nombre de carpeta y pegar en excel. Y de ahí, escribir a mano el resto de los datos.
Ahora lo hago de otra manera. Selecciono todas las carpetas, copio ruta y pego en Excel. Como quiero abrir la carpeta desde Excel, he usado la función hipervínculo.
Esto es lo único que me sale correcto jejejejeje.

Lo segundo es extraer los siguientes datos.. pongo un ejemplo de carpeta:
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $$$

De ahí necesito hallar y extraer:
- Nombre autor (Luz Santana).
- Nombre curso (INSPIRACION Y CREATIVIDAD CON LUZ).
- Plataforma (Hineva).
- Adquisición ($$$ = Compra).

Para el autor usé lo siguiente:
=SI.ERROR(EXTRAE(A14;ENCONTRAR("\";A14)+1;ENCONTRAR("-";A14)-ENCONTRAR("\";A14)-1);"")
Pero, lógicamente, me extrae lo siguiente: ...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana (por más que busco, no sé cómo añadir una tercera línea oblicua).

En cuanto al nombre del curso:
=SI.ERROR(EXTRAE(A14;ENCONTRAR("-";A14)+1;ENCONTRAR(" (";A14)-ENCONTRAR("-";A14)-1);"")
Bieeeen, sí y no. No siempre las carpetas tendrán esta nomenclatura (me explico más abajo).

Respecto a la plataforma.
=SI.ERROR(EXTRAE(A14;ENCONTRAR("(";A14)+1;ENCONTRAR(")";A14)-ENCONTRAR("(";A14)-1);"")
Otro tanto, como veréis, uso la misma fórmula. Y sí, también consigo extraer únicamente la plataforma, sin paréntesis, pero me pasa igual que con el anterior, no siempre las carpetas tienen la misma nomenclatura.

La adquisición es más chunga.
=SI(NO(ESERROR(HALLAR("$$$";D15;1)));"Compra";"Suscripción").
Aquí necesitaría realmente 4 valores (compra, suscripción, obsequio y descarga). E igualmente, cambia la nomenclatura de las carpetas.

Estas podrían ser las nomenclaturas, y he ahí donde me es difícil extraer toda la información y tengo que escribir manualmente :(

Opción 1: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $

Opción 2: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $$$

Opción 3: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $

Opción 4: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $$$

Opción 4: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva)

Opción 5: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ

Visto lo visto, ¿creéis que vale la pena modificar las 1500 carpetas para facilitar la tarea a Excel? :(

Muchas gracias.

Valora esta pregunta

Me gusta: Está pregunta es útil y esta clara

No me gusta: Está pregunta no esta clara o no es útil

Responder

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 27/01/2022 18:56:14

Empezemos.

Estos son los directorios:

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $$$

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $$$

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva)

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ

Puedes conseguir esta lista con una macro o abriendo una ventana de CMD y conseguir la lista con el comando DIR. Si te interesa esta segunda opción hablamos.

Una vez tengas la lista en las celdas de la columna A, selecciona la columna y ves a la pestaña Datos grupo Herramientas de datos y selecciona Texto en columnas. Selecciona Delimitadores en la pantalla siguiente pon la barra de directorio \ en Otros

-A-+- Columna B -------------------+- Col C ----+- Columna D -----------------------------------------------

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva)

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ

Ahora selecciona la columna D y ves a la pestaña Datos grupo Herramientas de datos y selecciona Texto en columnas. Selecciona Delimitadores en la pantalla siguiente pon el guiòn - en Otros

-A-+- Columna B -------------------+- Col C ----+- Columna D -+- Columna E -------------------------------------

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ (Hineva)

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ

Ahora selecciona la columna E y ves a la pestaña Datos grupo Herramientas de datos y selecciona Texto en columnas. Selecciona Delimitadores en la pantalla siguiente pon abrir parentesis ( en Otros

-A-+- Columna B -------------------+- Col C ----+- Columna D -+-Columna E ----------------------------+-Col F ----

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva) $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva) $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $   |

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $$$ |

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva)

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     |

Ahora selecciona la columna F y ves a la pestaña Datos grupo Herramientas de datos y selecciona Texto en columnas. Selecciona Delimitadores en la pantalla siguiente pon cerrar parentesis ) en Otros

-A-+- Columna B -------------------+- Col C ----+- Columna D -+-Columna E ----------------------------+- Col F--+- Col G

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva  | $

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva  | $$$

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $   |         |

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ $$$ |         |

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     | Hineva  |

H: | ...RECURSOS Y VIDEOTUTORIALES | FOTOGRAFIA | Luz Santana | INSPIRACION Y CREATIVIDAD CON LUZ     |

Y ya tienes el problema bastante resuelto.

Saludos.
\\//_

Valora esta respuesta

Me gusta: Está respuesta es útil y esta clara

No me gusta: Está respuesta no esta clara o no es útil

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 28/01/2022 00:25:41

En primer lugar, muchas gracias por tu ayuda y tiempo.
Error mío al poner el mismo ejemplo con diferentes nomenclaturas, pero tal como comenté, son más de 1500 carpetas y, todos son diferentes porque son autores, plataformas y cursos distintos.
De hecho, intenté lo de Texto en columnas, pero lógicamente no sirvió :(
Preferiría no usar macro, sino funciones. Pero si no se puede, tendré que buscarme otra opción :(

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 28/01/2022 10:28:35

Si subes un ejemplo podría mirar como hacerlo.
Por ejemplo sube las 1500 referencias y estudio como hacerlo con funciones.
También explica que se debe sacar de cada una de ellas, no necesariamente 1500 explicaciones pero si un resumen para que entienda que deseas extraer de cada referencia.

Saludos.
\\//_

Valora esta respuesta

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 28/01/2022 21:28:50

muchas gracias!
acabo de conseguir una parte gracias a las explicaciones en este vídeo: https://www.youtube.com/watch?v=__aMWUXeUDM

Es decir, de este ejemplo: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva) $, he conseguido extraer Luz Santana, cuya función se me ha quedado de la siguiente manera (ni idea si puedo acortarlo)...

=EXTRAE(EXTRAE(D38;HALLAR("@";SUSTITUIR(D38;"\";"@";LARGO(D38)-LARGO(SUSTITUIR(D38;"\";""))))+1;500);1;LARGO(EXTRAE(D38;HALLAR("@";SUSTITUIR(D38;"\";"@";LARGO(D38)-LARGO(SUSTITUIR(D38;"\";""))))+1;500))-LARGO(D45)-1)

Me falta hacerlo con el título del curso y la plataforma. Con esto me pondré ahora (la verdad es que había tirado la toalla).

lo que no consigo por nada del mundo es la última parte, la adquisición. Al final de algunas carpetas, tengo mi propia leyenda, donde:
$$$ = comprado
$ = por suscripción
! = gratuito
(nada, sin ningún símbolo al final) = descargado.

Hasta la fecha solo he conseguido esto:

=SI(NO(ESERROR(HALLAR("$$$";A19;1)));"Compra";"Suscripción")

pero como verás, tengo 4 opciones y solo me permite introducir 2 posibilidades :(

No quiero atosigarte con +1500 carpetas... lo siguiente es un pequeño ejemplo de esas carpetas

H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Jenny Boucing-MASTER RETOUCHING HAIR (JennyPhotography) $
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Adan Benítez-BEAUTY $$$
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Tito Bentan-HOW TO PHOTOGRAPH GLASS ON A WHITE BACKGROUND (Photi)
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\An Beketova-RETOUCHING SKIN
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Ben Askin-TAKE CONTROL OF YOUR LIGHT (Crtsy) $$$
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Cambridge in Colour-USING TELEPHOTO LENSES !
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Canon-LIBRO ROJO DE CANON
H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Carly Smerth-SHAFTS OF LIGHT (Mens) !

Nuevamente, gracias por tu tiempo

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 28/01/2022 22:08:31

Para la ultima parte usa esta formula:

=SI(DERECHA(A1;4)=" $$$";"Compra";

 SI(DERECHA(A1;2)=" $"  ;"Suscripción";

 SI(DERECHA(A1;2)=" !"  ;"Gratuito";"Descargado")))

Para extraer el AUTOR la función que has puesto tiene un error, hace referencia a dos celdas diferentes D38 y D45 y ami no me funciona
Ya pensare como hacerlo de forma más simple.

Me puede ayudar si me envias el libro con todas las referencias. Si no quieres o puedes en este foro puedes hacerlo a mi correo:

[email protected]

Saludos.
\\//_

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 28/01/2022 22:51:41

La formula para extraer el AUTOR es esta:

=IZQUIERDA(EXTRAE(A1;45;999);ENCONTRAR("-";EXTRAE(A1;45;999);1)-1)

Parto de la suposición que todos empiezan en la misma posición. El 45 equivale a esta función:

=ENCONTRAR("FOTOGRAFIA";A1)+11

Para la plataforma sirve esta función:

=SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("(";A1);999);ENCONTRAR(")";EXTRAE(A1;ENCONTRAR("(";A1);999)));"")

Si el resultado lo quieres sin los parentesis:

=SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("(";A1)+1;999);ENCONTRAR(")";EXTRAE(A1;ENCONTRAR("(";A1)+1;999))-1);"")

Ahora falta:

[_Ok_] - Nombre autor (Luz Santana).

[____] - Nombre curso (INSPIRACION Y CREATIVIDAD CON LUZ).

[_Ok_] - Plataforma (Hineva).

[_Ok_] - Adquisición ($$$ = Compra).

Y esta que queda va a ser un pelin más complicada y me la tengo que pensar este fin de semana.

Saludos.
\\//_

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 29/01/2022 23:11:28

Esta es la función que faltaba:

=SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" (";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999))-2);

 SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" $";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999))-2);

 SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" !";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999))-2);

                    EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999))))

.                                                            E1

                   +---------------------------------------------------------------------------------------------+

                   |                                                                  D1                         |

                   |                                              +------------------------------------------+   |

                   |                  C1                          |                     C1                   |   |

                   |      +----------------------------+          |           +----------------------------+ |   |

                   |      +                 B1         |          |           |                B1          | |   |

                   |      |            +--------+      |          |           |            +--------+      | |   |

                   |      |            |        |      |          |           |            |        |      | |   |

=SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" (";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999) )-2 );

 SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" $";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999) )-2 );

 SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999);ENCONTRAR(" !";EXTRAE(A1;ENCONTRAR("-";A1;1)+2;999) )-2 );

                    EXTRAE(A1;ENCONTRAR("-";A1;1)+1;999))))

Voy a ver si puedo explicar esta macro función por partes para que se entienda, parece muy complicada pero no lo es.

Para encontrar el nombre del curso sabemos que empieza después del guion:

Buscamos la posición del guión

B1 =ENCONTRAR("-";A1;1)+1)

Y extraemos el texto

C1 =EXTRAE(A1;B1;999)

Ahora tenemos este texto: MASTER RETOUCHING HAIR (JennyPhotography) $

Que termina en un paréntesis abierto '(', un Dólar '$', una admiración '!' o en nada. Ejemplo para buscar el paréntesis, pero lo busco en el resultado de C1:

D1 =ENCONTRAR(" (";C1)

El orden para buscar es el expresado arriba.

Y ahora ya puedo recortar el texto:

E1 =IZQUIERDA(C1;D1)

Si no hay paréntesis debe buscar el Dólar y si no hay la admiración y si no dejar lo que hay. Y como se sabe que no hay pues porque la función de D1 da error. Entonces sería así:

F1 =SI.ERROR(IZQUIERDA(C1;D1);  ' Y aquí es cuando da el error y hacemos otra búsqueda ' )

Entonces completamos la función:

F1 =SI.ERROR(IZQUIERDA(C1;D1-2);

    SI.ERROR(IZQUIERDA(C1;D1-2);

    SI.ERROR(IZQUIERDA(C1;D1-2);

                       C1)))

En el primer Si.Error busca el paréntesis, si no esta salta al segundo y busca el Dólar, si no esta salta al tercero y busca la admiración y si tampoco esta dela el texto tal cual.

Ahora es momento de completar la función para no tener tantas columna y una sola celda con la función. Empezaremos cambiando D1 por la función correspondiente

F1 =SI.ERROR(IZQUIERDA(C1;ENCONTRAR(" (";C1)-2);

    SI.ERROR(IZQUIERDA(C1;ENCONTRAR(" $";C1)-2);

    SI.ERROR(IZQUIERDA(C1;ENCONTRAR(" !";C1)-2);

                       C1)))

Ahora cambiamos C1 por la función correspondiente

F1 =SI.ERROR(IZQUIERDA(EXTRAE(A1;B1;999);ENCONTRAR(" (";EXTRAE(A1;B1;999))-2);

    SI.ERROR(IZQUIERDA(EXTRAE(A1;B1;999);ENCONTRAR(" $";EXTRAE(A1;B1;999))-2);

    SI.ERROR(IZQUIERDA(EXTRAE(A1;B1;999);ENCONTRAR(" !";EXTRAE(A1;B1;999))-2);

                       EXTRAE(A1;B1;999))))

Y ahora solo queda cambiar B1 por la función correspondiente

F1 =SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1);999);ENCONTRAR(" (";EXTRAE(A1;ENCONTRAR("-";A1;1)+2);999))-2);

    SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1);999);ENCONTRAR(" $";EXTRAE(A1;ENCONTRAR("-";A1;1)+2);999))-2);

    SI.ERROR(IZQUIERDA(EXTRAE(A1;ENCONTRAR("-";A1;1)+1);999);ENCONTRAR(" !";EXTRAE(A1;ENCONTRAR("-";A1;1)+2);999))-2);

                       EXTRAE(A1;ENCONTRAR("-";A1;1)+1);999))))

Espero que se entienda los pasos seguidos para construir la función. La función parece muy compleja pero siguiendo pasa a paso como la he creado se hace más fácil de entender.

Saludos.
\\//_

LWP-Hallar-y-extraer-datos-de-rutas-carpetas-Windows.zip(9,7 KB)

Valora esta respuesta

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 30/01/2022 14:55:01

Wow! qué vergüenza me da!!!! no puedo agradecerte mucho más allá que darte las gracias por tu tiempo. Como me gusta estudiar las ayudas y no copiar y pegar sin ton ni son, solo quería agradecerte tu ayuda antes que nada. Déjame estudiar lo que me propones y te comento algo.

En cuanto al autor, plataforma y título curso, eso lo conseguí hace un par de días. El código que te pegué se me quedó a la mitad, por eso te dio error seguro. No obstante, voy a estudiar tus propuestas. Esto es lo que tengo, por si alguien quiere aprovechar, de lo que conseguí.

Autor: =EXTRAE(EXTRAE(A10;HALLAR("@";SUSTITUIR(A10;"\";"@";LARGO(A10)-LARGO(SUSTITUIR(A10;"\";""))))+1;500);1;LARGO(EXTRAE(A10;HALLAR("@";SUSTITUIR(A10;"\";"@";LARGO(A10)-LARGO(SUSTITUIR(A10;"\";""))))+1;500))-LARGO(EXTRAE(A10;HALLAR("@";SUSTITUIR(A10;"-";"@";LARGO(A10)-LARGO(SUSTITUIR(A10;"-";""))))+1;500))-1)

Plataforma: =SI.ERROR(EXTRAE(A10;ENCONTRAR("(";A10)+1;ENCONTRAR(")";A10)-ENCONTRAR("(";A10)-1);"")

Título curso: =SI.ERROR(EXTRAE(A10;ENCONTRAR("-";A10)+1;ENCONTRAR(" (";A10)-ENCONTRAR("-";A10)-1);"")

Y de momento funciona.

Respecto a la adquisición que me propones, eso sí va a ser lo primero que vea porque no lo consigo:

=SI(NO(ESERROR(HALLAR("$$$";A10;1)));"Compra";"Suscripción")

Con esta fórmula lo consigo a medias, es decir, perfectamente obtengo esas 2 últimas opciones si tengo $$$ o $, pero si no tengo nada, me pone suscripción :(

Me sugieres esto:
=SI(DERECHA(A1;4)=" $$$";"Compra";
SI(DERECHA(A1;2)=" $" ;"Suscripción";
SI(DERECHA(A1;2)=" !" ;"Gratuito";"Descargado")))

sí, eso lo tengo claro, pero no tanto unirlo, no sé cómo puedo concatenar estas 3 funciones :(

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 30/01/2022 15:15:15

Esta es una sola función presentada en tres lineas para facilitar su lectura:

=SI(DERECHA(A1;4)=" $$$";"Compra";SI(DERECHA(A1;2)=" $";"Suscripción";SI(DERECHA(A1;2)=" !" ;"Gratuito";"Descargado")))

Como no se si sabes algo de programación te lo voy a poner de forma que lo entiendas o eso espero

=SI DERECHA(A1;4)=" $$$" entonces

    "Compra"

 En_caso_contrario

     SI(DERECHA(A1;2)=" $"  entonces

         "Suscripción"

     En_caso_contrario

         SI(DERECHA(A1;2)=" !" entonces

             "Gratuito"

         En_caso_contrario

             "Descargado"

Esto se lee así:

Si los 4 últimos caracteres son un espacio y tres símbolos Dólar entonces pones Compra en caso contrario si los 2 últimos caracteres son un espacio y un símbolo Dólar entonces pones Suscripción en caso contrario si los 2 últimos caracteres son un espacio y un símbolo admiración entonces pones Gratuito en caso contrario Descargado

Saludos.
\\//_

Valora esta respuesta

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 30/01/2022 15:36:01

Discúlpame Antoni,
Tomé tus funciones si de referencia y leí en la ayuda de microsoft cómo anidar diferentes funciones si, luego vi que tú lo habías puesto así (es que lo vi en 3 líneas diferentes y me confundí).

Como no lo conseguía, estuve 3 días modificando el final de mis +1500 carpetas (sí, a mano :(

así que ahora solo tengo $ (=Suscripción). $$$ (=Compra) y vacío (=Descarga), a mano, que son muy poquitas, pondré "gratuito".

El caso es que he hecho lo siguiente:
=SI(DERECHA(A11;4)=" $$$";"Compra";SI(DERECHA(A11;2)=" $";"Suscripción";SI(DERECHA(A11;" ")="";"Descarga")))

pero, oh! sorpresa, me devuelve como error #¡VALOR! (es lo que pasa cuando uno no sabe). Seguiré investigando.

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 30/01/2022 15:51:45

Esta parte en negrita esta mal:

=SI(DERECHA(A11;4)=" $$$";"Compra";SI(DERECHA(A11;2)=" $";"Suscripción";SI(DERECHA(A11;" ")="";"Descarga")))

Te pongo la corrección

=SI(DERECHA(A11;4)=" $$$";"Compra";SI(DERECHA(A11;2)=" $";"Suscripción";SI(DERECHA(A11;2)=" !";Gratuito";"Descarga")))

Saludos.
\\//_

Valora esta respuesta

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 30/01/2022 18:35:53

Hola Antoni,
Tal como comenté, tuve que cambiar el listado de los valores. Ya mis carpetas no tienen símbolo de exclamación, solo 1 o 3 símbolos del dólar o nada. Por eso puse la función que dices no está correcta.

Por ejemplo, en esta ruta no tengo dólares

Opción 4: H:\...RECURSOS Y VIDEOTUTORIALES\FOTOGRAFIA\Luz Santana-INSPIRACION Y CREATIVIDAD CON LUZ (Hineva)

por tanto, es un curso descargado, de ahí que haya escrito la siguiente función

=SI(DERECHA(A67;4)=" $$$";"Compra";SI(DERECHA(A67;2)=" $";"Suscripción";SI(DERECHA(A67;0)=") ";"Descargado")))

pero me lo devuelve FALSO si no hay símbolo del dólar (el resto, con símbolo del dolar, está perfecto).

Valora esta respuesta

Comentar

Pos: 2

Val: 4.908

Hallar y extraer datos de rutas carpetas Windows

Publicado por Antoni Masana (2486 intervenciones) el 30/01/2022 18:49:08

En el caso de tener 3, 2, 1 o ningún signo dólar la función es asi;

=SI(DERECHA(A1;4)=" $$$";"Compra";

 SI(DERECHA(A1;3)=" $$" ;"Suscripción";

 SI(DERECHA(A1;2)=" $"  ;"Gratuito";"Descargado")))

==== EXPLICACIÓN ====

" $$$" --> "Compra"

" $$"  --> "Suscripción"

" $"   --> "Gratuito"

""     --> "Descargado"

El fallo en la tuya es que en el último SI() no hay un texto en el caso de Falso:

=SI(DERECHA(A67;4)=" $$$";"Compra";

 SI(DERECHA(A67;2)=" $";"Suscripción";

 SI(DERECHA(A67;0)=") ";"Descargado" ; "Aqui falta texto")))

Saludos
\\//_

Valora esta respuesta

Comentar

Hallar y extraer datos de rutas carpetas Windows

Publicado por María García (7 intervenciones) el 30/01/2022 19:26:00

Hola Antoni,
Acabo de ver tu explicación y hasta ahora lo había estado intentando extrayendo los últimos dígitos de mi cadena de texto. El problema es que solo tengo 3 valores como te he comentado

$$$ = Compra
$ = Suscripción
ningún símbolo = Descarga

El caso es que he intentado, como ya comenté, extraer lo que me aparece en mi cadena de texto después del paréntesis de cierre (porque el vacío no me lo encuentra), pero a pesar de poner el paréntesis entre comillas, Excel cree que estoy cerrando la función.

EDITO: Perfecto!!! ahora entendí mejor lo que me proponías, yo pensaba que había que poner todos los valores con sus resultados, pero ahora veo que a falta de 2, el tercero que queda es la última respuesta que necesito. Ten en cuenta que sé muy, muy poco de funciones, por eso me ha costado mucho entender cómo conseguirlo.

Por tanto, ha quedado de la siguiente manera y funciona a la perfección!!!!

=SI(DERECHA(A112;4)=" $$$";"Compra";SI(DERECHA(A112;2)=" $";"Suscripción";"Descargado"))

Gracias!!!!!!!

ahora ya sé cómo concatenar varios if!!!

Valora esta respuesta

Comentar

Problemas con If y error protected view

Problema con Inventario