Excel - CBU Calculo

alguien tiene o sabe donde encontrar el Algoritmo de Calculo del CBU (clave bancaria uniforme) en argentina?
gracias

Pásame una cuenta completa, indicando donde está situado el CBU (supongo que serán dos dígitos). Es muy posible que sea igual que la española.

Saludos

Un numero de cuenta por ejemplo es 4-100-0940411237-4.
El CBU lo podes ver en la pagina www.macro.com.ar, busca el link donde dice CBU (un cuadradito a la derecha y al medio).

Pues según lo que he encontrado por la red, eso se parece al CBU lo mismo que un churro a una castaña.
Según http://www.latiumsoftware.com/es/pascal/0049.php y el programador Ernesto De Spirito, con fecha 30 de Sep 2003
"Las cuentas bancarias en Argentina se identifican por un número de CBU
(Clave Bancaria Uniforme), formado por 22 dígitos, divididos en dos
bloques. El primer bloque, formado por 8 dígitos, identifica al banco y
sucursal, mientras que el segundo bloque, formado por los restantes 13
dígitos, identifica la cuenta bancaria. El último dígito de cada bloque
es el dígito verificador del mismo según el algoritmo clave 10 con
ponderador 97132"

Lo que tú indicas no tiene 22 dígitos, ¿habéis cambiado la norma desde 2003?

Saludos

lo que pase es el numero de una cuenta, no de un cbu.
te paso una cuenta ejemplo : 4-100-09404012374-4
el cbu de dicha cuenta es: 2850100640094040123748

Para validar el CBU es necesario crear una función de usuario

Function ValidarCBU(Dato As String) As Boolean
'Clave Bancaria Uniforme
'---------------------------------------
' Copyright (c) 2003 Ernesto De Spirito
' Adaptada por José Luis Gonzalez para funcion Excel
' www. latiumsoftware.com/es/index.php
' www. latiumsoftware.com/es/pascal/0049.php
' Determina si un número de CBU es válido. ARGENTINA
' La cadena que se pasa como parámetro debe estar formada
' por 22 dígitos numéricos (no se admiten guiones, barras
' ni espacios como parte de la cadena con el CBU).

' El dígito verificador está en las posiciones 8 y 22
' usando clave 10 con ponderador 9713
'--------------------------------------
Dim Peso(4) As Integer
Dim i As Integer
Dim j As Integer
Dim Suma As Integer
Dim digito As Integer
Peso(0) = 3
Peso(1) = 1
Peso(2) = 7
Peso(3) = 9
'
'Verifica longitud
If Len(Dato) <> 22 Then
ValidarCBU = False
Exit Function
End If
'
'Verifica que son todo números
For i = 1 To Len(Dato)
If Mid(Dato, i, 1) < "0" Or Mid(Dato, i, 1) > "9" Then
ValidarCBU = False
Exit Function
End If
Next i
'
'Verifica 8º Dígito
'
Suma = 0
j = 0
For i = 7 To 1 Step -1
Suma = Suma + (Mid(Dato, i, 1) * Peso(j Mod 4))
j = j + 1
Next i
digito = (10 - Suma Mod 10) Mod 10
If Val(Mid(Dato, 8, 1)) <> digito Then
ValidarCBU = False
Exit Function
End If
'
'Verifica 22º Dígito
'
Suma = 0
j = 0
For i = 21 To 9 Step -1
Suma = Suma + (Mid(Dato, i, 1) * Peso(j Mod 4))
j = j + 1
Next i
digito = (10 - Suma Mod 10) Mod 10
If Val(Mid(Dato, 22, 1)) <> digito Then
ValidarCBU = False
Exit Function
End If
ValidarCBU = True
End Function

Saludos

Buen día. Tienes un video en youtube para ver como programaste el formulario. Muchas gracias.

Hola Como Puedo Saver Mi CBU De Mi Tarjeta Macro Familiar Por Internet ??