Power Builder - Recorrer controles

Buenas tardes atodos ,
tengo el sguiente scrip para recorrer todos los controles q hay en mi ventana
pero no se como modificar una propiedad del control una vez q ya lo encontre
por ejemplo modificar el color si es un statictext

object winobjecttype[]
long ll_count
FOR ll_count = 1 to UpperBound(Control[])
winobjecttype[ll_count] = TypeOf(Control[ll_count])
choose Case winobjecttype[ll_count]
Case SingleLineEdit!
Case DataWindow!
Case statictext!
// Control[ll_count].textcolor = rgb (25,250,200)
messagebox ("encontre static text",string (ll_count))
End choose

NEXT

//st_1.textcolor = rgb (0,0,0)

Espero me puedan ayudar

fijate si esto lo q deseas hacer

long ll_w_color,ll_t_color // asigna el color q desees a estas variables

long ll_count
statictext ls_statictext
singlelineedit ls_singlelinedit
dropdownlistbox ls_dropdownlistbox
listbox ls_listbox
editmask ls_editmask
checkbox ls_checkbox

FOR ll_count = 1 to UpperBound(this.Control[])
if mid(this.Control[ll_count].classname(),1,3)="mdi" then goto salto_control

choose case this.Control[ll_count].typeof()
case datawindow!
f_cambia_color_dw_con_skin(this.Control[ll_count],ll_w_color,ll_t_color)
case statictext!
ls_statictext=this.Control[ll_count]
ls_statictext.backcolor=ll_w_color
ls_statictext.textcolor=ll_t_color
case singlelineedit!
ls_singlelinedit=this.Control[ll_count]
ls_singlelinedit.backcolor=ll_w_color
ls_singlelinedit.textcolor=ll_t_color
case dropdownlistbox!
ls_dropdownlistbox=this.Control[ll_count]
ls_dropdownlistbox.backcolor=ll_w_color
ls_dropdownlistbox.textcolor=ll_t_color
case listbox!
ls_listbox=this.Control[ll_count]
ls_listbox.backcolor=ll_w_color
ls_listbox.textcolor=ll_t_color
case editmask!
ls_editmask=this.Control[ll_count]
ls_editmask.backcolor=ll_w_color
ls_editmask.textcolor=ll_t_color
case checkbox!
ls_checkbox=this.Control[ll_count]
ls_checkbox.backcolor=ll_w_color
ls_checkbox.textcolor=ll_t_color
end choose

salto_control:
NEXT

// f_cambia_color_dw_con_skin(this.Control[ll_count],ll_w_color,ll_t_color) esta funcion tu no la tienes, asi q modifica esa linea

espero te de una idea
saludos desde argentina

Ok Amilcar gracias por tu ayuda
me va a ser de bastante utilidad

Saludos desde Lima Peru

y como seria esta funcion que comentaste? esa es la que esta mas picante