RE:Envio de mails masivos
Te paso esta funcion de LotusScrip para el envio de mails ... solo deberias armarte un agente que recorra con un bucle el listado de mails, y por cada uno .. llamar a esta funcion:
Function MailSend( Link As Variant, SendTo As Variant , CopyTo As Variant, BlindCopyTo , Subject As Variant, Body As Variant, NroIcono As Integer , NomSalida As String ) As Variant
%REM
Funcion utilizada para Enviar Correos
Parametros
Link ==>>Puede ser:
NotesDocument ( y agrego un docLink al documento )
NotesView ( y agrego un docLink a la vista )
NotesDatabase ( y agrego un docLink a la base de datos )
NotesRichTextItem ( y se utiliza ese RichText para pegarlo al final del Body del Mail)
* Si no es ninguno de estos no se crea DocLink
SendTo ==>> Nombre/s de grupos o personas para enviar el correo
CopyTo ==>> Nombre/s de grupos o personas para enviar copia del correo
BlindCopyTo==>> Nombre/s de grupos o personas para enviar copia oculta del correo
Subject ==>> Titulo del mensaje (string)
Body ==>> Cuerpo del mensaje. Puede ser NotesRichTextItem o String:
==>> Si es string se poga el texto al principio del Body del Mail
==>> Si es NotesRichTextItem se pega ese objeto al principio del Body del Mail
NroIcono ==>> Integer que representara el Icono a mostrar en la base de correo del usuario
NomSalida ==>> Nombre con el que saldra el correo ( para cambiar el nombre de la persona que envia el correo)
Devuelve Verdadero o falso dependiente si se pudo enviar correo o no
%END REM
On Error Goto EH
Dim session As NotesSession
Dim mailbox As NotesDatabase
Dim memo As NotesDocument
Dim Rich As NotesRichTextItem
Dim Style As NotesRichTextStyle
Dim itemSendTo As NotesItem
Dim itemCopyTo As NotesItem
Dim itemBlindCopyTo As NotesItem
Dim itemSubject As NotesItem
MailSend = False
' Creo el documento para enviar por correo
Set session = New NotesSession
If Trim(NomSalida) <> "" Then
If session.IsOnServer Then
Set mailbox = New NotesDatabase( "" , "mail1.box" )
Else
Set mailbox = New NotesDatabase( session.CurrentDatabase.Server , "mail1.box" )
End If
Set memo = New NotesDocument( mailbox )
Call memo.ReplaceItemValue("From" , NomSalida )
Call memo.ReplaceItemValue("SendFrom" , NomSalida )
Call memo.ReplaceItemValue("Principal" , NomSalida )
Call memo.ReplaceItemValue("ReplyTo" , NomSalida )
Call memo.ReplaceItemValue( "SendTo" , SendTo )
Call memo.ReplaceItemValue("Recipients" , SendTo )
Call memo.ReplaceItemValue( "CopyTo" , "" )
Call memo.ReplaceItemValue( "BlindCopyTo" , "" )
Call memo.ReplaceItemValue("PostedDate" , memo.Created )
Call memo.ReplaceItemValue("ComposedDate" , memo.Created )
Call memo.ReplaceItemValue("DeliveredDate" , memo.Created )
Call memo.ReplaceItemValue("SaveMessageOnSend" , False )
Else
Set memo = New NotesDocument( session.CurrentDatabase )
Call memo.ReplaceItemValue( "SendTo" , SendTo )
Call memo.ReplaceItemValue( "CopyTo" , CopyTo )
Call memo.ReplaceItemValue( "BlindCopyTo" , BlindCopyTo )
End If
Call memo.ReplaceItemValue( "Subject" , Subject )
Set Rich = New NotesRichTextItem( memo , "Body" )
' Defino un Estilo
Set Style = session.CreateRichTextStyle()
Style.Bold = True
Style.FontSize = 8
Style.NotesFont = FONT_HELV
' Si ingreso el numero de Icono para ver en la vista
If NroIcono > 0 Then
Call memo.ReplaceItemValue( "_ViewIcon" , NroIcono )
End If
' Si el parametro pasado no es un RichText => Creo el RichText
If Typename( Body ) = "NOTESRICHTEXTITEM" Then
' Copio el RichText pasado como Body al cuerpo del Mail que voy a enviar
Call Rich.AppendRTItem( Body )
Else
' Copio el String pasado como cuerpo del correo al Body del mail a enviar
Call Rich.AppendText( Body )
Call Rich.AddNewLine(1)
End If
' Si se paso algun objecto real para hacer el Link -->> Lo creo
Select Case Typename( Link )
Case "NOTESDOCUMENT"
Call Rich.AppendStyle( Style )
Call Rich.AddNewLine(1)
Call Rich.AppendText( "Haga click aqui para ver el documento -->> " )
Call Rich.AppendDocLink( Link , "Click aqui para ver el documento" )
Case "NOTESVIEW"
Call Rich.AppendStyle( Style )
Call Rich.AddNewLine(1)
Call Rich.AppendText( "Haga click aqui para ver la vista -->> " )
Call Rich.AppendDocLink( Link , "Click aqui para ver la vista" )
Case "NOTESDATABASE"
Call Rich.AppendStyle( Style )
Call Rich.AddNewLine(1)
Call Rich.AppendText( "Haga click aqui para ver la base de datos -->> " )
Call Rich.AppendDocLink( Link , "Click aqui para ver la base de datos " & Link.Server & " " & Link.FilePath )
Case "NOTESRICHTEXTITEM"
' Copio el RichText pasado como parametro al cuerpo del Mail que voy a enviar
Call Rich.AppendRTItem( Link )
End Select
' ||| Enviar el mensaje de correo electrónico |||
If Trim(NomSalida) <> "" Then
Call memo.Save( True , False )
Else
Call memo.send(False)
End If
MailSend = True
Exit Function
EH:
Print "Error al enviar mail: " & Err & " " & Error & " (linea: " & Erl & ")"
Exit Function
End Function