FoxPro/Visual FoxPro - Que no aparesca el formulario en la barra de tarea

Hola¡¡¡ buenas a todos, agradeceria que me ayudaran con este problema:

Buno lo que quiero es hacer que mi formuario no se vea en la barra de tareas, trabajo con visual fox pro 6.0. me habian dicho que existia la propiedad "ShowInTaskBar", pero no la encuantro por ningun lado... alguien sabe de otra manera para lograr que mi formuario no aparesca en la barra de tareas???

De momento no sé si funcione para vfp6, Pero en vfp 9 solo con cambiar la propiedad a .F. y revisar el WindowState no esté a 2, Funcionará perfecto.

Propiedad del Formulario:

ShowInTaskBar=.F. ó Thisform.ShowInTaskBar=.F.

Suerte►

Hola disculpen las molestias pero es VFP 6.0 no existe la propiedad ShowInTaskBar, por lo cual no puedo hacerlo asi...

ayuda por favor...

Prueba este ejemplo

Local oForm, lcPath
* Abrimos la biblioteca Systray
Set Classlib To (Home() + "Samples\Solution\Toledo\Systray") Additive
* Instanciamos el formulario de ejemplo
oForm = CreateObject("frmMinToTray")
* Verificamos la creación del objeto
If Vartype( oForm ) == "O"
* Si se creó, mostramos el formulario
oForm.Show()
* Iniciamos el bucle de lectura de eventos
Read Events
Else
* Sino, mostramos un mensaje de error
MessageBox( "Ocurrió un problema al crear el formulario", ;
16, "Ejemplo de MinToTray" )
EndIf
* Liberamos la biblioteca
Set Classlib To
* Finalizamos la ejecución
Return

**************************************************
* Definición del formulario de ejemplo *
**************************************************
Define Class frmMinToTray As Form
* Establecemos valores para algunas propiedades
Top = 0
Left = 0
Height = 142
Width = 375
ShowWindow = 2 && - Formulario de Nivel Superior
DoCreate = .T.
Caption = "Ejemplo de MinToTray"
Name = "frmMinToTray"

* Agregamos un CheckBox para definir si se minimizará al Systray o no.
Add Object chkMinToTray As CheckBox With ;
Top = 60, ;
Left = 84, ;
Height = 17, ;
Width = 209, ;
AutoSize = .T., ;
BackStyle = 0, ;
Caption = "Minimizar a la bandeja del sistema", ;
Value = .F., ;
Name = "chkMinToTray"

* Agregamos el manejador de la bandeja del sistema
Add Object oSysTray As SysTray With ;
Top = 0, ;
Left = 0, ;
AddIconToSysTrayAtInit = .F., ;
Name = "oSysTray"

* En el evento Deactivate vamos a codificar la funcionalidad
Procedure Deactivate
Local lcLib As String

With This
* Si el evento Deactivate se disparó por Minizar
* y el CheckBox está tildado, minizamos al SysTray
If .WindowState = 1 And .chkMinToTray.Value
With .oSysTray
***lcLib = .ClassLibrary
***Set Classlib To (lcLib) Additive
* Indicamos el ícono que se mostrará en el SysTray
.IconFile = HOME() + "Graphics\Icons\Misc\Face03.ico"
* Indicamos el texto emergente que se mostrará
.TipText = Thisform.Caption
* Agregamos el ícono al SysTray
.AddIconToSysTray()
EndWith
* Además, ocultamos el formulario
.Visible = .F.
EndIf
EndWith
EndProc

* Atendemos el evento que se dispara por Doble Clic en el Systray
Procedure oSysTray.IconDblClickEvent
With Thisform
* Restauramos el formulario
.WindowState = 0
* y lo hacemos visible
.Visible = .T.
EndWith
* Además, quitamos el ícono del Systray
This.RemoveIconFromSysTray()
EndProc

* Este evento se dispara al cerrar el formulario
Procedure QueryUnLoad
* Salimos del bucle de eventos
Clear Events
EndProc
EndDefine


Suerte

En verdad es un tanto mas complejo en versiones anteriores para realizar unas opciones en cuanto a vfp, por eso es mas aconsejable tratar de trabajar en vfp9.

Y asi como esta opcion existen mas propiedades que ya vienen por default.

suerte►