Visual Basic - Eliminar menu por defecto de caja de texto

Buenos días, deseo eliminar el menú por defecto que proporcionan las cajas de texto, para evitar las opciones que da dicho menú.

Saludos Alejandro.

No hay una propiedad o un método directo, lo puedes hacer con API's de Windows, fijate con ésto:

Public Const WM_CUT = &H300
Public Const WM_COPY = &H301
Public Const WM_PASTE = &H302
Public Const WM_CLEAR = &H303
Public Const GWL_WNDPROC = -4
Public Const WM_RBUTTONUP = &H205

Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Public lpPrevWndProc As Long
Private lngHWnd As Long

Public Sub Hook(hWnd As Long)
lngHWnd = hWnd
lpPrevWndProc = SetWindowLong(lngHWnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub

Public Sub UnHook()
Dim lngReturnValue As Long
lngReturnValue = SetWindowLong(lngHWnd, GWL_WNDPROC, lpPrevWndProc)
End Sub

Public Function WindowProc(ByVal hw As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Select Case uMsg
Case WM_CUT
Case WM_COPY
Case WM_PASTE
Case WM_CLEAR
Case WM_RBUTTONUP
Case Else
WindowProc = CallWindowProc(lpPrevWndProc, hw, uMsg, wParam, lParam)
End Select
End Function

Gracias Cecilia, pero me gustaria que me dijeras donde pongo este código. Se que parte de él ó no se si todo deberá de ir en un modulo pero como invoco a las funciones. Te agradeceria que me ayudaras un poquito mas.

Gracias por todo.

El código lo puedes colocar todo en un módulo y luego en cada textbox en el evento GotFocus haces:

Hook Text.hwnd

Y en el LostFocus:

UnHook

Sino lo puedes hacer en un control a partir de un TextBox.

Hola Cecilia acabo de poner en un módulo el código y luego en los eventos GotFocus y LostFocus y sigue apareciendo el menú. Tengo definida una matriz de controles pero he incluido una caja de texto y tampoco funciona. Te agradecería cualquier ayuda que me pudieras brindar.
Saludos Alejandro

A mi me funciona sin problemas, puedes intentar colocar el código en el evento Load y Unload del Form respectivamente a ver que sucede.

Si revisas en http://www.vb-helper.com/howto_remove_context_menu.html tienes un ejemplo y es casi el mismo código.