Supongo que es una pantalla de Presentacion de tu programa:
LPARAMETERS tcCaption, tcTexto
oPresenta = CREATEOBJECT("Presenta",tcCaption,tcTexto)
oPresenta.SHOW
_SCREEN.VISIBLE = .F.
* espero 5":
=INKEY(5)
oPresenta.RELEASE
_SCREEN.VISIBLE = .T.
RETURN
*--- Definición de la clase
DEFINE CLASS presenta AS FORM
HEIGHT = 150
WIDTH = 380
SHOWWINDOW = 2
DOCREATE = .T.
AUTOCENTER = .T.
BORDERSTYLE = 2
CAPTION = "Andy Soft Design"
CONTROLBOX = .F.
CLOSABLE = .F.
MAXBUTTON = .F.
MINBUTTON = .F.
MOVABLE = .F.
NAME = "PRESENTA"
ADD OBJECT lblPresenta AS LABEL WITH ;
AUTOSIZE = .T., ;
FONTBOLD = .T., ;
FONTSIZE = 24, ;
BACKSTYLE = 0, ;
CAPTION = "Pon lo que quieras...", ;
HEIGHT = 40, ;
LEFT = 40, ;
TOP = 25, ;
WIDTH = 250, ;
TABINDEX = 1, ;
FORECOLOR = RGB(255,0,0), ;
NAME = "lblPresenta"
ADD OBJECT lblespera AS LABEL WITH ;
AUTOSIZE = .T., ;
FONTBOLD = .T., ;
FONTNAME = "Arial", ;
FONTSIZE = 10, ;
BACKSTYLE = 0, ;
CAPTION = "Espere un momento por favor...", ;
HEIGHT = 20, ;
LEFT = 70, ;
MOUSEPOINTER = 11, ;
TOP = 120, ;
WIDTH = 200, ;
TABINDEX = 2, ;
NAME = "lblEspera"
*----------------
PROCEDURE UNLOAD
*--- Muestro cursor
SYS(2002,1)
ENDPROC
*------------------------
PROCEDURE LOAD
*--- Oculto cursor
SYS(2002)
ENDPROC
*************
PROCEDURE INIT
*******************
LPARAMETERS tcTitulo, tcPresenta
IF NOT EMPTY(tcTitulo)
THIS.CAPTION = tcTitulo
ENDIF
IF NOT EMPTY(tcPresenta)
THIS.lblPresenta.CAPTION = tcPresenta
ENDIF
THIS.REFRESH
ENDPROC
ENDDEFINE
