FoxPro/Visual FoxPro - Consulta para una presentación "profesional"

   
Vista:

Consulta para una presentación "profesional"

Publicado por Andrea (325 intervenciones) el 01/06/2009 13:57:49
Hola a todos!!

En un programa que estoy haciendo, necesitaría que al abrir la aplicación, aparezca un FORM de presentación mientras, en segundo plano, se vayan cargando las bases de datos, las variables, etc.
(Al mejor estilo de Acrobat Reader, Corel Draw, etc. Hasta incluso los programas de Office lo hacen)

De la manera que lo estoy haciendo (con la ventana de VFP de soporte) aparece en la barra de Título que dice "Visual FoxPro" pero casi enseguida la cambio con

_Screen.caption="[nombre de mi programa]"

Pero me gustaría que en el proceso aparezca una ventana de presentación (que incluya el nombre del programa, la versión, etc.) MIENTRAS SE CARGA LA APLICACIÓN EN SEGUNDO PLANO.

Tengo hecho el FORM de presentación pero no sé como hacer que desaparezca solo y siga con la ejecución del programa.

(Le podría poner un botón cerrar [ x ], pero me parece que es poco serio)

¿Alguna idea???

Desde ya MUCHAS GRACIAS!!
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

RE:Consulta para una presentación

Publicado por andy (221 intervenciones) el 01/06/2009 15:19:00
Prueba con esto a ver si te gusta (poner ESTABLECER PRINCIPAL)

*----------------------------------------------------------
* PRESENTA.PRG (Nombre del archivo)
*----------------------------------------------------------
* Este programa muestra una ventana de presentación mientras
* se ejecutan todos los seteos para mi aplicación.
*----------------------------------------------------------
LPARAMETERS tcCaption, tcTexto
oPresenta = CREATEOBJECT("Presenta",tcCaption,tcTexto)
oPresenta.SHOW
_SCREEN.VISIBLE = .F.

*--- Retardo para que se muestre el form completo
DOEVENTS
DOEVENTS
DOEVENTS

****************************************
*--- Aquí hago todos los seteos
*--- o tareas mientras se muestra
*--- la presentación
*--- Para prueba espero 3"
=INKEY(3) && Sacar esta línea
****************************************
oPresenta.RELEASE
_SCREEN.VISIBLE = .T.
****************************************
*--- Aquí ya llamo al menú o formulario principal de mi aplicación:

*DO MiMenu.MPR
* ó
* DO FORM MiForm
****************************************
RETURN

*----------------------------------
*--- Definición de la clase
*----------------------------------
DEFINE CLASS presenta AS FORM
HEIGHT = 150
WIDTH = 380
SHOWWINDOW = 2
DOCREATE = .T.
AUTOCENTER = .T.
BORDERSTYLE = 2
CAPTION = "Andy Soft Design"
CONTROLBOX = .F.
CLOSABLE = .F.
MAXBUTTON = .F.
MINBUTTON = .F.
MOVABLE = .F.
NAME = "PRESENTA"

ADD OBJECT lblPresenta AS LABEL WITH ;
AUTOSIZE = .T., ;
FONTBOLD = .T., ;
FONTSIZE = 24, ;
BACKSTYLE = 0, ;
CAPTION = "Gestión 6.2", ;
HEIGHT = 40, ;
LEFT = 40, ;
TOP = 25, ;
WIDTH = 250, ;
TABINDEX = 1, ;
FORECOLOR = RGB(255,0,0), ;
NAME = "lblPresenta"

ADD OBJECT lblespera AS LABEL WITH ;
AUTOSIZE = .T., ;
FONTBOLD = .T., ;
FONTNAME = "Arial", ;
FONTSIZE = 10, ;
BACKSTYLE = 0, ;
CAPTION = "Espere un momento por favor...", ;
HEIGHT = 20, ;
LEFT = 70, ;
MOUSEPOINTER = 11, ;
TOP = 120, ;
WIDTH = 200, ;
TABINDEX = 2, ;
NAME = "lblEspera"

PROCEDURE UNLOAD
*--- Muestro cursor
SYS(2002,1)
ENDPROC

PROCEDURE LOAD
*--- Oculto cursor
SYS(2002)
ENDPROC

PROCEDURE INIT
LPARAMETERS tcTitulo, tcPresenta
IF NOT EMPTY(tcTitulo)
THIS.CAPTION = tcTitulo
ENDIF
IF NOT EMPTY(tcPresenta)
THIS.lblPresenta.CAPTION = tcPresenta
ENDIF
THIS.REFRESH
ENDPROC

ENDDEFINE
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

RE:Consulta para una presentación

Publicado por Andrea (325 intervenciones) el 02/06/2009 20:38:24
Muchas gracias. Lo voy a probar!
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar