FoxPro/Visual FoxPro - ENVIAR MENSAJES DESDE VISUAL FOX

   
Vista:

ENVIAR MENSAJES DESDE VISUAL FOX

Publicado por Roberto Matarrita rmatarria@gmail.com (1 intervención) el 28/07/2014 07:14:05
Buenas Noches.
Necesito saber como enviar mensajes a otra computadora o usuario desde Visual Fox 9.
Necesito saber si existe algùn código que me pueda servir para enviar un mensaje a los usuarios.

Roberto
Costa Rica.
Valora esta pregunta
Me gusta: Está pregunta es útil y esta claraNo me gusta: Está pregunta no esta clara o no es útil
0
Responder

ENVIAR MENSAJES DESDE VISUAL FOX

Publicado por MANY (84 intervenciones) el 28/07/2014 08:29:33
Saludo Roberto

No se si esto existe, pero si no existe se puede construir usando alguna tabla compartida para enviar los mensajes por esta via y luego ver el procedimiento para que los usuarios la reciban, en esto hay que inventar lo que no existe a codigo limpio.

Por tu bien y el de todo espero que esto exista.

Hasta luego.
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar

ENVIAR MENSAJES DESDE VISUAL FOX

Publicado por Ernesto Hernandez (4632 intervenciones) el 28/07/2014 19:29:11
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
*!* !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
*!*	Copyright (c) ARG-Software Design Lab. 2001-2002
*!*	All rights reserved.
*!*
*!*	Simple MessageSender class,
*!*
*!*	This sample code is FREEWARE.
*!*
*!*
*!*	Author: Alex Grigorjev
*!*	E-mail: AlexG@arg.kirov.ru
*!* !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
 
oSender = CreateObject( "MessageSender")
oSender.Recipient = "localhost"
oSender.ReturnAddress = "ARG's Message_Sender"
?oSender.Send( "How are you doing?" + ;
				Chr(13) + Chr(10) + ;
				Chr(13) + Chr(10) + ;
				"This is a sample message sent by ARG's MessageSender")
 
Define Class MessageSender As Custom
 
	Recipient = ""
	ReturnAddress = ""
	UseNETSEND = .F.
 
	Procedure Init()
		DoDefault()
	EndProc
 
	Procedure Destroy
		DoDefault()
	EndProc
 
	Procedure Error(nError, cMethod, nLine)
	EndProc
 
	*- If the function succeeds, the return value is NERR_Success = 0.
	Function Send( tcMessage)
		Local lnResult
 
		lnResult = 0
 
		With This
			If Type( ".Recipient") != "C" Or Empty( .Recipient)
				&& no recipient
				Return -1
			EndIf
 
			If Type( "m.tcMessage") != "C" Or Empty( m.tcMessage)
				&& nothing to send
				Return -2
			EndIf
 
			If .UseNetSend
				Local lcCmd, loShell
 
				lcCmd = "NET SEND " + AllTrim( .Recipient) + ' "' + AllTrim( m.tcMessage) + '"'
 
				loShell = CreateObject( "WScript.Shell")
 
				If Type( "m.loShell") = "O" And !IsNull( m.loShell)
					lnResult = m.loShell.Run( m.lcCmd, 0, .T.)
				Else
					&& cannot create Shell object, will try Fox RUN command
					lcCmd = m.lcCmd
					!&lcCmd
					&& or ShellExecute
					* 	Declare Integer ShellExecute In Shell32 Integer, String, String, String, String, Integer
					* 	ShellExecute( 0, "open", "cmd.exe", "/c" + m.lcCmd, NULL, 2)
					* Or
					*	lcCmd = SubStr( m.lcCmd, 5)
					* 	ShellExecute( 0, "open", "net.exe", m.lcCmd, NULL, 2)
				EndIf
			Else
				Declare Integer NetMessageBufferSend In NetAPI32 ;
					String @ servername, ;
					String @ msgname, ;
					String @ fromname, ;
					String @ buf, ;
					Integer buflen
 
				Local lcMsgName, lcFrom, lnMsgLen, lcMsgBuf
 
				lcFrom = .ReturnAddress
 
				If Type( "m.lcFrom") != "C" Or Empty( m.lcFrom)
					lcFrom = "Unknown"
				EndIf
 
				lcMsgName = StrConv( AllTrim( .Recipient) + Chr( 0), 5)
 
				lcFrom = StrConv( AllTrim( m.lcFrom) + Chr(0), 5)
 
				lcMsgBuf = StrConv( AllTrim( m.tcMessage) + Chr(0), 5)
 
				lnMsgLen = Len( m.lcMsgBuf)
 
				lcMsgBuf = m.lcMsgBuf + Chr(0) + Chr(0)
 
				lnResult = NetMessageBufferSend( .NULL., m.lcMsgName, m.lcFrom, m.lcMsgBuf, m.lnMsgLen)
			EndIf
		EndWith
 
		Return m.lnResult
	EndFunc
 
EndDefine
Valora esta respuesta
Me gusta: Está respuesta es útil y esta claraNo me gusta: Está respuesta no esta clara o no es útil
0
Comentar