Código de Basic - Sudoku C64

Imágen de perfil
Val: 545
Oro
Ha mantenido su posición en Basic (en relación al último mes)
Gráfica de Basic

Sudoku C64gráfica de visualizaciones


Basic

Actualizado el 27 de Diciembre del 2019 por Adelino (24 códigos) (Publicado el 23 de Octubre del 2019)
9.217 visualizaciones desde el 23 de Octubre del 2019
Programa para Commodore 64.

C64Disk

Requerimientos

Realizado y probado en la app Hand Basic para iPad y emulador Power64 para Mac.

1.0

Publicado el 23 de Octubre del 2019gráfica de visualizaciones de la versión: 1.0
611 visualizaciones desde el 23 de Octubre del 2019

1.1

Actualizado el 19 de Noviembre del 2019 (Publicado el 26 de Octubre del 2019)gráfica de visualizaciones de la versión: 1.1
661 visualizaciones desde el 26 de Octubre del 2019

1.2

Actualizado el 19 de Noviembre del 2019 (Publicado el 2 de Noviembre del 2019)gráfica de visualizaciones de la versión: 1.2
879 visualizaciones desde el 2 de Noviembre del 2019
estrellaestrellaestrellaestrellaestrella
estrellaestrellaestrellaestrella
estrellaestrellaestrella
estrellaestrella
estrella

Version para emulador.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
10 POKE 53280,0: POKE 53281,0
20 PRINT CHR$(151) CHR$(147)
30 DIM A(242), B(2), C(80), Q(80)
40 DIM X(80), Y(80), Z(80)
50 B=1133
 
100 FOR V=0 TO 2
110 FOR W=0 TO 2: READ A$: B=B+62
120 FOR N=0 TO 2
130 FOR M=0 TO 2
140 X(C)=27*V+9*W
150 Y(C)=27*N+9*M+81
160 Z(C)=27*V+9*N+162
170 A=ASC(MID$(A$,3*N+M+1))
180 IF A=46 THEN A=32
190 POKE B,A: POKE B+41,91
200 POKE B-1,66: POKE B+1,66
210 POKE B-40,67: POKE B+40,67
220 POKE B+54272,15
230 IF V+W=0 THEN POKE B-39,114
240 IF V+W=4 THEN POKE B+41,113
250 IF N+M=0 THEN POKE B+39,107
260 IF N+M=4 THEN POKE B+41,115
270 Q(C)=B
280 B=B+2
290 C=C+1
300 NEXT M,N,W,V
310 POKE 1154,112: POKE 1172,110
320 POKE B+21,109: POKE B+39,125
330 A=0: C=0: M=0
 
340 IF A=29 AND C<80 THEN C=C+1
350 IF A=157 AND C>0 THEN C=C-1
360 IF A=17 AND C<72 THEN C=C+9
370 IF A=145 AND C>8 THEN C=C-9
380 IF A>57 OR A<48 AND A<>32 GOTO 430
390 IF A=48 THEN A=32
400 POKE Q(C),A
410 A=29
420 GOTO 340
430 POKE Q(C),PEEK(Q(C))+128
440 GET A$: IF A$="" GOTO 440
450 POKE Q(C),PEEK(Q(C))-128
460 A=ASC(A$)
470 IF A<>13 GOTO 340
 
480 FOR C=0 TO 80
490 A=PEEK(Q(C))-49
500 IF A<0 GOTO 560
510 IF A(X(C)+A)+A(Y(C)+A)+A(Z(C)+A)=0 GOTO 530
520 POKE Q(C),32: GOTO 560
530 B(C/27)=B(C/27)+1
540 A(X(C)+A)=1: A(Y(C)+A)=1: A(Z(C)+A)=1
550 POKE Q(C)+54272,6
560 NEXT
 
570 FOR V=0 TO 2: N=0
580 FOR W=0 TO 2
590 IF B(W)>B(N) THEN N=W
600 NEXT
610 B(N)=-1
620 FOR C=27*N TO 27*N+26
630 IF PEEK(Q(C))=32 THEN C(M)=C: M=M+1
640 NEXT C,V
650 B=SGN(M)
 
660 IF B=0 THEN END
670 B=B-1
680 C=C(B)
690 A=PEEK(Q(C))-49
700 IF A<0 THEN A=0: GOTO 740
710 A(X(C)+A)=0: A(Y(C)+A)=0: A(Z(C)+A)=0
720 IF A=8 THEN POKE Q(C),32: GOTO 660
730 A=A+1
740 IF A(X(C)+A) GOTO 720
750 IF A(Y(C)+A) GOTO 720
760 IF A(Z(C)+A) GOTO 720
770 A(X(C)+A)=1: A(Y(C)+A)=1: A(Z(C)+A)=1
780 POKE Q(C),A+49
790 B=B+1
800 IF B<M GOTO 680
810 GET A$: IF A$<>" " GOTO 810
820 GOTO 670
 
900 DATA ....76...
910 DATA 1...3874.
920 DATA .7.......
930 DATA ..4.6.5.1
940 DATA .67...28.
950 DATA 3.1.4.6..
960 DATA .......1.
970 DATA .2561...9
980 DATA ...98....



Comentarios sobre la versión: 1.2 (0)


No hay comentarios
 

Comentar la versión: 1.2

Nombre
Correo (no se visualiza en la web)
Valoración
Comentarios...
CerrarCerrar
CerrarCerrar
Cerrar

Tienes que ser un usuario registrado para poder insertar imágenes, archivos y/o videos.

Puedes registrarte o validarte desde aquí.

Codigo
Negrita
Subrayado
Tachado
Cursiva
Insertar enlace
Imagen externa
Emoticon
Tabular
Centrar
Titulo
Linea
Disminuir
Aumentar
Vista preliminar
sonreir
dientes
lengua
guiño
enfadado
confundido
llorar
avergonzado
sorprendido
triste
sol
estrella
jarra
camara
taza de cafe
email
beso
bombilla
amor
mal
bien
Es necesario revisar y aceptar las políticas de privacidad

1.3

Actualizado el 19 de Noviembre del 2019 (Publicado el 13 de Noviembre del 2019)gráfica de visualizaciones de la versión: 1.3
1.171 visualizaciones desde el 13 de Noviembre del 2019

1.4

Publicado el 18 de Noviembre del 2019gráfica de visualizaciones de la versión: 1.4
1.199 visualizaciones desde el 18 de Noviembre del 2019

1.5

Actualizado el 29 de Enero del 2021 (Publicado el 19 de Noviembre del 2019)gráfica de visualizaciones de la versión: 1.5
2.197 visualizaciones desde el 19 de Noviembre del 2019

1.6

Publicado el 27 de Diciembre del 2019gráfica de visualizaciones de la versión: 1.6
2.500 visualizaciones desde el 27 de Diciembre del 2019
http://lwp-l.com/s5602