Pascal/Turbo Pascal - Copiar contenido de un archivo de texto a un array

program FileToNumber;

const CuantosNumeros = 10;

var ArrayDeNumeros: Array[1..CuantosNumeros] of Integer;

    n: Integer;

procedure FileToArray(const FileName: string);

var Line: string;

    MyFile: TEXT;

    Contador, NumError: Integer;

begin

  Assign(MyFile, FileName);

{$I-}

  Reset(MyFile);

{$I+}

  if IOResult <> 0 then

  begin

    writeln('No he podido abrir el archivo ' + FileName + '. Sorry!');

    readln;

    exit;

  end;

  for Contador := 1 to CuantosNumeros do

    ArrayDeNumeros[Contador] := 0;     {Edad = 0 equivale a "Edad No Asignada"}

  Contador := 0;

  while not Eof(MyFile) and (Contador < CuantosNumeros) do

  begin

    Readln(MyFile, Line);

    if Length(Line) > 0 then

    begin

      Contador := Contador + 1;

                       {Realizar aqui la conversión de la linea a entero}

                       {según el formato utilizado. Por ejemplo...}

      Val(Line, ArrayDeNumeros[Contador], NumError);

      if NumError <> 0 then

        ArrayDeNumeros[Contador] := -1;

                       {Edad = -1 equivale a "Error en Valor de Edad"}

    end;

  end;

  Close(MyFile);

end;

begin

  FileToArray('Numeros.txt');

  writeln('Edades leidas en el archivo Numeros.txt');

  for n := 1 to CuantosNumeros do

    if ArrayDeNumeros[n] > 0 then

      writeln(ArrayDeNumeros[n]);

  readln;

end.