Visual Basic - archivos

saludos:

tengo una aplicacion la cual recupera los datos de un archivo llamado calk.eyy la extension la invente yo, "calk" es el nombre del archivo puesto por el usuario al momento de guardar el documento trabajado en mi aplicacion. (como es el . doc en el word), y lo que quiero es asociar el archivo con extension " eyy ", para que cuando se haga doble clik en él, se habra la aplicacion y el documento (al = cuando uno hace doble clik en un .doc, se abre el word y el documento), la gracia es que tambien tenga un icono correspondiente. oviamente la aplicacion se va a instalar en cualquier pc.

eso como lo ago gracias.

' Las APIS necesarias para registrar extensiones son estas:

Private Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Private Declare Function RegSetValue Lib "advapi32.dll" Alias "RegSetValueA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal dwType As Long, ByVal lpData As String, ByVal cbData As Long) As Long

Private Const HKEY_CLASSES_ROOT = &H80000000
Private Const MAX_PATH = 260&
Private Const REG_SZ = 1
Private Sub AssociateFileExtension()
Dim sKeyName As String, sKeyValue As String
Dim ret&, lphKey&
'Se crea una entrada en el Root llamada "MyApp".
sKeyName = "Mycalk"
sKeyValue = "Mycalk"
ret& = RegCreateKey&(HKEY_CLASSES_ROOT, sKeyName, lphKey&)
ret& = RegSetValue&(lphKey&, "", REG_SZ, sKeyValue, 0&)
'Se crea una entrada en el Root cuya extension se asocia con "Mycalk".
sKeyName = "." & "eyy"
sKeyValue = "Mycalk"
ret& = RegCreateKey&(HKEY_CLASSES_ROOT, sKeyName, lphKey&)
ret& = RegSetValue&(lphKey&, "", REG_SZ, sKeyValue, 0&)
'Acá se agrega el command line para "Mycalk".
sKeyName = "Mycalk"
sKeyValue = "C:\Archivo de Programas\Mycalk\Mycalk.exe" & " %1"
ret& = RegCreateKey&(HKEY_CLASSES_ROOT, sKeyName, lphKey&)
ret& = RegSetValue&(lphKey&, "shell\open\command", REG_SZ, sKeyValue, MAX_PATH)
'Acá se incorpora el Icono por default
sKeyName = "Mycalk"
sKeyValue = "C:\Archivo de Programas\Mycalk\Mycalk.exe" & ",0"
ret& = RegCreateKey&(HKEY_CLASSES_ROOT, sKeyName, lphKey&)
ret& = RegSetValue&(lphKey&, "DefaultIcon", REG_SZ, sKeyValue, MAX_PATH)
End Sub

saludos:

gracias por responder,,,,otra pregunta, como aprendiste todo esto, ya que por lo mas que e buscado , no e podido encontrar manuales con respecto a las apis...